libs/glibmm2/scripts/docgen.m4

   1
   2 ## GTKMM_DOXYGEN_INPUT_SUBDIRS(subdirectory list)
   3 ##
   4 AC_DEFUN([GTKMM_DOXYGEN_INPUT_SUBDIRS],
   5 [
   6 GTKMM_DOXYGEN_INPUT=
   7 gtkmm_srcdir=`cd "$srcdir" >/dev/null && pwd`
   8
   9 gtkmm_list="$@"
  10 for gtkmm_sublib in $gtkmm_list
  11 do
  12   GTKMM_DOXYGEN_INPUT="$GTKMM_DOXYGEN_INPUT ${gtkmm_srcdir}/${gtkmm_sublib}/${gtkmm_sublib}mm/"
  13 done
  14
  15 AC_SUBST(GTKMM_DOXYGEN_INPUT)
  16 ])
  17
  18
  19 ## GTKMM_ARG_ENABLE_FULLDOCS()
  20 ##
  21 ## Check whether to build the full docs into the generated source.  If yes,
  22 ## set GTKMMPROC_MERGECDOCS='--mergecdocs', which will be passed to gtkmmproc
  23 ## (in build_shared/Makefile_gensrc.am_fragment).  This will be much slower.
  24 ##
  25 AC_DEFUN([GTKMM_ARG_ENABLE_FULLDOCS],
  26 [
  27 AC_REQUIRE([GLIBMM_CHECK_PERL])
  28
  29 AC_MSG_CHECKING([[whether to merge C reference docs into generated headers]])
  30
  31 AC_ARG_ENABLE([fulldocs],
  32     [  --enable-fulldocs       Generate fully-documented reference docs, takes
  33                           longer to build.  [[default=enabled for CVS builds]]],
  34     [gtkmm_enable_fulldocs=$enableval],
  35     [gtkmm_enable_fulldocs=$USE_MAINTAINER_MODE])
  36
  37 AC_MSG_RESULT([${gtkmm_enable_fulldocs}])
  38
  39 GTKMMPROC_MERGECDOCS=
  40
  41 if test "x$gtkmm_enable_fulldocs" = xyes; then
  42 {
  43   GTKMMPROC_MERGECDOCS='--mergecdocs'
  44
  45   if test "x$USE_MAINTAINER_MODE" != xyes; then
  46   {
  47     AC_MSG_WARN([[
  48 *** --enable-fulldocs only works if --enable-maintainer-mode is also set.
  49 *** gtkmm source tarballs should be packaged with --enable-fulldocs, so
  50 *** usually you don't need this option unless you got gtkmm from CVS.
  51 ]])
  52   }
  53   fi
  54
  55   AC_CACHE_CHECK(
  56     [whether the XML::Parser module is available],
  57     [gtkmm_cv_have_xml_parser],
  58   [
  59     gtkmm_cv_have_xml_parser=no
  60     "$PERL_PATH" -e 'use strict; use XML::Parser; exit 0;' >&5 2>&5 && gtkmm_cv_have_xml_parser=yes
  61   ])
  62
  63   if test "x$gtkmm_cv_have_xml_parser" = xno; then
  64   {
  65     AC_MSG_ERROR([[
  66 *** The Perl module XML::Parser is required to build $PACKAGE from CVS.
  67 ]])
  68   }
  69   fi
  70 }
  71 fi
  72
  73 AC_SUBST(GTKMMPROC_MERGECDOCS)
  74 ])
  75