src/bin/jpip/CMakeLists.txt

   1 # Headers file are located here:
   2 include_directories(
   3   ${OPENJPEG_BINARY_DIR}/src/lib/openjp2 # opj_config.h
   4   ${OPENJPEG_SOURCE_DIR}/src/lib/openjp2
   5   ${OPENJPEG_SOURCE_DIR}/src/bin/common # opj_getopt.h
   6   ${OPENJPEG_SOURCE_DIR}/src/bin/jp2 # convert.h
   7   ${OPENJPEG_SOURCE_DIR}/src/lib/openjpip
   8   ${FCGI_INCLUDE_DIRS}
   9 )
  10
  11 # Tool to embed metadata into JP2 file
  12 add_executable(opj_jpip_addxml opj_jpip_addxml.c)
  13 # Install exe
  14 install(TARGETS opj_jpip_addxml
  15   EXPORT OpenJPEGTargets
  16   DESTINATION ${OPENJPEG_INSTALL_BIN_DIR} COMPONENT Applications
  17   )
  18
  19 if(BUILD_JPIP_SERVER)
  20   set(OPJ_SERVER_SRCS
  21   ${CMAKE_CURRENT_SOURCE_DIR}/opj_server.c
  22   )
  23
  24   # Build executable
  25   add_executable(opj_server ${OPJ_SERVER_SRCS})
  26   target_link_libraries(opj_server openjpip_server)
  27   set_property(
  28     TARGET opj_server
  29     APPEND PROPERTY
  30     COMPILE_DEFINITIONS SERVER QUIT_SIGNAL="quitJPIP"
  31     )
  32
  33   # On unix you need to link to the math library:
  34   if(UNIX)
  35     target_link_libraries(opj_server m)
  36   endif()
  37
  38   # Install exe
  39   install(TARGETS opj_server
  40     EXPORT OpenJPEGTargets
  41     DESTINATION ${OPENJPEG_INSTALL_BIN_DIR} COMPONENT Applications
  42     )
  43 endif()
  44
  45 set(EXES
  46   opj_dec_server
  47   opj_jpip_transcode
  48   opj_jpip_test
  49   opj_jpip_compress
  50   )
  51 foreach(exe ${EXES})
  52   if(${exe} STREQUAL "opj_jpip_compress")
  53     add_executable(${exe} ${exe}.c
  54       ${OPENJPEG_SOURCE_DIR}/src/bin/common/opj_getopt.c
  55       ${OPENJPEG_SOURCE_DIR}/src/bin/jp2/convert.c
  56     )
  57     target_link_libraries(${exe}
  58       ${PNG_LIBNAME} ${TIFF_LIBNAME} ${LCMS_LIBNAME}
  59     )
  60   else()
  61     add_executable(${exe} ${exe}.c)
  62   endif()
  63   target_link_libraries(${exe} openjpip)
  64   install(TARGETS ${exe}
  65     EXPORT OpenJPEGTargets
  66     DESTINATION ${OPENJPEG_INSTALL_BIN_DIR} COMPONENT Applications
  67     )
  68 endforeach()
  69
  70 # Build the two java clients:
  71 find_package(Java 1.5 COMPONENTS Development) # javac, jar
  72
  73 # Only build the java viewer if dev is found:
  74 if(Java_Development_FOUND AND Java_JAVAC_EXECUTABLE)
  75   set(jflags $ENV{JFLAGS})
  76   # search for package org.apache.xerces.parsers
  77   find_file(APACHE_XERCES_JAR
  78     NAMES xerces-j2.jar xercesImpl.jar
  79     PATHS /usr/share/java/
  80     NO_DEFAULT_PATH
  81     )
  82   mark_as_advanced(APACHE_XERCES_JAR)
  83
  84   # Decide to build the simple viewer or the xerces one:
  85   if(EXISTS ${APACHE_XERCES_JAR})
  86     configure_file(
  87       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer_xerces/dist/manifest.txt.in
  88       ${CMAKE_CURRENT_BINARY_DIR}/opj_viewer_xerces/dist/manifest.txt
  89       @ONLY
  90       )
  91     # build dep list:
  92     file(GLOB java2_srcs "opj_viewer_xerces/src/*.java")
  93
  94     # Need some common files:
  95     list(APPEND java2_srcs
  96       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/src/ImageManager.java
  97       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/src/ImgdecClient.java
  98       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/src/JPIPHttpClient.java
  99       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/src/MML.java
 100       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/src/PnmImage.java
 101       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/src/RegimViewer.java
 102       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/src/ResizeListener.java
 103       )
 104
 105     # make sure target javac dir exists:
 106     file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/classes2)
 107     # Build java
 108     add_custom_command(
 109       OUTPUT ${LIBRARY_OUTPUT_PATH}/opj_jpip_viewer.jar
 110       COMMAND ${Java_JAVAC_EXECUTABLE} ${jflags}
 111       -classpath ${APACHE_XERCES_JAR}
 112       ${java2_srcs} -d ${CMAKE_CURRENT_BINARY_DIR}/classes2
 113       COMMAND ${Java_JAR_EXECUTABLE} cfm ${LIBRARY_OUTPUT_PATH}/opj_jpip_viewer.jar
 114       ${CMAKE_CURRENT_BINARY_DIR}/opj_viewer_xerces/dist/manifest.txt
 115       -C ${CMAKE_CURRENT_BINARY_DIR}/classes2 .
 116       DEPENDS ${java2_srcs}
 117       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer_xerces/dist/manifest.txt.in
 118       COMMENT "javac *.java; jar cvf -> opj_viewer_xerces.jar"
 119       )
 120
 121     # name the target
 122     add_custom_target(OPJViewerXercesJar ALL
 123       DEPENDS ${LIBRARY_OUTPUT_PATH}/opj_jpip_viewer.jar
 124       COMMENT "building opj_jpip_viewer.jar (xerces)"
 125       )
 126
 127     install(FILES ${LIBRARY_OUTPUT_PATH}/opj_jpip_viewer.jar
 128       DESTINATION ${OPENJPEG_INSTALL_SHARE_DIR} COMPONENT JavaModule
 129       )
 130   else()
 131     # opj_viewer (simple, no xerces)
 132     # build dep list:
 133     file(GLOB java1_srcs "opj_viewer/src/*.java")
 134
 135     # make sure target javac dir exists:
 136     file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/classes1)
 137     # Build java
 138     add_custom_command(
 139       OUTPUT ${LIBRARY_OUTPUT_PATH}/opj_jpip_viewer.jar
 140       COMMAND ${Java_JAVAC_EXECUTABLE} ${jflags}
 141       ${java1_srcs} -d ${CMAKE_CURRENT_BINARY_DIR}/classes1
 142       COMMAND ${Java_JAR_EXECUTABLE} cfm ${LIBRARY_OUTPUT_PATH}/opj_jpip_viewer.jar
 143       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/dist/manifest.txt -C
 144       ${CMAKE_CURRENT_BINARY_DIR}/classes1 .
 145       DEPENDS ${java1_srcs}
 146       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/dist/manifest.txt
 147       COMMENT "javac *.java; jar cvf -> opj_jpip_viewer.jar"
 148       )
 149
 150     # name the target
 151     add_custom_target(OPJViewerJar ALL
 152       DEPENDS ${LIBRARY_OUTPUT_PATH}/opj_jpip_viewer.jar
 153       COMMENT "building opj_jpip_viewer.jar (no xerces found)"
 154       )
 155
 156     install(FILES ${LIBRARY_OUTPUT_PATH}/opj_jpip_viewer.jar
 157       DESTINATION ${OPENJPEG_INSTALL_SHARE_DIR} COMPONENT JavaModule
 158       )
 159   endif()
 160 else()
 161   message(WARNING "No java compiler found. Wont be able to build java viewer")
 162 endif()