configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(RtAudio, 5.0.0, gary@music.mcgill.ca, rtaudio)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_SRCDIR(RtAudio.cpp)
   5 AC_CONFIG_FILES([rtaudio.pc Makefile tests/Makefile doc/Makefile doc/doxygen/Doxyfile])
   6 AM_INIT_AUTOMAKE([1.14 -Wall -Werror foreign subdir-objects])
   7
   8 # libtool version: current:revision:age
   9 #
  10 # If the library source code has changed at all since the last update, then
  11 # increment revision (`c:r:a' becomes `c:r+1:a').
  12 #
  13 # If any interfaces have been added, removed, or changed since the last update,
  14 # increment current, and set revision to 0.
  15 #
  16 # If any interfaces have been added since the last public release, then
  17 # increment age.
  18 #
  19 # If any interfaces have been removed since the last public release, then set
  20 # age to 0.
  21 m4_define([lt_current], 6)
  22 m4_define([lt_revision], 0)
  23 m4_define([lt_age], 0)
  24
  25 m4_define([lt_version_info], [lt_current:lt_revision:lt_age])
  26 m4_define([lt_current_minus_age], [m4_eval(lt_current - lt_age)])
  27
  28 SO_VERSION=lt_version_info
  29 AC_SUBST(SO_VERSION)
  30 AC_SUBST(api)
  31 AC_SUBST(req)
  32
  33 api=""
  34 req=""
  35
  36 # configure flags
  37 AC_ARG_ENABLE(debug, [AS_HELP_STRING([--enable-debug],[enable various debug output])])
  38 AC_ARG_WITH(jack, [AS_HELP_STRING([--with-jack], [choose JACK server support (mac and linux only)])])
  39 AC_ARG_WITH(alsa, [AS_HELP_STRING([--with-alsa], [choose native ALSA API support (linux only)])])
  40 AC_ARG_WITH(pulse, [AS_HELP_STRING([--with-pulse], [choose PulseAudio API support (linux only)])])
  41 AC_ARG_WITH(oss, [AS_HELP_STRING([--with-oss], [choose OSS API support (unixes)])])
  42 AC_ARG_WITH(core, [AS_HELP_STRING([--with-core], [choose CoreAudio API support (mac only)])])
  43 AC_ARG_WITH(asio, [AS_HELP_STRING([--with-asio], [choose ASIO API support (win32 only)])])
  44 AC_ARG_WITH(ds, [AS_HELP_STRING([--with-ds], [choose DirectSound API support (win32 only)])])
  45 AC_ARG_WITH(wasapi, [AS_HELP_STRING([--with-wasapi], [choose Windows Audio Session API support (win32 only)])])
  46
  47 # Check version number coherency between RtAudio.h and configure.ac
  48 AC_MSG_CHECKING([that version numbers are coherent])
  49 RTAUDIO_VERSION=`sed -n 's/#define RTAUDIO_VERSION "\(.*\)"/\1/p' $srcdir/RtAudio.h`
  50 AS_IF(
  51    [test "x$RTAUDIO_VERSION" != "x$PACKAGE_VERSION"],
  52    [AC_MSG_FAILURE([testing RTAUDIO_VERSION==PACKAGE_VERSION failed, check that RtAudio.h defines RTAUDIO_VERSION as "$PACKAGE_VERSION" or that the first line of configure.ac has been updated.])]
  53 )
  54 # Enable some nice automake features if they are available
  55 m4_ifdef([AM_MAINTAINER_MODE], [AM_MAINTAINER_MODE])
  56 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  57
  58 # Fill GXX with something before test.
  59 GXX="no"
  60 # if the user did not provide any CXXFLAGS, we can override them
  61 AS_IF([test "x$CXXFLAGS" = "x" ], [override_cxx=yes], [override_cxx=no])
  62 AS_IF([test "x$CFLAGS" = "x" ], [override_c=yes], [override_c=no])
  63
  64 dnl Check for pkg-config program, used for configuring some libraries.
  65 m4_define_default([PKG_PROG_PKG_CONFIG],
  66 [AC_MSG_CHECKING([pkg-config])
  67 AC_MSG_RESULT([no])])
  68
  69 PKG_PROG_PKG_CONFIG
  70
  71 dnl If the pkg-config autoconf support isn't installed, define its
  72 dnl autoconf macro to disable any packages depending on it.
  73 m4_define_default([PKG_CHECK_MODULES],
  74 [AC_MSG_CHECKING([$1])
  75 AC_MSG_RESULT([no])
  76 $4])
  77
  78
  79 # Checks for programs.
  80 AC_PROG_CXX(g++ CC c++ cxx)
  81 AM_PROG_AR
  82 AC_PATH_PROG(AR, ar, no)
  83 AS_IF([test "x${AR}" = "xno" ], [
  84     AC_MSG_ERROR([Could not find ar - needed to create a library])
  85 ])
  86
  87 # Initialize libtool
  88 LT_INIT([win32-dll])
  89 AC_CONFIG_MACRO_DIR([m4])
  90
  91 # Checks for header files.
  92 AC_HEADER_STDC
  93 AC_CHECK_HEADERS(sys/ioctl.h unistd.h)
  94
  95 # Check compiler and use -Wall if gnu
  96 AS_IF([test "x${GXX}" = "xyes" ], [
  97   CXXFLAGS="-Wall -Wextra ${CXXFLAGS}"
  98   AS_IF([ test "x${enable_debug}" = "xyes" ], [
  99     # Add -Werror in debug mode
 100     CXXFLAGS="-Werror ${CXXFLAGS}"
 101   ], [
 102     # hide private symbols in non-debug mode
 103     visibility="-fvisibility=hidden"
 104   ])
 105 ])
 106
 107 # Check for debug
 108 AC_MSG_CHECKING(whether to compile debug version)
 109 debugflags=""
 110 AS_CASE([${enable_debug}],
 111   [ yes ], [
 112     AC_MSG_RESULT([yes])
 113     AC_DEFINE([__RTAUDIO_DEBUG__])
 114     debugflags="${debugflags} -g -O0"
 115     object_path=Debug
 116   ],
 117   [ no ], [
 118     AC_MSG_RESULT([no!])
 119     debugflags="${debugflags} -O3"
 120   ], [
 121     AC_MSG_RESULT([no])
 122   ])
 123
 124 # For debugging and optimization ... overwrite default because it has both -g and -O2
 125 AS_IF([test "x$debugflags" != x],
 126   AS_IF([test "x$override_cxx" = "xyes" ], CXXFLAGS="$CXXFLAGS $debugflags", CXXFLAGS="$debugflags $CXXFLAGS")
 127   AS_IF([test "x$override_c" = "xyes" ], CFLAGS="$CFLAGS $debugflags", CFLAGS="$debugflags $CFLAGS")
 128   )
 129
 130
 131 # Checks for functions
 132 AC_CHECK_FUNC(gettimeofday, [cppflag="$cppflag -DHAVE_GETTIMEOFDAY"], )
 133
 134 # Checks for doxygen
 135 AC_CHECK_PROG( DOXYGEN, [doxygen], [doxygen] )
 136 AM_CONDITIONAL( MAKE_DOC, [test "x${DOXYGEN}" != x ] )
 137
 138 # Copy doc files to build dir if necessary
 139 AC_CONFIG_LINKS( [doc/release.txt:doc/release.txt] )
 140 AC_CONFIG_LINKS( [doc/doxygen/footer.html:doc/doxygen/footer.html] )
 141 AC_CONFIG_LINKS( [doc/doxygen/error.txt:doc/doxygen/error.txt] )
 142 AC_CONFIG_LINKS( [doc/doxygen/tutorial.txt:doc/doxygen/tutorial.txt] )
 143 AC_CONFIG_LINKS( [doc/doxygen/compiling.txt:doc/doxygen/compiling.txt] )
 144 AC_CONFIG_LINKS( [doc/doxygen/acknowledge.txt:doc/doxygen/acknowledge.txt] )
 145 AC_CONFIG_LINKS( [doc/doxygen/license.txt:doc/doxygen/license.txt] )
 146 AC_CONFIG_LINKS( [doc/doxygen/header.html:doc/doxygen/header.html] )
 147 AC_CONFIG_LINKS( [doc/doxygen/duplex.txt:doc/doxygen/duplex.txt] )
 148 AC_CONFIG_LINKS( [doc/doxygen/settings.txt:doc/doxygen/settings.txt] )
 149 AC_CONFIG_LINKS( [doc/doxygen/probe.txt:doc/doxygen/probe.txt] )
 150 AC_CONFIG_LINKS( [doc/doxygen/playback.txt:doc/doxygen/playback.txt] )
 151 AC_CONFIG_LINKS( [doc/doxygen/multi.txt:doc/doxygen/multi.txt] )
 152 AC_CONFIG_LINKS( [doc/doxygen/recording.txt:doc/doxygen/recording.txt] )
 153 AC_CONFIG_LINKS( [doc/doxygen/apinotes.txt:doc/doxygen/apinotes.txt] )
 154 AC_CONFIG_LINKS( [doc/images/mcgill.gif:doc/images/mcgill.gif] )
 155 AC_CONFIG_LINKS( [doc/images/ccrma.gif:doc/images/ccrma.gif] )
 156
 157 # Checks for package options and external software
 158 AC_CANONICAL_HOST
 159
 160 AC_MSG_CHECKING(for audio API)
 161
 162 AS_IF([test "x$with_jack" = "xyes"], [
 163   AC_MSG_RESULT(using JACK)
 164   AC_CHECK_LIB(jack, jack_client_open, , AC_MSG_ERROR(JACK support requires the jack library!))
 165   api="$api -D__UNIX_JACK__"
 166 ])
 167
 168 case $host in
 169   *-*-netbsd*)
 170   AS_IF([test "x$api" = "x"], [
 171     AC_MSG_RESULT(using OSS)
 172     api="$api -D__LINUX_OSS__"
 173     AC_CHECK_LIB(ossaudio, main, , AC_MSG_ERROR([RtAudio requires the ossaudio library]))
 174     AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR(RtAudio requires the pthread library!))
 175   ])
 176   ;;
 177
 178   *-*-freebsd*)
 179   AS_IF([test "x$api" = "x"], [
 180     AC_MSG_RESULT(using OSS)
 181     api="$api -D__LINUX_OSS__"
 182     AC_CHECK_LIB(ossaudio, main, , AC_MSG_ERROR([RtAudio requires the ossaudio library]))
 183     AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR(RtAudio requires the pthread library!))
 184   ])
 185   ;;
 186
 187   *-*-linux*)
 188   # Look for ALSA flag
 189   AS_IF([test "x$with_alsa" = "xyes"], [
 190     AC_MSG_RESULT(using ALSA)
 191     api="$api -D__LINUX_ALSA__"
 192     req="$req alsa"
 193     AC_CHECK_LIB(asound, snd_pcm_open, , AC_MSG_ERROR(ALSA support requires the asound library!))
 194   ])
 195
 196   # Look for PULSE flag
 197   AS_IF([test "x$with_pulse" = "xyes"], [
 198     AC_MSG_RESULT(using PulseAudio)
 199     api="$api -D__LINUX_PULSE__"
 200     req="$req libpulse-simple"
 201     AC_CHECK_LIB(pulse-simple, pa_simple_flush, , AC_MSG_ERROR(PulseAudio support requires the pulse-simple library!))
 202   ])
 203
 204   # Look for OSS flag
 205   AS_IF([test "x$with_oss" = "xyes"], [
 206     AC_MSG_RESULT(using OSS)
 207     api="$api -D__LINUX_OSS__"
 208   ])
 209
 210   # If no audio api flags specified, use ALSA
 211   AS_IF([test "x$api" = "x" ], [
 212     AC_MSG_RESULT(using ALSA)
 213     api="${api} -D__LINUX_ALSA__"
 214     req="${req} alsa"
 215     AC_CHECK_LIB(asound, snd_pcm_open, , AC_MSG_ERROR(ALSA support requires the asound library!))
 216   ])
 217   AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR(RtAudio requires the pthread library!))
 218   ;;
 219
 220   *-apple*)
 221   # Look for Core flag
 222   AS_IF([test "x$with_core" = "xyes"], [
 223     AC_MSG_RESULT(using CoreAudio)
 224     api="$api -D__MACOSX_CORE__"
 225     AC_CHECK_HEADER(CoreAudio/CoreAudio.h, [], [AC_MSG_ERROR(CoreAudio header files not found!)] )
 226     LIBS="$LIBS -framework CoreAudio -framework CoreFoundation"
 227   ])
 228
 229   # If no audio api flags specified, use CoreAudio
 230   AS_IF([test "x$api" = "x" ], [
 231     AC_MSG_RESULT(using CoreAudio)
 232     api="${api} -D__MACOSX_CORE__"
 233     AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 234       [],
 235       [AC_MSG_ERROR(CoreAudio header files not found!)] )
 236     LIBS="LIBS -framework CoreAudio -framework CoreFoundation"
 237   ])
 238
 239   AC_CHECK_LIB(pthread, pthread_create, , AC_MSG_ERROR(RtAudio requires the pthread library!))
 240   ;;
 241
 242   *-mingw32*)
 243   AS_IF([test "x$with_asio" = "xyes" ], [
 244     AC_MSG_RESULT(using ASIO)
 245     api="$api -D__WINDOWS_ASIO__"
 246     AC_SUBST( objects, ["asio.o asiodrivers.o asiolist.o iasiothiscallresolver.o"] )
 247   ])
 248
 249   # Look for DirectSound flag
 250   AS_IF([test "x$with_ds" = "xyes" ], [
 251     AC_MSG_RESULT(using DirectSound)
 252     api="$api -D__WINDOWS_DS__"
 253     LIBS="-ldsound -lwinmm $LIBS"
 254   ])
 255
 256   # Look for WASAPI flag
 257   AS_IF([test "x$with_wasapi" = "xyes"], [
 258     AC_MSG_RESULT(using WASAPI)
 259     api="$api -D__WINDOWS_WASAPI__"
 260     LIBS="-lwinmm -luuid -lksuser $LIBS"
 261   ])
 262
 263   # If no audio api flags specified, use DS
 264   AS_IF([test "x$api" = "x" ], [
 265     AC_MSG_RESULT(using DirectSound)
 266     api="$api -D__WINDOWS_DS__"
 267     LIBS="-ldsound -lwinmm $LIBS"
 268   ])
 269
 270   LIBS="-lole32 $LIBS"
 271   ;;
 272
 273   *)
 274   # Default case for unknown realtime systems.
 275   AC_MSG_ERROR(Unknown system type for realtime support!)
 276   ;;
 277 esac
 278
 279 CPPFLAGS="$CPPFLAGS $api"
 280
 281 AC_OUTPUT