CMakeLists.txt

   1 # Main CMakeLists.txt to build the OpenJPEG project using CMake (www.cmake.org)
   2 # Written by Mathieu Malaterre
   3
   4 # This CMake project will by default create a library called openjpeg
   5 # But if you want to use this project within your own (CMake) project
   6 # you will eventually like to prefix the library to avoid linking confusion
   7 # For this purpose you can define a CMake var: OPENJPEG_NAMESPACE to whatever you like
   8 # e.g.:
   9 # SET(OPENJPEG_NAMESPACE "GDCMOPENJPEG")
  10 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  11
  12 IF(COMMAND CMAKE_POLICY)
  13   CMAKE_POLICY(SET CMP0003 NEW)
  14 ENDIF(COMMAND CMAKE_POLICY)
  15
  16 IF(NOT OPENJPEG_NAMESPACE)
  17   SET(OPENJPEG_NAMESPACE "OPENJPEG")
  18   SET(OPENJPEG_STANDALONE 1)
  19 ENDIF(NOT OPENJPEG_NAMESPACE)
  20 # In all cases:
  21 STRING(TOLOWER ${OPENJPEG_NAMESPACE} OPENJPEG_LIBRARY_NAME)
  22
  23 PROJECT(${OPENJPEG_NAMESPACE} C)
  24
  25 # Do full dependency headers.
  26 INCLUDE_REGULAR_EXPRESSION("^.*$")
  27
  28 #-----------------------------------------------------------------------------
  29 # OPENJPEG version number, useful for packaging and doxygen doc:
  30 SET(OPENJPEG_VERSION_MAJOR 1)
  31 SET(OPENJPEG_VERSION_MINOR 4)
  32 SET(OPENJPEG_VERSION_BUILD 0)
  33 SET(OPENJPEG_VERSION
  34   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  35
  36 # This setting of SOVERSION assumes that any API change
  37 # will increment either the minor or major version number of openjpeg
  38 SET(OPENJPEG_LIBRARY_PROPERTIES
  39   VERSION   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}"
  40   SOVERSION "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}"
  41 )
  42 # You will also need to define a value for the following variables:
  43 # OPENJPEG_INSTALL_BIN_DIR          - binary dir (executables)
  44 # OPENJPEG_INSTALL_LIB_DIR          - library dir (libs)
  45 # OPENJPEG_INSTALL_DATA_DIR         - share dir (say, examples, data, etc)
  46 # OPENJPEG_INSTALL_INCLUDE_DIR      - include dir (headers)
  47
  48 # --------------------------------------------------------------------------
  49 # Install directories
  50
  51 STRING(TOLOWER ${PROJECT_NAME} projectname)
  52 SET(subdir "${projectname}-${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}")
  53
  54 IF(NOT OPENJPEG_INSTALL_BIN_DIR)
  55   SET(OPENJPEG_INSTALL_BIN_DIR "bin")
  56 ENDIF(NOT OPENJPEG_INSTALL_BIN_DIR)
  57
  58 IF(NOT OPENJPEG_INSTALL_LIB_DIR)
  59   SET(OPENJPEG_INSTALL_LIB_DIR "lib")
  60 ENDIF(NOT OPENJPEG_INSTALL_LIB_DIR)
  61
  62 IF(NOT OPENJPEG_INSTALL_DATA_DIR)
  63   SET(OPENJPEG_INSTALL_DATA_DIR "share/${subdir}")
  64 ENDIF(NOT OPENJPEG_INSTALL_DATA_DIR)
  65
  66 IF(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
  67   SET(OPENJPEG_INSTALL_INCLUDE_DIR "include/${subdir}")
  68 ENDIF(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
  69
  70 IF(NOT OPENJPEG_INSTALL_DOC_DIR)
  71   SET(OPENJPEG_INSTALL_DOC_DIR "share/doc/${subdir}")
  72 ENDIF(NOT OPENJPEG_INSTALL_DOC_DIR)
  73
  74 IF(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
  75   SET(OPENJPEG_INSTALL_PACKAGE_DIR ${OPENJPEG_INSTALL_LIB_DIR}/${subdir}
  76     CACHE INTERNAL "")
  77 ENDIF(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
  78
  79 #-----------------------------------------------------------------------------
  80 # Test for some required system information.
  81 INCLUDE (${CMAKE_ROOT}/Modules/CMakeBackwardCompatibilityC.cmake)
  82
  83 #-----------------------------------------------------------------------------
  84 # Setup file for setting custom ctest vars
  85 CONFIGURE_FILE(
  86   ${CMAKE_CURRENT_SOURCE_DIR}/CMake/CTestCustom.cmake.in
  87   ${CMAKE_CURRENT_BINARY_DIR}/CTestCustom.cmake
  88   @ONLY
  89   )
  90
  91 #-----------------------------------------------------------------------------
  92 # OpenJPEG build configuration options.
  93 OPTION(BUILD_SHARED_LIBS "Build OpenJPEG with shared libraries." OFF)
  94
  95 #-----------------------------------------------------------------------------
  96 SET (EXECUTABLE_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all executables.")
  97 SET (LIBRARY_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all libraries.")
  98 MARK_AS_ADVANCED(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
  99
 100
 101 #-----------------------------------------------------------------------------
 102 # For the codec...
 103 OPTION(BUILD_EXAMPLES "Build the Examples (codec...)." ON)
 104
 105
 106 # configure name mangling to allow multiple libraries to coexist
 107 # peacefully
 108 IF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 109 SET(MANGLE_PREFIX ${OPENJPEG_LIBRARY_NAME})
 110 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in
 111                ${CMAKE_CURRENT_BINARY_DIR}/openjpeg_mangle.h
 112                @ONLY IMMEDIATE)
 113 ENDIF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 114
 115 #-----------------------------------------------------------------------------
 116 # Always build the library
 117 INCLUDE_DIRECTORIES(BEFORE ${CMAKE_CURRENT_BINARY_DIR})
 118 SUBDIRS(
 119   libopenjpeg
 120   mj2
 121   # cmake 2.4.5 has poor java support
 122   #j2kviewer/src
 123   )
 124
 125 IF(NOT UNIX)
 126 SUBDIRS(
 127   jpwl
 128   jp3d
 129   indexer_JPIP
 130   )
 131 ENDIF(NOT UNIX)
 132
 133 #-----------------------------------------------------------------------------
 134 # Build example only if requested
 135 IF(BUILD_EXAMPLES)
 136   SUBDIRS(codec)
 137 ENDIF(BUILD_EXAMPLES)
 138
 139 #-----------------------------------------------------------------------------
 140 # For the documentation
 141 OPTION(BUILD_DOCUMENTATION "Build the doxygen documentation" OFF)
 142 IF(BUILD_DOCUMENTATION)
 143   SUBDIRS(doc)
 144 ENDIF(BUILD_DOCUMENTATION)
 145
 146 #-----------------------------------------------------------------------------
 147 # For openjpeg team if they ever want CDash+CMake
 148 OPTION(BUILD_TESTING "Build the tests." OFF)
 149 IF(BUILD_TESTING)
 150   ENABLE_TESTING()
 151   INCLUDE(CTest)
 152 ENDIF(BUILD_TESTING)
 153
 154 # Adding test with dataset from:
 155 # http://www.crc.ricoh.com/~gormish/jpeg2000conformance/
 156 # -> wget http://www.crc.ricoh.com/~gormish/jpeg2000conformance/j2kp4files_v1_5.zip
 157 # http://www.jpeg.org/jpeg2000guide/testimages/testimages.html
 158 #-----------------------------------------------------------------------------
 159 # Adding JPEG2000_CONFORMANCE_DATA_ROOT
 160 FIND_PATH(JPEG2000_CONFORMANCE_DATA_ROOT testimages.html
 161   ${OPENJPEG_SOURCE_DIR}/../jpeg2000testimages
 162   $ENV{JPEG2000_CONFORMANCE_DATA_ROOT}
 163 )
 164
 165 #-----------------------------------------------------------------------------
 166 # Compiler specific flags:
 167 IF(CMAKE_COMPILER_IS_GNUCC)
 168   # For all builds, make sure openjpeg is std99 compliant:
 169   # SET(CMAKE_C_FLAGS "-Wall -std=c99 ${CMAKE_C_FLAGS}") # FIXME: this setting prevented us from setting a coverage build.
 170   # Do not use ffast-math for all build, it would produce incorrect results, only set for release:
 171   SET(CMAKE_C_FLAGS_RELEASE "-ffast-math ${CMAKE_C_FLAGS_RELEASE}")
 172 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 173
 174 # install all targets referenced as OPENJPEGTargets
 175 install(EXPORT OpenJPEGTargets DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR})
 176 CONFIGURE_FILE( ${OPENJPEG_SOURCE_DIR}/CMake/OpenJPEGConfig.cmake.in
 177   ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 178   @ONLY
 179 )
 180 INSTALL( FILES ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 181   DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR}
 182 )
 183