CMakeLists.txt

   1 # Main CMakeLists.txt to build the OpenJPEG project using CMake (www.cmake.org)
   2 # Written by Mathieu Malaterre
   3
   4 # This CMake project will by default create a library called openjpeg
   5 # But if you want to use this project within your own (CMake) project
   6 # you will eventually like to prefix the library to avoid linking confusion
   7 # For this purpose you can define a CMake var: OPENJPEG_NAMESPACE to whatever you like
   8 # e.g.:
   9 # SET(OPENJPEG_NAMESPACE "GDCMOPENJPEG")
  10 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  11
  12 IF(COMMAND CMAKE_POLICY)
  13   CMAKE_POLICY(SET CMP0003 NEW)
  14 ENDIF(COMMAND CMAKE_POLICY)
  15
  16 IF(NOT OPENJPEG_NAMESPACE)
  17   SET(OPENJPEG_NAMESPACE "OPENJPEG")
  18   SET(OPENJPEG_STANDALONE 1)
  19 ENDIF(NOT OPENJPEG_NAMESPACE)
  20 # In all cases:
  21 STRING(TOLOWER ${OPENJPEG_NAMESPACE} OPENJPEG_LIBRARY_NAME)
  22
  23 PROJECT(${OPENJPEG_NAMESPACE} C)
  24
  25 # Do full dependency headers.
  26 INCLUDE_REGULAR_EXPRESSION("^.*$")
  27
  28 #-----------------------------------------------------------------------------
  29 # OPENJPEG version number, useful for packaging and doxygen doc:
  30 SET(OPENJPEG_VERSION_MAJOR 1)
  31 SET(OPENJPEG_VERSION_MINOR 99)
  32 SET(OPENJPEG_VERSION_BUILD 0)
  33 SET(OPENJPEG_VERSION
  34   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  35 SET(PACKAGE_VERSION
  36   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  37 SET(OPENJPEG_LIBRARY_PROPERTIES
  38   VERSION   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}"
  39   SOVERSION "${OPENJPEG_VERSION_MAJOR}"
  40 )
  41
  42 # --------------------------------------------------------------------------
  43 # Path to additional CMake modules
  44 SET(CMAKE_MODULE_PATH
  45     ${CMAKE_SOURCE_DIR}/CMake
  46     ${CMAKE_MODULE_PATH})
  47
  48 # --------------------------------------------------------------------------
  49 # On Visual Studio 8 MS deprecated C. This removes all 1.276E1265 security
  50 # warnings
  51 IF(WIN32)
  52   IF(NOT BORLAND)
  53     IF(NOT CYGWIN)
  54       IF(NOT MINGW)
  55         IF(NOT ITK_ENABLE_VISUAL_STUDIO_DEPRECATED_C_WARNINGS)
  56           ADD_DEFINITIONS(
  57             -D_CRT_FAR_MAPPINGS_NO_DEPRECATE
  58             -D_CRT_IS_WCTYPE_NO_DEPRECATE
  59             -D_CRT_MANAGED_FP_NO_DEPRECATE
  60             -D_CRT_NONSTDC_NO_DEPRECATE
  61             -D_CRT_SECURE_NO_DEPRECATE
  62             -D_CRT_SECURE_NO_DEPRECATE_GLOBALS
  63             -D_CRT_SETERRORMODE_BEEP_SLEEP_NO_DEPRECATE
  64             -D_CRT_TIME_FUNCTIONS_NO_DEPRECATE
  65             -D_CRT_VCCLRIT_NO_DEPRECATE
  66             -D_SCL_SECURE_NO_DEPRECATE
  67             )
  68         ENDIF(NOT ITK_ENABLE_VISUAL_STUDIO_DEPRECATED_C_WARNINGS)
  69       ENDIF(NOT MINGW)
  70     ENDIF(NOT CYGWIN)
  71   ENDIF(NOT BORLAND)
  72 ENDIF(WIN32)
  73
  74
  75 # --------------------------------------------------------------------------
  76 # Install directories
  77
  78 STRING(TOLOWER ${PROJECT_NAME} projectname)
  79 SET(OPENJPEG_INSTALL_SUBDIR "${projectname}-${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}")
  80
  81 IF(NOT OPENJPEG_INSTALL_BIN_DIR)
  82   SET(OPENJPEG_INSTALL_BIN_DIR "bin")
  83 ENDIF(NOT OPENJPEG_INSTALL_BIN_DIR)
  84
  85 IF(NOT OPENJPEG_INSTALL_LIB_DIR)
  86   SET(OPENJPEG_INSTALL_LIB_DIR "lib")
  87 ENDIF(NOT OPENJPEG_INSTALL_LIB_DIR)
  88
  89 IF(NOT OPENJPEG_INSTALL_SHARE_DIR)
  90   SET(OPENJPEG_INSTALL_SHARE_DIR "share")
  91 ENDIF(NOT OPENJPEG_INSTALL_SHARE_DIR)
  92
  93 IF(NOT OPENJPEG_INSTALL_DATA_DIR)
  94   SET(OPENJPEG_INSTALL_DATA_DIR "${OPENJPEG_INSTALL_SHARE_DIR}/${OPENJPEG_INSTALL_SUBDIR}")
  95 ENDIF(NOT OPENJPEG_INSTALL_DATA_DIR)
  96
  97 IF(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
  98   SET(OPENJPEG_INSTALL_INCLUDE_DIR "include/${OPENJPEG_INSTALL_SUBDIR}")
  99 ENDIF(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
 100
 101 IF(NOT OPENJPEG_INSTALL_MAN_DIR)
 102   SET(OPENJPEG_INSTALL_MAN_DIR "share/man/")
 103 ENDIF(NOT OPENJPEG_INSTALL_MAN_DIR)
 104
 105 IF(NOT OPENJPEG_INSTALL_DOC_DIR)
 106   SET(OPENJPEG_INSTALL_DOC_DIR "share/doc/${OPENJPEG_INSTALL_SUBDIR}")
 107 ENDIF(NOT OPENJPEG_INSTALL_DOC_DIR)
 108
 109 IF(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
 110   # We could install *.cmake files in share/ however those files contains
 111   # hardcoded path to libraries on a multi-arch system (fedora/debian) those
 112   # path will be different (lib/i386-linux-gnu vs lib/x86_64-linux-gnu)
 113   SET(OPENJPEG_INSTALL_PACKAGE_DIR "${OPENJPEG_INSTALL_LIB_DIR}/${OPENJPEG_INSTALL_SUBDIR}")
 114 ENDIF(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
 115
 116 #-----------------------------------------------------------------------------
 117 # Big endian test:
 118 INCLUDE (${CMAKE_ROOT}/Modules/TestBigEndian.cmake)
 119 TEST_BIG_ENDIAN(OPJ_BIG_ENDIAN)
 120
 121 #-----------------------------------------------------------------------------
 122 # Setup file for setting custom ctest vars
 123 CONFIGURE_FILE(
 124   ${CMAKE_SOURCE_DIR}/CMake/CTestCustom.cmake.in
 125   ${CMAKE_BINARY_DIR}/CTestCustom.cmake
 126   @ONLY
 127   )
 128
 129 #-----------------------------------------------------------------------------
 130 # OpenJPEG build configuration options.
 131 OPTION(BUILD_SHARED_LIBS "Build OpenJPEG shared library and link executables against it." ON)
 132 SET (EXECUTABLE_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all executables.")
 133 SET (LIBRARY_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all libraries.")
 134 MARK_AS_ADVANCED(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
 135
 136 #-----------------------------------------------------------------------------
 137 # configure name mangling to allow multiple libraries to coexist
 138 # peacefully
 139 IF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 140 SET(MANGLE_PREFIX ${OPENJPEG_LIBRARY_NAME})
 141 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in
 142                ${CMAKE_CURRENT_BINARY_DIR}/openjpeg_mangle.h
 143                @ONLY)
 144 ENDIF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 145
 146 #-----------------------------------------------------------------------------
 147 # pkgconfig support
 148 IF(UNIX)
 149   # install in lib and not share (see multi-arch note above)
 150   CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libopenjpeg1.pc.cmake
 151     ${CMAKE_CURRENT_BINARY_DIR}/libopenjpeg1.pc @ONLY)
 152   INSTALL( FILES  ${CMAKE_CURRENT_BINARY_DIR}/libopenjpeg1.pc DESTINATION
 153     ${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig )
 154   INSTALL( CODE "EXECUTE_PROCESS(COMMAND ${CMAKE_COMMAND} -E create_symlink
 155   \"libopenjpeg1.pc\"
 156   \"\$ENV{DESTDIR}${CMAKE_INSTALL_PREFIX}/${OPENJPEG_INSTALL_SHARE_DIR}/pkgconfig/libopenjpeg.pc\")")
 157 ENDIF(UNIX)
 158
 159 #-----------------------------------------------------------------------------
 160 # Compiler specific flags:
 161 IF(CMAKE_COMPILER_IS_GNUCC)
 162   # For all builds, make sure openjpeg is std99 compliant:
 163   # SET(CMAKE_C_FLAGS "-Wall -std=c99 ${CMAKE_C_FLAGS}") # FIXME: this setting prevented us from setting a coverage build.
 164   # Do not use ffast-math for all build, it would produce incorrect results, only set for release:
 165   SET(CMAKE_C_FLAGS_RELEASE "-ffast-math ${CMAKE_C_FLAGS_RELEASE}")
 166 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 167
 168 #-----------------------------------------------------------------------------
 169 # opj_config.h generation (1/2)
 170 INCLUDE (${CMAKE_ROOT}/Modules/CheckIncludeFile.cmake)
 171 CHECK_INCLUDE_FILE("strings.h"      HAVE_STRINGS_H)
 172 CHECK_INCLUDE_FILE("inttypes.h"     HAVE_INTTYPES_H)
 173 CHECK_INCLUDE_FILE("memory.h"       HAVE_MEMORY_H)
 174 CHECK_INCLUDE_FILE("stdint.h"       HAVE_STDINT_H)
 175 CHECK_INCLUDE_FILE("stdlib.h"       HAVE_STDLIB_H)
 176 CHECK_INCLUDE_FILE("string.h"       HAVE_STRING_H)
 177 CHECK_INCLUDE_FILE("sys/stat.h"     HAVE_SYS_STAT_H)
 178 CHECK_INCLUDE_FILE("sys/types.h"    HAVE_SYS_TYPES_H)
 179 CHECK_INCLUDE_FILE("unistd.h"       HAVE_UNISTD_H)
 180
 181 # Enable Large file support
 182 INCLUDE(TestLargeFiles)
 183 OPJ_TEST_LARGE_FILES(OPJ_HAVE_LARGEFILES)
 184
 185 #-----------------------------------------------------------------------------
 186 # Build Library
 187 INCLUDE_DIRECTORIES(BEFORE ${OPENJPEG_BINARY_DIR})
 188 ADD_SUBDIRECTORY(libopenjpeg)
 189
 190 #-----------------------------------------------------------------------------
 191 # Build Applications
 192 OPTION(BUILD_CODEC "Build the CODEC executables" ON)
 193 OPTION(BUILD_MJ2 "Build the MJ2 executables." OFF)
 194 OPTION(BUILD_JPWL "Build the JPWL library and executables" OFF)
 195 OPTION(BUILD_JPIP "Build the JPIP library and executables." OFF)
 196 IF(BUILD_JPIP)
 197   OPTION(BUILD_JPIP_SERVER "Build the JPIP server." OFF)
 198 ENDIF(BUILD_JPIP)
 199 OPTION(BUILD_VIEWER "Build the OPJViewer executable (C++)" OFF)
 200 OPTION(BUILD_JAVA "Build the openjpeg jar (Java)" OFF)
 201 MARK_AS_ADVANCED(BUILD_VIEWER)
 202 MARK_AS_ADVANCED(BUILD_JAVA)
 203
 204 IF(BUILD_CODEC OR BUILD_MJ2)
 205   # OFF: It will only build 3rd party libs if they are not found on the system
 206   # ON: 3rd party libs will ALWAYS be build, and used
 207   OPTION(BUILD_THIRDPARTY "Build the thirdparty executables if it is needed" OFF)
 208   ADD_SUBDIRECTORY(thirdparty)
 209   ADD_SUBDIRECTORY(applications)
 210 ENDIF (BUILD_CODEC OR BUILD_MJ2)
 211
 212 include(CheckTypeSize)
 213 CHECK_TYPE_SIZE(ssize_t     SSIZE_T)
 214
 215 #-----------------------------------------------------------------------------
 216 # opj_config.h generation (2/2)
 217 CONFIGURE_FILE("${OPENJPEG_SOURCE_DIR}/opj_config.h.cmake.in"
 218  "${OPENJPEG_BINARY_DIR}/opj_config.h"
 219  @ONLY
 220  )
 221
 222 #-----------------------------------------------------------------------------
 223 # Build DOCUMENTATION (not in ALL target and only if Doxygen is found)
 224 OPTION(BUILD_DOC "Build the HTML documentation (with doxygen if available)." OFF)
 225 IF(BUILD_DOC)
 226     ADD_SUBDIRECTORY(doc)
 227 ENDIF(BUILD_DOC)
 228
 229 #-----------------------------------------------------------------------------
 230 # Buld Testing
 231 OPTION(BUILD_TESTING "Build the tests." OFF)
 232 IF(BUILD_TESTING)
 233   IF(BUILD_CODEC)
 234     ENABLE_TESTING()
 235     INCLUDE(CTest)
 236
 237     # Search openjpeg data needed for the tests
 238     # They could be found via svn on the OpenJPEG google code project
 239     # svn checkout http://openjpeg.googlecode.com/svn/data (about 70 Mo)
 240     FIND_PATH(OPJ_DATA_ROOT README-OPJ-Data
 241       PATHS
 242       $ENV{OPJ_DATA_ROOT}
 243       ${CMAKE_SOURCE_DIR}/../data
 244       )
 245
 246     # Add repository where to find tests
 247     ADD_SUBDIRECTORY(tests)
 248
 249   ELSE(BUILD_CODEC)
 250     message(FATAL_ERROR "You need build codec to run the tests")
 251   ENDIF(BUILD_CODEC)
 252 ENDIF(BUILD_TESTING)
 253
 254 #-----------------------------------------------------------------------------
 255 # install all targets referenced as OPENJPEGTargets
 256 INSTALL(EXPORT OpenJPEGTargets DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR})
 257 CONFIGURE_FILE( ${OPENJPEG_SOURCE_DIR}/CMake/OpenJPEGConfig.cmake.in
 258   ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 259   @ONLY
 260 )
 261 INSTALL( FILES ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 262   DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR}
 263 )
 264
 265 #-----------------------------------------------------------------------------
 266 # install CHANGES and LICENSE
 267 IF(EXISTS ${OPENJPEG_SOURCE_DIR}/CHANGES)
 268   INSTALL(FILES CHANGES DESTINATION ${OPENJPEG_INSTALL_DOC_DIR})
 269 ENDIF(EXISTS ${OPENJPEG_SOURCE_DIR}/CHANGES)
 270 INSTALL(FILES LICENSE DESTINATION ${OPENJPEG_INSTALL_DOC_DIR})
 271
 272 INCLUDE (CMake/OpenJPEGCPack.cmake)