CMakeLists.txt

   1 # Main CMakeLists.txt to build the OpenJPEG project using CMake (www.cmake.org)
   2 # Written by Mathieu Malaterre
   3
   4 # This CMake project will by default create a library called openjpeg
   5 # But if you want to use this project within your own (CMake) project
   6 # you will eventually like to prefix the library to avoid linking confusion
   7 # For this purpose you can define a CMake var: OPENJPEG_NAMESPACE to whatever you like
   8 # e.g.:
   9 # SET(OPENJPEG_NAMESPACE "GDCMOPENJPEG")
  10 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  11
  12 IF(COMMAND CMAKE_POLICY)
  13   CMAKE_POLICY(SET CMP0003 NEW)
  14 ENDIF(COMMAND CMAKE_POLICY)
  15
  16 IF(NOT OPENJPEG_NAMESPACE)
  17   SET(OPENJPEG_NAMESPACE "OPENJPEG")
  18   SET(OPENJPEG_STANDALONE 1)
  19 ENDIF(NOT OPENJPEG_NAMESPACE)
  20 # In all cases:
  21 STRING(TOLOWER ${OPENJPEG_NAMESPACE} OPENJPEG_LIBRARY_NAME)
  22
  23 PROJECT(${OPENJPEG_NAMESPACE} C)
  24
  25 # Do full dependency headers.
  26 INCLUDE_REGULAR_EXPRESSION("^.*$")
  27
  28 #-----------------------------------------------------------------------------
  29 # OPENJPEG version number, useful for packaging and doxygen doc:
  30 SET(OPENJPEG_VERSION_MAJOR 1)
  31 SET(OPENJPEG_VERSION_MINOR 4)
  32 SET(OPENJPEG_VERSION_BUILD 0)
  33 SET(OPENJPEG_VERSION
  34   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  35 SET(PACKAGE_VERSION
  36   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  37 SET(OPENJPEG_LIBRARY_PROPERTIES
  38   VERSION   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}"
  39   SOVERSION "${OPENJPEG_VERSION_MAJOR}"
  40 )
  41
  42 # On Visual Studio 8 MS deprecated C. This removes all 1.276E1265 security
  43 # warnings
  44 IF(WIN32)
  45   IF(NOT BORLAND)
  46     IF(NOT CYGWIN)
  47       IF(NOT MINGW)
  48         IF(NOT ITK_ENABLE_VISUAL_STUDIO_DEPRECATED_C_WARNINGS)
  49           ADD_DEFINITIONS(
  50             -D_CRT_FAR_MAPPINGS_NO_DEPRECATE
  51             -D_CRT_IS_WCTYPE_NO_DEPRECATE
  52             -D_CRT_MANAGED_FP_NO_DEPRECATE
  53             -D_CRT_NONSTDC_NO_DEPRECATE
  54             -D_CRT_SECURE_NO_DEPRECATE
  55             -D_CRT_SECURE_NO_DEPRECATE_GLOBALS
  56             -D_CRT_SETERRORMODE_BEEP_SLEEP_NO_DEPRECATE
  57             -D_CRT_TIME_FUNCTIONS_NO_DEPRECATE
  58             -D_CRT_VCCLRIT_NO_DEPRECATE
  59             -D_SCL_SECURE_NO_DEPRECATE
  60             )
  61         ENDIF(NOT ITK_ENABLE_VISUAL_STUDIO_DEPRECATED_C_WARNINGS)
  62       ENDIF(NOT MINGW)
  63     ENDIF(NOT CYGWIN)
  64   ENDIF(NOT BORLAND)
  65 ENDIF(WIN32)
  66
  67
  68 # --------------------------------------------------------------------------
  69 # Install directories
  70
  71 STRING(TOLOWER ${PROJECT_NAME} projectname)
  72 SET(OPENJPEG_INSTALL_SUBDIR "${projectname}-${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}")
  73
  74 IF(NOT OPENJPEG_INSTALL_BIN_DIR)
  75   SET(OPENJPEG_INSTALL_BIN_DIR "bin")
  76 ENDIF(NOT OPENJPEG_INSTALL_BIN_DIR)
  77
  78 IF(NOT OPENJPEG_INSTALL_LIB_DIR)
  79   SET(OPENJPEG_INSTALL_LIB_DIR "lib")
  80 ENDIF(NOT OPENJPEG_INSTALL_LIB_DIR)
  81
  82 IF(NOT OPENJPEG_INSTALL_DATA_DIR)
  83   SET(OPENJPEG_INSTALL_DATA_DIR "share/${OPENJPEG_INSTALL_SUBDIR}")
  84 ENDIF(NOT OPENJPEG_INSTALL_DATA_DIR)
  85
  86 IF(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
  87   SET(OPENJPEG_INSTALL_INCLUDE_DIR "include/")
  88 ENDIF(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
  89
  90 IF(NOT OPENJPEG_INSTALL_MAN_DIR)
  91   SET(OPENJPEG_INSTALL_MAN_DIR "share/man/")
  92 ENDIF(NOT OPENJPEG_INSTALL_MAN_DIR)
  93
  94 IF(NOT OPENJPEG_INSTALL_DOC_DIR)
  95   SET(OPENJPEG_INSTALL_DOC_DIR "share/doc/${OPENJPEG_INSTALL_SUBDIR}")
  96 ENDIF(NOT OPENJPEG_INSTALL_DOC_DIR)
  97
  98 IF(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
  99   SET(OPENJPEG_INSTALL_PACKAGE_DIR ${OPENJPEG_INSTALL_LIB_DIR}/${OPENJPEG_INSTALL_SUBDIR}
 100     CACHE INTERNAL "")
 101 ENDIF(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
 102
 103 #-----------------------------------------------------------------------------
 104 # Test for some required system information.
 105 INCLUDE (${CMAKE_ROOT}/Modules/CMakeBackwardCompatibilityC.cmake)
 106
 107 #-----------------------------------------------------------------------------
 108 # Test for getopt being available in this system
 109 INCLUDE (${OPENJPEG_SOURCE_DIR}/CMake/CheckHaveGetopt.cmake )
 110
 111 #-----------------------------------------------------------------------------
 112 # Setup file for setting custom ctest vars
 113 CONFIGURE_FILE(
 114   ${CMAKE_SOURCE_DIR}/CMake/CTestCustom.cmake.in
 115   ${CMAKE_BINARY_DIR}/CTestCustom.cmake
 116   @ONLY
 117   )
 118
 119 #-----------------------------------------------------------------------------
 120 # OpenJPEG build configuration options.
 121 OPTION(BUILD_SHARED_LIBS "Build OpenJPEG shared library and link executables against it." ON)
 122 SET (EXECUTABLE_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all executables.")
 123 SET (LIBRARY_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all libraries.")
 124 MARK_AS_ADVANCED(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
 125
 126 #-----------------------------------------------------------------------------
 127 # configure name mangling to allow multiple libraries to coexist
 128 # peacefully
 129 IF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 130 SET(MANGLE_PREFIX ${OPENJPEG_LIBRARY_NAME})
 131 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in
 132                ${CMAKE_CURRENT_BINARY_DIR}/openjpeg_mangle.h
 133                @ONLY IMMEDIATE)
 134 ENDIF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 135
 136 #-----------------------------------------------------------------------------
 137 # pkgconfig support
 138 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libopenjpeg1.pc.cmake ${CMAKE_CURRENT_BINARY_DIR}/libopenjpeg1.pc @ONLY)
 139 INSTALL( FILES  ${CMAKE_CURRENT_BINARY_DIR}/libopenjpeg1.pc DESTINATION ${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig )
 140 INSTALL( CODE
 141   "EXECUTE_PROCESS(COMMAND ${CMAKE_COMMAND} -E create_symlink \"libopenjpeg1.pc\" \"\$ENV{DESTDIR}${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig/libopenjpeg.pc\")")
 142
 143 #-----------------------------------------------------------------------------
 144 # Compiler specific flags:
 145 IF(CMAKE_COMPILER_IS_GNUCC)
 146   # For all builds, make sure openjpeg is std99 compliant:
 147   # SET(CMAKE_C_FLAGS "-Wall -std=c99 ${CMAKE_C_FLAGS}") # FIXME: this setting prevented us from setting a coverage build.
 148   # Do not use ffast-math for all build, it would produce incorrect results, only set for release:
 149   SET(CMAKE_C_FLAGS_RELEASE "-ffast-math ${CMAKE_C_FLAGS_RELEASE}")
 150 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 151
 152 #-----------------------------------------------------------------------------
 153 # opj_config.h generation
 154 FIND_FILE(HAVE_STRINGS_H_FOUND strings.h)
 155 IF(NOT HAVE_STRINGS_H_FOUND STREQUAL "HAVE_STRINGS_H_FOUND-NOTFOUND")
 156   FIND_FILE(HAVE_STRINGS_H strings.h)
 157   SET(HAS_STRINGS_H 1)
 158 ENDIF()
 159 FIND_FILE(HAVE_INTTYPES_H_FOUND inttypes.h)
 160 IF(NOT HAVE_INTTYPES_H_FOUND STREQUAL "HAVE_INTTYPES_H_FOUND-NOTFOUND")
 161   FIND_FILE(HAVE_INTTYPES_H inttypes.h)
 162   SET(HAS_INTTYPES_H 1)
 163 ENDIF()
 164 FIND_FILE(HAVE_MEMORY_H_FOUND memory.h)
 165 IF(NOT HAVE_MEMORY_H_FOUND STREQUAL "HAVE_MEMORY_H_FOUND-NOTFOUND")
 166   FIND_FILE(HAVE_MEMORY_H memory.h)
 167   SET(HAS_MEMORY_H 1)
 168 ENDIF()
 169 FIND_FILE(HAVE_STDINT_H_FOUND stdint.h)
 170 IF(NOT HAVE_STDINT_H_FOUND STREQUAL "HAVE_STDINT_H_FOUND-NOTFOUND")
 171   FIND_FILE(HAVE_STDINT_H stdint.h)
 172   SET(HAS_STDINT_H 1)
 173 ENDIF()
 174 FIND_FILE(HAVE_STDLIB_H_FOUND stdlib.h)
 175 IF(NOT HAVE_STDLIB_H_FOUND STREQUAL "HAVE_STDLIB_H_FOUND-NOTFOUND")
 176   FIND_FILE(HAVE_STDLIB_H stdlib.h)
 177   SET(HAS_STDLIB_H 1)
 178 ENDIF()
 179 FIND_FILE(HAVE_STRING_H_FOUND string.h)
 180 IF(NOT HAVE_STRING_H_FOUND STREQUAL "HAVE_STRING_H_FOUND-NOTFOUND")
 181   FIND_FILE(HAVE_STRING_H string.h)
 182   SET(HAS_STRING_H 1)
 183 ENDIF()
 184 FIND_FILE(HAVE_SYS_STAT_H_FOUND sys/stat.h)
 185 IF(NOT HAVE_SYS_STAT_H_FOUND STREQUAL "HAVE_SYS_STAT_H_FOUND-NOTFOUND")
 186   FIND_FILE(HAVE_SYS_STAT_H sys/stat.h)
 187   SET(HAS_SYS_STAT_H 1)
 188 ENDIF()
 189 FIND_FILE(HAVE_SYS_TYPES_H_FOUND sys/types.h)
 190 IF(NOT HAVE_SYS_TYPES_H_FOUND STREQUAL "HAVE_SYS_TYPES_H_FOUND-NOTFOUND")
 191   FIND_FILE(HAVE_SYS_TYPES_H sys/types.h)
 192   SET(HAS_SYS_TYPES_H 1)
 193 ENDIF()
 194 FIND_FILE(HAVE_UNISTD_H_FOUND unistd.h)
 195 IF(NOT HAVE_UNISTD_H_FOUND STREQUAL "HAVE_UNISTD_H_FOUND-NOTFOUND")
 196   FIND_FILE(HAVE_UNISTD_H unistd.h)
 197   SET(HAS_UNISTD_H 1)
 198 ENDIF()
 199 CONFIGURE_FILE("${OPENJPEG_SOURCE_DIR}/opj_configh.cmake.in"
 200  "${OPENJPEG_BINARY_DIR}/opj_config.h"
 201  @ONLY
 202  )
 203
 204 #-----------------------------------------------------------------------------
 205 # CDash+CMake : to be updated
 206 OPTION(BUILD_TESTING "Build the tests." OFF)
 207 IF(BUILD_TESTING)
 208   ENABLE_TESTING()
 209   INCLUDE(CTest)
 210 ENDIF(BUILD_TESTING)
 211
 212 #-----------------------------------------------------------------------------
 213 # Build Library
 214 INCLUDE_DIRECTORIES(BEFORE ${OPENJPEG_BINARY_DIR})
 215 ADD_SUBDIRECTORY(libopenjpeg)
 216
 217 #-----------------------------------------------------------------------------
 218 # Build Applications
 219 OPTION(BUILD_CODEC "Build the CODEC executables" ON)
 220 OPTION(BUILD_MJ2 "Build the MJ2 executables." OFF)
 221 ADD_SUBDIRECTORY(applications)
 222
 223 #-----------------------------------------------------------------------------
 224 # Build JPWL-flavoured library and executables
 225 OPTION(BUILD_JPWL "Build the JPWL library and executables" OFF)
 226
 227 #-----------------------------------------------------------------------------
 228 # Build DOCUMENTATION (not in ALL target and only if Doxygen is found)
 229 ADD_SUBDIRECTORY(doc)
 230
 231 #-----------------------------------------------------------------------------
 232 # Tests data
 233 IF(BUILD_TESTING)
 234 # Adding test with dataset from:
 235 # http://www.openjpeg.org/conformance/j2kp4files_v1_5.zip
 236 # -> wget http://www.openjpeg.org/conformance/j2kp4files_v1_5.zip
 237 # http://www.jpeg.org/jpeg2000guide/testimages/testimages.html
 238 # Adding JPEG2000_CONFORMANCE_DATA_ROOT
 239 FIND_PATH(JPEG2000_CONFORMANCE_DATA_ROOT testimages.html
 240   ${OPENJPEG_SOURCE_DIR}/../jpeg2000testimages
 241   $ENV{JPEG2000_CONFORMANCE_DATA_ROOT}
 242 )
 243 ENDIF(BUILD_TESTING)
 244
 245 #-----------------------------------------------------------------------------
 246 # install all targets referenced as OPENJPEGTargets
 247 INSTALL(EXPORT OpenJPEGTargets DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR})
 248 CONFIGURE_FILE( ${OPENJPEG_SOURCE_DIR}/CMake/OpenJPEGConfig.cmake.in
 249   ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 250   @ONLY
 251 )
 252 INSTALL( FILES ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 253   DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR}
 254 )
 255
 256 #-----------------------------------------------------------------------------
 257 # install CHANGES and LICENSE
 258 INSTALL(
 259   FILES       CHANGES
 260               LICENSE
 261   DESTINATION ${OPENJPEG_INSTALL_DOC_DIR})