src/bin/jpip/CMakeLists.txt

   1 # Headers file are located here:
   2 include_directories(
   3   ${OPENJPEG_BINARY_DIR}/src/lib/openjp2 # opj_config.h
   4   ${OPENJPEG_SOURCE_DIR}/src/lib/openjp2
   5   ${OPENJPEG_SOURCE_DIR}/src/lib/openjpip
   6   ${FCGI_INCLUDE_DIRS}
   7 )
   8
   9 # Tool to embed metadata into JP2 file
  10 add_executable(opj_jpip_addxml opj_jpip_addxml.c)
  11 # Install exe
  12 install(TARGETS opj_jpip_addxml
  13   EXPORT OpenJPEGTargets
  14   DESTINATION ${OPENJPEG_INSTALL_BIN_DIR} COMPONENT Applications
  15   )
  16
  17 if(BUILD_JPIP_SERVER)
  18
  19   set(OPJ_SERVER_SRCS
  20   ${CMAKE_CURRENT_SOURCE_DIR}/opj_server.c
  21   )
  22
  23   # Build executable
  24   add_executable(opj_server ${OPJ_SERVER_SRCS})
  25   target_link_libraries(opj_server openjpip_server)
  26   set_property(
  27     TARGET opj_server
  28     APPEND PROPERTY
  29     COMPILE_DEFINITIONS SERVER QUIT_SIGNAL="quitJPIP"
  30     )
  31
  32   # On unix you need to link to the math library:
  33   if(UNIX)
  34     target_link_libraries(opj_server m)
  35   endif()
  36
  37   # Install exe
  38   install(TARGETS opj_server
  39     EXPORT OpenJPEGTargets
  40     DESTINATION ${OPENJPEG_INSTALL_BIN_DIR} COMPONENT Applications
  41     )
  42 endif()
  43
  44 set(EXES
  45   opj_dec_server
  46   opj_jpip_transcode
  47   opj_jpip_test
  48   )
  49 foreach(exe ${EXES})
  50   add_executable(${exe} ${exe}.c)
  51   target_link_libraries(${exe} openjpip_local)
  52   install(TARGETS ${exe}
  53     EXPORT OpenJPEGTargets
  54     DESTINATION ${OPENJPEG_INSTALL_BIN_DIR} COMPONENT Applications
  55     )
  56 endforeach()
  57
  58 # Build the two java clients:
  59 find_package(Java 1.5 COMPONENTS Development) # javac, jar
  60
  61 # Only build the java viewer if dev is found:
  62 if(Java_Development_FOUND AND Java_JAVAC_EXECUTABLE)
  63   set(jflags $ENV{JFLAGS})
  64   # search for package org.apache.xerces.parsers
  65   find_file(APACHE_XERCES_JAR
  66     NAMES xerces-j2.jar xercesImpl.jar
  67     PATHS /usr/share/java/
  68     NO_DEFAULT_PATH
  69     )
  70   mark_as_advanced(APACHE_XERCES_JAR)
  71
  72   # Decide to build the simple viewer or the xerces one:
  73   if(EXISTS ${APACHE_XERCES_JAR})
  74     configure_file(
  75       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer_xerces/dist/manifest.txt.in
  76       ${CMAKE_CURRENT_BINARY_DIR}/opj_viewer_xerces/dist/manifest.txt
  77       @ONLY
  78       )
  79     # build dep list:
  80     file(GLOB java2_srcs "opj_viewer_xerces/src/*.java")
  81
  82     # Need some common files:
  83     list(APPEND java2_srcs
  84       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/src/ImageManager.java
  85       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/src/ImgdecClient.java
  86       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/src/JPIPHttpClient.java
  87       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/src/MML.java
  88       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/src/PnmImage.java
  89       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/src/RegimViewer.java
  90       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/src/ResizeListener.java
  91       )
  92
  93     # make sure target javac dir exists:
  94     file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/classes2)
  95     # Build java
  96     add_custom_command(
  97       OUTPUT ${LIBRARY_OUTPUT_PATH}/opj_jpip_viewer.jar
  98       COMMAND ${Java_JAVAC_EXECUTABLE} ${jflags}
  99       -classpath ${APACHE_XERCES_JAR}
 100       ${java2_srcs} -d ${CMAKE_CURRENT_BINARY_DIR}/classes2
 101       COMMAND ${Java_JAR_EXECUTABLE} cfm ${LIBRARY_OUTPUT_PATH}/opj_jpip_viewer.jar
 102       ${CMAKE_CURRENT_BINARY_DIR}/opj_viewer_xerces/dist/manifest.txt
 103       -C ${CMAKE_CURRENT_BINARY_DIR}/classes2 .
 104       DEPENDS ${java2_srcs}
 105       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer_xerces/dist/manifest.txt.in
 106       COMMENT "javac *.java; jar cvf -> opj_viewer_xerces.jar"
 107       )
 108
 109     # name the target
 110     add_custom_target(OPJViewerXercesJar ALL
 111       DEPENDS ${LIBRARY_OUTPUT_PATH}/opj_jpip_viewer.jar
 112       COMMENT "building opj_jpip_viewer.jar (xerces)"
 113       )
 114
 115     install(FILES ${LIBRARY_OUTPUT_PATH}/opj_jpip_viewer.jar
 116       DESTINATION ${OPENJPEG_INSTALL_SHARE_DIR} COMPONENT JavaModule
 117       )
 118   else()
 119     # opj_viewer (simple, no xerces)
 120     # build dep list:
 121     file(GLOB java1_srcs "opj_viewer/src/*.java")
 122
 123     # make sure target javac dir exists:
 124     file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/classes1)
 125     # Build java
 126     add_custom_command(
 127       OUTPUT ${LIBRARY_OUTPUT_PATH}/opj_jpip_viewer.jar
 128       COMMAND ${Java_JAVAC_EXECUTABLE} ${jflags}
 129       ${java1_srcs} -d ${CMAKE_CURRENT_BINARY_DIR}/classes1
 130       COMMAND ${Java_JAR_EXECUTABLE} cfm ${LIBRARY_OUTPUT_PATH}/opj_jpip_viewer.jar
 131       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/dist/manifest.txt -C
 132       ${CMAKE_CURRENT_BINARY_DIR}/classes1 .
 133       DEPENDS ${java1_srcs}
 134       ${CMAKE_CURRENT_SOURCE_DIR}/opj_viewer/dist/manifest.txt
 135       COMMENT "javac *.java; jar cvf -> opj_jpip_viewer.jar"
 136       )
 137
 138     # name the target
 139     add_custom_target(OPJViewerJar ALL
 140       DEPENDS ${LIBRARY_OUTPUT_PATH}/opj_jpip_viewer.jar
 141       COMMENT "building opj_jpip_viewer.jar (no xerces found)"
 142       )
 143
 144     install(FILES ${LIBRARY_OUTPUT_PATH}/opj_jpip_viewer.jar
 145       DESTINATION ${OPENJPEG_INSTALL_SHARE_DIR} COMPONENT JavaModule
 146       )
 147   endif()
 148 else()
 149   message(WARNING "No java compiler found. Wont be able to build java viewer")
 150 endif()