tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 cmake_minimum_required(VERSION 2.8.7)
   4
   5 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6
   7 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   8 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   9 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
  10
  11
  12 set(INPUT_NR_PATH ${INPUT_NR})
  13 set(TEMP_PATH ${TEMP})
  14 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  15
  16 # need kdu_expand if possible
  17 find_package(KAKADU)
  18 # need jpylyzer if possible
  19 find_package(JPYLYZER)
  20
  21 #########################################################################
  22 # GENERATION OF THE TEST SUITE (DUMP)
  23 # Dump all files with the selected extension inside the input directory
  24
  25 # technically opj_dump should simply parse these one, since syntax is ok.
  26 set(BLACKLIST_JPEG2000_TMP
  27     2539.pdf.SIGFPE.706.1712.jp2
  28     0290cb77c5df21828fa74cf2ab2c84d8.SIGFPE.d25.31.jp2
  29     26ccf3651020967f7778238ef5af08af.SIGFPE.d25.527.jp2
  30     4035.pdf.SIGSEGV.d8b.3375.jp2
  31     3635.pdf.asan.77.2930.jp2
  32     issue165.jp2
  33     #edf_c2_1103421.jp2
  34     edf_c2_1178956.jp2
  35     edf_c2_1000290.jp2
  36     #edf_c2_1000691.jp2 # ok
  37     #edf_c2_20.jp2 #looks ok as per kdu_jp2info
  38     edf_c2_1377017.jp2
  39     edf_c2_1002767.jp2
  40     edf_c2_10025.jp2
  41     edf_c2_1000234.jp2
  42     edf_c2_225881.jp2
  43     edf_c2_1000671.jp2
  44     #edf_c2_1013627.jp2 # weird box, but kdu_jp2info ok
  45     edf_c2_1015644.jp2
  46     edf_c2_101463.jp2
  47     edf_c2_1674177.jp2
  48     edf_c2_1673169.jp2
  49     issue418.jp2
  50     issue429.jp2
  51     issue427-null-image-size.jp2
  52     issue427-illegal-tile-offset.jp2
  53     issue495.jp2
  54     issue820.jp2
  55    )
  56
  57 # Define a list of file which should be gracefully rejected:
  58 set(BLACKLIST_JPEG2000
  59     ${BLACKLIST_JPEG2000_TMP}
  60     broken1.jp2
  61     broken2.jp2
  62     broken3.jp2
  63     broken4.jp2
  64     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  65     gdal_fuzzer_check_comp_dx_dy.jp2
  66     gdal_fuzzer_check_number_of_tiles.jp2
  67     gdal_fuzzer_unchecked_numresolutions.jp2
  68     mem-b2ace68c-1381.jp2
  69     1851.pdf.SIGSEGV.ce9.948.jp2
  70     1888.pdf.asan.35.988.jp2
  71     issue362-2863.jp2 #kdu_jp2info ok
  72     issue362-2866.jp2
  73     issue362-2894.jp2
  74     issue400.jp2 #kdu_jp2info ok
  75     issue364-38.jp2
  76     issue364-903.jp2 #kdu_jp2info ok
  77     issue393.jp2 #kdu_jp2info ok
  78     issue408.jp2 #kdu_jp2info ok
  79     issue420.jp2 #kdu_jp2info ok
  80     27ac957758a35d00d6765a0c86350d9c.SIGFPE.d25.537.jpc #kdu_jp2info crash
  81     3672da2f1f67bbecad27d7181b4e9d7c.SIGFPE.d25.805.jpc #kdu_jp2info crash
  82     issue476.jp2 #kdu_jp2info ok
  83     issue475.jp2 #kdu_jp2info ok
  84     issue413.jp2 #kdu_jp2info ok
  85     issue823.jp2 #kdu_jp2info ok
  86    )
  87
  88 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  89      "${INPUT_NR}/*.j2k"
  90      "${INPUT_NR}/*.j2c"
  91      "${INPUT_NR}/*.jp2"
  92      "${INPUT_NR}/*.jpc"
  93      #"${INPUT_NR}/*.jpx"
  94      )
  95
  96 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  97   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  98   #get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  99   # cannot use longest extension function, since some name contains multiples
 100   # dots. Instead write out own shortest extension function:
 101   string(FIND ${INPUT_FILENAME_NAME} "." SHORTEST_EXT_POS REVERSE)
 102   string(SUBSTRING ${INPUT_FILENAME_NAME} 0 ${SHORTEST_EXT_POS} INPUT_FILENAME_NAME_WE)
 103   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
 104
 105   # Dump the input image
 106   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
 107            COMMAND opj_dump
 108                -i ${INPUT_FILENAME}
 109                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
 110                -v
 111                )
 112
 113   if(bad_jpeg2000)
 114     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
 115                          PROPERTIES WILL_FAIL TRUE)
 116
 117   else()
 118
 119     # Compare the dump output with the baseline
 120     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
 121                 COMMAND compare_dump_files
 122             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
 123             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
 124             )
 125
 126     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
 127                          PROPERTIES DEPENDS
 128                          NR-${INPUT_FILENAME_NAME}-dump)
 129   endif()
 130
 131 endforeach()
 132
 133
 134 #########################################################################
 135 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
 136 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
 137 # to know which files processed and with which options.
 138
 139 # Configure the test suite file:
 140 configure_file("test_suite.ctest.in"
 141                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
 142                @ONLY)
 143
 144 # Read the file into a list
 145 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
 146
 147 # Try to find and configure and read another test suite file
 148 file(GLOB TEST_SUITE_FILES *.ctest.in)
 149 if (TEST_SUITE_FILES)
 150   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
 151
 152     # Avoid to process the official test suite
 153     set(FILE_ALREADY_READ 0)
 154     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
 155     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 156
 157     if(NOT FILE_ALREADY_READ)
 158       # Configure the additional test suite file:
 159       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 160       configure_file("${TEST_SUITE_FILE}"
 161                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 162                      @ONLY)
 163       # Read the additional file into a list
 164       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 165       # Append the list of command
 166       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 167
 168     endif()
 169
 170   endforeach()
 171
 172 else()
 173
 174   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 175
 176 endif()
 177
 178
 179 set(nonregression_filenames_used)
 180 # Parse the command line found in the file(s)
 181 set(IT_TEST_ENC 0)
 182 set(IT_TEST_DEC 0)
 183 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 184
 185   set(IGNORE_LINE_FOUND 0)
 186
 187   # Replace space by ; to generate a list
 188   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 189
 190   # Check if the first argument begin by the comment sign
 191   list(GET CMD_ARG_LIST 0 EXE_NAME)
 192
 193   if(EXE_NAME)
 194     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 195   endif()
 196
 197   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 198
 199     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 200
 201   else()
 202
 203     # Check if the first argument begin by the failed sign
 204     set(FAILED_TEST_FOUND 0)
 205     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 206
 207     if (FAILED_TEST_FOUND)
 208       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 209       set(FAILED_TEST_FOUND_1 0)
 210       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 211
 212       if (FAILED_TEST_FOUND_1)
 213
 214         list(REMOVE_AT CMD_ARG_LIST 0)
 215
 216       else ()
 217
 218         set(FAILED_TEST_FOUND_2 0)
 219         list(GET CMD_ARG_LIST 1 EXE_NAME)
 220         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 221
 222         if (FAILED_TEST_FOUND_2)
 223
 224           list(REMOVE_AT CMD_ARG_LIST 0)
 225           list(REMOVE_AT CMD_ARG_LIST 0)
 226
 227         else ()
 228
 229           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 230
 231         endif ()
 232       endif ()
 233
 234     else ()
 235       # Check if the first argument is equal to opj_compress
 236       string(REGEX MATCH "^opj_compress$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 237
 238       if(EXE_NAME_FOUND)
 239
 240         string(REGEX MATCH "opj_compress" ENC_TEST_FOUND ${EXE_NAME})
 241
 242       else()
 243
 244         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 245
 246       endif()
 247
 248       list(REMOVE_AT CMD_ARG_LIST 0)
 249
 250     endif ()
 251
 252     # Parse the argument list to find the input filename and output filename
 253     set(CMD_ARG_LIST_2 "")
 254     set(ARG_POS 0)
 255     set(INPUT_ARG_POS 0)
 256     set(OUTPUT_ARG_POS 0)
 257
 258     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 259
 260       math(EXPR ARG_POS "${ARG_POS}+1" )
 261
 262       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 263       if(INPUT_ARG_FOUND)
 264         set(INPUT_ARG_POS ${ARG_POS})
 265         set(INPUT_ARG_FOUND 0)
 266       endif()
 267
 268       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 269       if(OUTPUT_ARG_FOUND)
 270         set(OUTPUT_ARG_POS ${ARG_POS})
 271         set(OUTPUT_ARG_FOUND 0)
 272       endif()
 273
 274       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 275
 276     endforeach()
 277
 278     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 279     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 280     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 281     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 282     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 283
 284     #-----
 285     # Now we can add the test suite corresponding to a line command in the file
 286     #-----
 287     # ENCODER TEST SUITE
 288     if(ENC_TEST_FOUND)
 289         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 290
 291         # Encode an image into the jpeg2000 format
 292         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 293           COMMAND opj_compress
 294           ${CMD_ARG_LIST_2}
 295         )
 296
 297         if(FAILED_TEST_FOUND)
 298             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 299         else()
 300
 301           # Dump the encoding file
 302           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 303             COMMAND opj_dump
 304             -i ${OUTPUT_FILENAME}
 305             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 306           )
 307           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 308                                PROPERTIES DEPENDS
 309                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 310
 311           # Compare the dump file with the baseline
 312           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 313             COMMAND compare_dump_files
 314             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 315             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 316           )
 317
 318           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 319                                PROPERTIES DEPENDS
 320                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 321
 322           # Decode the encoding file with kakadu expand command
 323           if (KDU_EXPAND_EXECUTABLE)
 324             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 325               COMMAND ${KDU_EXPAND_EXECUTABLE}
 326               -i ${OUTPUT_FILENAME}
 327               -o ${OUTPUT_FILENAME}.raw
 328               )
 329
 330             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 331                                  PROPERTIES DEPENDS
 332                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 333
 334             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 335             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 336               COMMAND compare_raw_files
 337               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 338               -t ${OUTPUT_FILENAME}.raw
 339             )
 340
 341             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 342                                  PROPERTIES DEPENDS
 343                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 344
 345           endif()
 346
 347           # Test the encoded file is a valid JP2 file
 348           if (JPYLYZER_EXECUTABLE)
 349             if (${OUTPUT_FILENAME} MATCHES "\\.jp2$")
 350               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser
 351                 COMMAND ${JPYLYZER_EXECUTABLE}
 352                 ${OUTPUT_FILENAME}
 353                 )
 354               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser PROPERTIES
 355                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 356                 PASS_REGULAR_EXPRESSION "<isValidJP2>True</isValidJP2>"
 357                 )
 358             endif()
 359           endif(JPYLYZER_EXECUTABLE)
 360
 361           # If lossless compression (simple test is 4 arguments), decompress & compare
 362           list(LENGTH CMD_ARG_LIST_2 ARG_COUNT)
 363           if (ARG_COUNT EQUAL 4)
 364             # can we compare with the input image ?
 365             if (${INPUT_FILENAME_NAME} MATCHES "\\.tif$")
 366               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 367                 COMMAND opj_decompress -i ${OUTPUT_FILENAME} -o ${OUTPUT_FILENAME}.lossless.tif
 368                 )
 369               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode PROPERTIES
 370                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 371                 )
 372               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare
 373                 COMMAND compare_images -b ${INPUT_FILENAME} -t ${OUTPUT_FILENAME}.lossless.tif -n 1 -d
 374                 )
 375               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare PROPERTIES
 376                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 377                 )
 378             endif()
 379           endif()
 380       endif()
 381
 382     # DECODER TEST SUITE
 383     else()
 384       string(FIND ${INPUT_FILENAME} "nonregression" nr_pos)
 385       if(${nr_pos} GREATER 0)
 386         list(APPEND nonregression_filenames_used ${INPUT_FILENAME_NAME})
 387       endif()
 388       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 389
 390       # Decode the input image
 391       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 392         COMMAND opj_decompress
 393         ${CMD_ARG_LIST_2}
 394       )
 395
 396       if(FAILED_TEST_FOUND)
 397
 398         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 399
 400       else()
 401         # if not failed, check against registered md5:
 402         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 403           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 404           -DOUTFILENAME:STRING=${OUTPUT_FILENAME}
 405           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 406
 407         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5
 408           PROPERTIES DEPENDS NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 409         )
 410
 411 # FIXME: add a compare2base function base on raw which
 412 # can output png diff files if necessary
 413 #  add_test(NR-${filename}-compare2base
 414 #      ${EXECUTABLE_OUTPUT_PATH}/compare_images
 415 #     -b ${BASELINE_NR}/opj_${filenameRef}
 416 #     -t ${TEMP}/${filename}.pgx
 417 #     -n ${nbComponents}
 418 #     -d
 419 #     -s b_t_
 420 #     )
 421 #
 422 #  set_tests_properties(NR-${filename}-compare2base
 423 #                       PROPERTIES DEPENDS
 424 #                       NR-${filename}-decode)
 425
 426       endif()
 427
 428     endif()
 429
 430   endif()
 431
 432 endforeach()
 433
 434 set(existing_filenames)
 435 foreach(f ${OPJ_DATA_NR_LIST})
 436   get_filename_component(ff ${f} NAME)
 437   list(APPEND existing_filenames ${ff})
 438 endforeach()
 439 if(existing_filenames)
 440 list(REMOVE_ITEM existing_filenames ${nonregression_filenames_used})
 441 endif()
 442
 443 # keep track of new addition:
 444 # if we reach here, then a J2K files was added but no test is present in
 445 # test_suite.ctest.in:
 446 foreach(found_but_no_test ${existing_filenames})
 447   add_test(NAME Found-But-No-Test-${found_but_no_test} COMMAND ${CMAKE_COMMAND} -E echo "${found_but_no_test}")
 448   set_tests_properties(Found-But-No-Test-${found_but_no_test} PROPERTIES WILL_FAIL TRUE)
 449 endforeach()