CMakeLists.txt

   1 # Main CMakeLists.txt to build the OpenJPEG project using CMake (www.cmake.org)
   2 # Written by Mathieu Malaterre
   3
   4 # This CMake project will by default create a library called openjpeg
   5 # But if you want to use this project within your own (CMake) project
   6 # you will eventually like to prefix the library to avoid linking confusion
   7 # For this purpose you can define a CMake var: OPENJPEG_NAMESPACE to whatever you like
   8 # e.g.:
   9 # SET(OPENJPEG_NAMESPACE "GDCMOPENJPEG")
  10 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  11
  12 IF(COMMAND CMAKE_POLICY)
  13   CMAKE_POLICY(SET CMP0003 NEW)
  14 ENDIF(COMMAND CMAKE_POLICY)
  15
  16 IF(NOT OPENJPEG_NAMESPACE)
  17   SET(OPENJPEG_NAMESPACE "OPENJPEG")
  18   SET(OPENJPEG_STANDALONE 1)
  19 ENDIF(NOT OPENJPEG_NAMESPACE)
  20 # In all cases:
  21 STRING(TOLOWER ${OPENJPEG_NAMESPACE} OPENJPEG_LIBRARY_NAME)
  22
  23 PROJECT(${OPENJPEG_NAMESPACE} C)
  24
  25 # Do full dependency headers.
  26 INCLUDE_REGULAR_EXPRESSION("^.*$")
  27
  28 #-----------------------------------------------------------------------------
  29 # OPENJPEG version number, useful for packaging and doxygen doc:
  30 SET(OPENJPEG_VERSION_MAJOR 1)
  31 SET(OPENJPEG_VERSION_MINOR 4)
  32 SET(OPENJPEG_VERSION_BUILD 0)
  33 SET(OPENJPEG_VERSION
  34   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  35 SET(PACKAGE_VERSION
  36   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  37 SET(OPENJPEG_LIBRARY_PROPERTIES
  38   VERSION   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}"
  39   SOVERSION "${OPENJPEG_VERSION_MAJOR}"
  40 )
  41 # You will also need to define a value for the following variables:
  42 # OPENJPEG_INSTALL_BIN_DIR          - binary dir (executables)
  43 # OPENJPEG_INSTALL_LIB_DIR          - library dir (libs)
  44 # OPENJPEG_INSTALL_DATA_DIR         - share dir (say, examples, data, etc)
  45 # OPENJPEG_INSTALL_INCLUDE_DIR      - include dir (headers)
  46
  47
  48 # On Visual Studio 8 MS deprecated C. This removes all 1.276E1265 security
  49 # warnings
  50 IF(WIN32)
  51   IF(NOT BORLAND)
  52     IF(NOT CYGWIN)
  53       IF(NOT MINGW)
  54         IF(NOT ITK_ENABLE_VISUAL_STUDIO_DEPRECATED_C_WARNINGS)
  55           ADD_DEFINITIONS(
  56             -D_CRT_FAR_MAPPINGS_NO_DEPRECATE
  57             -D_CRT_IS_WCTYPE_NO_DEPRECATE
  58             -D_CRT_MANAGED_FP_NO_DEPRECATE
  59             -D_CRT_NONSTDC_NO_DEPRECATE
  60             -D_CRT_SECURE_NO_DEPRECATE
  61             -D_CRT_SECURE_NO_DEPRECATE_GLOBALS
  62             -D_CRT_SETERRORMODE_BEEP_SLEEP_NO_DEPRECATE
  63             -D_CRT_TIME_FUNCTIONS_NO_DEPRECATE
  64             -D_CRT_VCCLRIT_NO_DEPRECATE
  65             -D_SCL_SECURE_NO_DEPRECATE
  66             )
  67         ENDIF(NOT ITK_ENABLE_VISUAL_STUDIO_DEPRECATED_C_WARNINGS)
  68       ENDIF(NOT MINGW)
  69     ENDIF(NOT CYGWIN)
  70   ENDIF(NOT BORLAND)
  71 ENDIF(WIN32)
  72
  73
  74 # --------------------------------------------------------------------------
  75 # Install directories
  76
  77 STRING(TOLOWER ${PROJECT_NAME} projectname)
  78 SET(subdir "${projectname}-${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}")
  79
  80 IF(NOT OPENJPEG_INSTALL_BIN_DIR)
  81   SET(OPENJPEG_INSTALL_BIN_DIR "bin")
  82 ENDIF(NOT OPENJPEG_INSTALL_BIN_DIR)
  83
  84 IF(NOT OPENJPEG_INSTALL_LIB_DIR)
  85   SET(OPENJPEG_INSTALL_LIB_DIR "lib")
  86 ENDIF(NOT OPENJPEG_INSTALL_LIB_DIR)
  87
  88 IF(NOT OPENJPEG_INSTALL_DATA_DIR)
  89   SET(OPENJPEG_INSTALL_DATA_DIR "share/${subdir}")
  90 ENDIF(NOT OPENJPEG_INSTALL_DATA_DIR)
  91
  92 IF(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
  93   SET(OPENJPEG_INSTALL_INCLUDE_DIR "include/")
  94 ENDIF(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
  95
  96 IF(NOT OPENJPEG_INSTALL_MAN_DIR)
  97   SET(OPENJPEG_INSTALL_MAN_DIR "share/man/")
  98 ENDIF(NOT OPENJPEG_INSTALL_MAN_DIR)
  99
 100 IF(NOT OPENJPEG_INSTALL_DOC_DIR)
 101   SET(OPENJPEG_INSTALL_DOC_DIR "share/doc/${subdir}")
 102 ENDIF(NOT OPENJPEG_INSTALL_DOC_DIR)
 103
 104 IF(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
 105   SET(OPENJPEG_INSTALL_PACKAGE_DIR ${OPENJPEG_INSTALL_LIB_DIR}/${subdir}
 106     CACHE INTERNAL "")
 107 ENDIF(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
 108
 109 #-----------------------------------------------------------------------------
 110 # Test for some required system information.
 111 INCLUDE (${CMAKE_ROOT}/Modules/CMakeBackwardCompatibilityC.cmake)
 112
 113 #-----------------------------------------------------------------------------
 114 # Test for getopt being available in this system
 115 INCLUDE (${PROJECT_SOURCE_DIR}/CMake/CheckHaveGetopt.cmake )
 116
 117 #-----------------------------------------------------------------------------
 118 # Setup file for setting custom ctest vars
 119 CONFIGURE_FILE(
 120   ${CMAKE_CURRENT_SOURCE_DIR}/CMake/CTestCustom.cmake.in
 121   ${CMAKE_CURRENT_BINARY_DIR}/CTestCustom.cmake
 122   @ONLY
 123   )
 124
 125 #-----------------------------------------------------------------------------
 126 # OpenJPEG build configuration options.
 127 OPTION(BUILD_SHARED_LIBS "Build OpenJPEG shared library and link executables against it." ON)
 128
 129 #-----------------------------------------------------------------------------
 130 SET (EXECUTABLE_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all executables.")
 131 SET (LIBRARY_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all libraries.")
 132 MARK_AS_ADVANCED(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
 133
 134
 135 # configure name mangling to allow multiple libraries to coexist
 136 # peacefully
 137 IF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 138 SET(MANGLE_PREFIX ${OPENJPEG_LIBRARY_NAME})
 139 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in
 140                ${CMAKE_CURRENT_BINARY_DIR}/openjpeg_mangle.h
 141                @ONLY IMMEDIATE)
 142 ENDIF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 143
 144 #-----------------------------------------------------------------------------
 145 # pkgconfig support
 146 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libopenjpeg1.pc.cmake ${CMAKE_CURRENT_BINARY_DIR}/libopenjpeg1.pc )
 147 INSTALL( FILES  ${CMAKE_CURRENT_BINARY_DIR}/libopenjpeg1.pc DESTINATION ${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig )
 148 INSTALL( CODE
 149   "EXECUTE_PROCESS(COMMAND ${CMAKE_COMMAND} -E create_symlink \"libopenjpeg1.pc\" \"\$ENV{DESTDIR}${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig/libopenjpeg.pc\")")
 150
 151 #-----------------------------------------------------------------------------
 152 # Always build the library
 153 INCLUDE_DIRECTORIES(BEFORE ${CMAKE_CURRENT_BINARY_DIR})
 154 SUBDIRS(libopenjpeg)
 155
 156 #-----------------------------------------------------------------------------
 157 # Build CODEC executables ?
 158 OPTION(BUILD_CODEC "Build the CODEC executables" ON)
 159
 160 #-----------------------------------------------------------------------------
 161 # Build MJ2 executables ?
 162 OPTION(BUILD_MJ2 "Build the MJ2 executables." OFF)
 163
 164 #-----------------------------------------------------------------------------
 165 # Build JPWL executables ?
 166 OPTION(BUILD_JPWL "Build the JPWL executables" OFF)
 167
 168 #-----------------------------------------------------------------------------
 169 # Build JP3D executables ?
 170 OPTION(BUILD_JP3D "Build the JP3D executables" OFF)
 171
 172 #-----------------------------------------------------------------------------
 173 # Build INDEXER_JPIP executables ?
 174 OPTION(BUILD_INDEXER_JPIP "Build the INDEXER_JPIP executables" OFF)
 175
 176 #-----------------------------------------------------------------------------
 177 # Build DOCUMENTATION ?
 178 OPTION(BUILD_DOC "Build the doxygen documentation" OFF)
 179
 180 #-----------------------------------------------------------------------------
 181 # For openjpeg team if they ever want CDash+CMake
 182 OPTION(BUILD_TESTING "Build the tests." OFF)
 183 IF(BUILD_TESTING)
 184   ENABLE_TESTING()
 185   INCLUDE(CTest)
 186 ENDIF(BUILD_TESTING)
 187
 188 # Adding test with dataset from:
 189 # http://www.crc.ricoh.com/~gormish/jpeg2000conformance/
 190 # -> wget http://www.crc.ricoh.com/~gormish/jpeg2000conformance/j2kp4files_v1_5.zip
 191 # http://www.jpeg.org/jpeg2000guide/testimages/testimages.html
 192 #-----------------------------------------------------------------------------
 193 # Adding JPEG2000_CONFORMANCE_DATA_ROOT
 194 FIND_PATH(JPEG2000_CONFORMANCE_DATA_ROOT testimages.html
 195   ${OPENJPEG_SOURCE_DIR}/../jpeg2000testimages
 196   $ENV{JPEG2000_CONFORMANCE_DATA_ROOT}
 197 )
 198
 199 #-----------------------------------------------------------------------------
 200 # Compiler specific flags:
 201 IF(CMAKE_COMPILER_IS_GNUCC)
 202   # For all builds, make sure openjpeg is std99 compliant:
 203   # SET(CMAKE_C_FLAGS "-Wall -std=c99 ${CMAKE_C_FLAGS}") # FIXME: this setting prevented us from setting a coverage build.
 204   # Do not use ffast-math for all build, it would produce incorrect results, only set for release:
 205   SET(CMAKE_C_FLAGS_RELEASE "-ffast-math ${CMAKE_C_FLAGS_RELEASE}")
 206 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 207
 208 # install all targets referenced as OPENJPEGTargets
 209 install(EXPORT OpenJPEGTargets DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR})
 210 CONFIGURE_FILE( ${OPENJPEG_SOURCE_DIR}/CMake/OpenJPEGConfig.cmake.in
 211   ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 212   @ONLY
 213 )
 214 INSTALL( FILES ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 215   DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR}
 216 )
 217 # install CHANGES and LICENSE
 218 INSTALL(
 219   FILES       CHANGES
 220               LICENSE
 221   DESTINATION ${OPENJPEG_INSTALL_DOC_DIR})
 222 #
 223 FIND_FILE(HAVE_STRINGS_H_FOUND strings.h)
 224 IF(NOT HAVE_STRINGS_H_FOUND STREQUAL "HAVE_STRINGS_H_FOUND-NOTFOUND")
 225   FIND_FILE(HAVE_STRINGS_H strings.h)
 226   SET(HAS_STRINGS_H 1)
 227 ENDIF()
 228 FIND_FILE(HAVE_INTTYPES_H_FOUND inttypes.h)
 229 IF(NOT HAVE_INTTYPES_H_FOUND STREQUAL "HAVE_INTTYPES_H_FOUND-NOTFOUND")
 230   FIND_FILE(HAVE_INTTYPES_H inttypes.h)
 231   SET(HAS_INTTYPES_H 1)
 232 ENDIF()
 233 FIND_FILE(HAVE_MEMORY_H_FOUND memory.h)
 234 IF(NOT HAVE_MEMORY_H_FOUND STREQUAL "HAVE_MEMORY_H_FOUND-NOTFOUND")
 235   FIND_FILE(HAVE_MEMORY_H memory.h)
 236   SET(HAS_MEMORY_H 1)
 237 ENDIF()
 238 FIND_FILE(HAVE_STDINT_H_FOUND stdint.h)
 239 IF(NOT HAVE_STDINT_H_FOUND STREQUAL "HAVE_STDINT_H_FOUND-NOTFOUND")
 240   FIND_FILE(HAVE_STDINT_H stdint.h)
 241   SET(HAS_STDINT_H 1)
 242 ENDIF()
 243 FIND_FILE(HAVE_STDLIB_H_FOUND stdlib.h)
 244 IF(NOT HAVE_STDLIB_H_FOUND STREQUAL "HAVE_STDLIB_H_FOUND-NOTFOUND")
 245   FIND_FILE(HAVE_STDLIB_H stdlib.h)
 246   SET(HAS_STDLIB_H 1)
 247 ENDIF()
 248 FIND_FILE(HAVE_STRING_H_FOUND string.h)
 249 IF(NOT HAVE_STRING_H_FOUND STREQUAL "HAVE_STRING_H_FOUND-NOTFOUND")
 250   FIND_FILE(HAVE_STRING_H string.h)
 251   SET(HAS_STRING_H 1)
 252 ENDIF()
 253 FIND_FILE(HAVE_SYS_STAT_H_FOUND sys/stat.h)
 254 IF(NOT HAVE_SYS_STAT_H_FOUND STREQUAL "HAVE_SYS_STAT_H_FOUND-NOTFOUND")
 255   FIND_FILE(HAVE_SYS_STAT_H sys/stat.h)
 256   SET(HAS_SYS_STAT_H 1)
 257 ENDIF()
 258 FIND_FILE(HAVE_SYS_TYPES_H_FOUND sys/types.h)
 259 IF(NOT HAVE_SYS_TYPES_H_FOUND STREQUAL "HAVE_SYS_TYPES_H_FOUND-NOTFOUND")
 260   FIND_FILE(HAVE_SYS_TYPES_H sys/types.h)
 261   SET(HAS_SYS_TYPES_H 1)
 262 ENDIF()
 263 FIND_FILE(HAVE_UNISTD_H_FOUND unistd.h)
 264 IF(NOT HAVE_UNISTD_H_FOUND STREQUAL "HAVE_UNISTD_H_FOUND-NOTFOUND")
 265   FIND_FILE(HAVE_UNISTD_H unistd.h)
 266   SET(HAS_UNISTD_H 1)
 267 ENDIF()
 268 #
 269 IF(BUILD_CODEC OR BUILD_JPWL OR BUILD_MJ2)
 270 #
 271 #
 272 IF(UNIX OR CYGWIN)
 273  SET(CMAKE_INCLUDE_PATH /usr/include /usr/local/include /opt/include
 274         /opt/local/include /usr/include/libpng /usr/include/libpng14
 275         /usr/include/libpng12 /usr/local/include/libpng
 276         /usr/local/include/libpng14 /usr/local/include/libpng12
 277         /opt/include/libpng /opt/include/libpng14 /opt/include/libpng12
 278         /opt/local/include/libpng /opt/local/include/libpng14)
 279  SET(CMAKE_LIBRARY_PATH /usr/lib /usr/local/lib /opt/lib /opt/local/lib)
 280 ENDIF()
 281 #
 282  FIND_PACKAGE(ZLIB QUIET)
 283 #
 284  IF(ZLIB_LIBRARY STREQUAL "ZLIB_LIBRARY-NOTFOUND")
 285    SET(ZLIB_FOUND 0)
 286  ENDIF(ZLIB_LIBRARY STREQUAL "ZLIB_LIBRARY-NOTFOUND")
 287 #
 288  IF(ZLIB_FOUND)
 289    SET(HAVE_ZLIB_H 1)
 290    SET(HABE_LIBZ 1)
 291    SET(Z_LIBNAME ${ZLIB_LIBRARIES})
 292    SET(Z_INCLUDE_DIRNAME ${ZLIB_INCLUDE_DIR})
 293  ENDIF(ZLIB_FOUND)
 294 #
 295  FIND_PACKAGE(PNG QUIET)
 296 #
 297  IF(PNG_LIBRARY STREQUAL "PNG_LIBRARY-NOTFOUND")
 298    SET(PNG_FOUND 0)
 299  ENDIF(PNG_LIBRARY STREQUAL "PNG_LIBRARY-NOTFOUND")
 300 #
 301  IF(PNG_FOUND)
 302    SET(HAVE_PNG_H 1)
 303    SET(HAVE_LIBPNG 1)
 304    SET(PNG_LIBNAME ${PNG_LIBRARIES})
 305    SET(PNG_INCLUDE_DIRNAME ${PNG_INCLUDE_DIR})
 306  ENDIF(PNG_FOUND)
 307 #
 308  FIND_PACKAGE(TIFF QUIET)
 309 #
 310  IF(TIFF_LIBRARY STREQUAL "TIFF_LIBRARY-NOTFOUND")
 311    SET(TIFF_FOUND 0)
 312  ENDIF(TIFF_LIBRARY STREQUAL "TIFF_LIBRARY-NOTFOUND")
 313 #
 314  IF(TIFF_FOUND)
 315    SET(HAVE_TIFF_H 1)
 316    SET(HAVE_LIBTIFF 1)
 317    SET(TIFF_LIBNAME ${TIFF_LIBRARIES})
 318    SET(TIFF_INCLUDE_DIRNAME ${TIFF_INCLUDE_DIR})
 319  ENDIF(TIFF_FOUND)
 320 #
 321  FIND_PACKAGE(LCMS QUIET)
 322 #
 323  IF(LCMS_LIBRARY STREQUAL "LCMS_LIBRARY-NOTFOUND")
 324   SET(LCMS_FOUND 0)
 325  ENDIF(LCMS_LIBRARY STREQUAL "LCMS_LIBRARY-NOTFOUND")
 326 #
 327  IF(LCMS_FOUND)
 328   SET(HAVE_LCMS1_H 1)
 329   SET(HAVE_LCMS1_LIB 1)
 330   SET(LCMS_LIBNAME ${LCMS_LIBRARIES})
 331   SET(LCMS_INCLUDE_DIRNAME ${LCMS_INCLUDE_DIR})
 332  ENDIF(LCMS_FOUND)
 333 #
 334  IF(NOT LCMS_FOUND)
 335   FIND_PACKAGE(LCMS2 QUIET)
 336    IF(LCMS2_LIBRARY STREQUAL "LCMS2_LIBRARY-NOTFOUND")
 337     SET(LCMS2_FOUND 0)
 338   ENDIF(LCMS2_LIBRARY STREQUAL "LCMS2_LIBRARY-NOTFOUND")
 339 #
 340   IF(LCMS2_FOUND)
 341    SET(HAVE_LCMS2_H 1)
 342     SET(HAVE_LCMS2_LIB 1)
 343     SET(LCMS_LIBNAME ${LCMS2_LIBRARIES})
 344     SET(LCMS_INCLUDE_DIRNAME ${LCMS2_INCLUDE_DIR})
 345   ENDIF(LCMS2_FOUND)
 346  ENDIF(NOT LCMS_FOUND)
 347 #-------------------------------------------------------------
 348  OPTION(BUILD_THIRDPARTY "Build the thirdparty executables" ON)
 349 #
 350  IF(NOT ZLIB_FOUND OR NOT PNG_FOUND OR NOT TIFF_FOUND OR (NOT LCMS_FOUND AND NOT LCMS2_FOUND))
 351   IF(BUILD_THIRDPARTY)
 352    SET(HAVE_ZLIB_H 1)
 353    SET(HAVE_LIBZ 1)
 354    SET(HAVE_PNG_H 1)
 355    SET(HAVE_LIBPNG 1)
 356    SET(HAVE_TIFF_H 1)
 357    SET(HAVE_LIBTIFF 1)
 358    SET(HAVE_LCMS2_H 1)
 359    SET(HAVE_LIBLCMS2 1)
 360 #
 361    ADD_SUBDIRECTORY(${OPENJPEG_SOURCE_DIR}/thirdparty)
 362 #
 363    LINK_DIRECTORIES(${CMAKE_BINARY_DIR}/thirdparty/lib)
 364 #
 365    IF(NOT ZLIB_FOUND)
 366     INCLUDE_DIRECTORIES(${OPENJPEG_SOURCE_DIR}/thirdparty/include)
 367     SET(ZLIB_INCLUDE_DIRNAME ${OPENJPEG_SOURCE_DIR}/thirdparty/include)
 368     SET(Z_LIBNAME z)
 369     SET(ZLIB_FOUND 1)
 370    ENDIF(NOT ZLIB_FOUND)
 371 #
 372    IF(NOT PNG_FOUND)
 373     SET(PNG_INCLUDE_DIRNAME ${OPENJPEG_SOURCE_DIR}/thirdparty/libpng)
 374     SET(PNG_LIBNAME png)
 375     SET(PNG_FOUND 1)
 376    ENDIF(NOT PNG_FOUND)
 377 #
 378    IF(NOT LCMS_FOUND AND NOT LCMS2_FOUND)
 379     SET(LCMS_INCLUDE_DIRNAME ${OPENJPEG_SOURCE_DIR}/thirdparty/liblcms2/include)
 380     SET(LCMS_LIBNAME lcms2)
 381     SET(LCMS2_FOUND 1)
 382    ENDIF(NOT LCMS_FOUND AND NOT LCMS2_FOUND)
 383 #
 384    IF(NOT TIFF_FOUND)
 385     SET(TIFF_INCLUDE_DIRNAME ${OPENJPEG_SOURCE_DIR}/thirdparty/libtiff)
 386     SET(TIFF_LIBNAME tiff)
 387     SET(TIFF_FOUND 1)
 388    ENDIF(NOT TIFF_FOUND)
 389 #
 390   ENDIF(BUILD_THIRDPARTY)
 391  ENDIF(NOT ZLIB_FOUND OR NOT PNG_FOUND OR NOT TIFF_FOUND OR (NOT LCMS_FOUND AND NOT LCMS2_FOUND))
 392 #
 393 ENDIF(BUILD_CODEC OR BUILD_JPWL OR BUILD_MJ2)
 394 #
 395 IF(BUILD_CODEC)
 396  SUBDIRS(codec)
 397 ENDIF(BUILD_CODEC)
 398 #
 399 IF(BUILD_MJ2)
 400  SUBDIRS(mj2)
 401 ENDIF(BUILD_MJ2)
 402 #
 403 IF(BUILD_JPWL)
 404  SUBDIRS(jpwl)
 405 ENDIF(BUILD_JPWL)
 406 #
 407 IF(BUILD_JP3D)
 408  SUBDIRS(jp3d)
 409 ENDIF(BUILD_JP3D)
 410 #
 411 IF(BUILD_INDEXER_JPIP)
 412  SUBDIRS(indexer_JPIP)
 413 ENDIF(BUILD_INDEXER_JPIP)
 414 #
 415 IF(BUILD_DOC)
 416  SUBDIRS(doc)
 417 ENDIF(BUILD_DOC)
 418 #
 419 # generate opj_config.h
 420 CONFIGURE_FILE("${OPENJPEG_SOURCE_DIR}/opj_configh.cmake.in"
 421  "${OPENJPEG_BINARY_DIR}/opj_config.h"
 422  @ONLY
 423 )