tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   4
   5 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   7 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
   8
   9
  10 set(INPUT_NR_PATH ${INPUT_NR})
  11 set(TEMP_PATH ${TEMP})
  12 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  13
  14 # need kdu_expand if possible
  15 find_package(KAKADU)
  16
  17 #########################################################################
  18 # GENERATION OF THE TEST SUITE (DUMP)
  19 # Dump all files with the selected extension inside the input directory
  20
  21 # technically opj_dump should simply parse these one, since syntax is ok.
  22 set(BLACKLIST_JPEG2000_TMP
  23     2539.pdf.SIGFPE.706.1712.jp2
  24     0290cb77c5df21828fa74cf2ab2c84d8.SIGFPE.d25.31.jp2
  25     26ccf3651020967f7778238ef5af08af.SIGFPE.d25.527.jp2
  26     4035.pdf.SIGSEGV.d8b.3375.jp2
  27     3635.pdf.asan.77.2930.jp2
  28     issue165.jp2
  29    )
  30
  31 # Define a list of file which should be gracefully rejected:
  32 set(BLACKLIST_JPEG2000
  33     ${BLACKLIST_JPEG2000_TMP}
  34     broken.jp2
  35     broken2.jp2
  36     broken3.jp2
  37     broken4.jp2
  38     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  39     gdal_fuzzer_check_comp_dx_dy.jp2
  40     gdal_fuzzer_check_number_of_tiles.jp2
  41     gdal_fuzzer_unchecked_numresolutions.jp2
  42     mem-b2ace68c-1381.jp2
  43     1851.pdf.SIGSEGV.ce9.948.jp2
  44    )
  45
  46 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  47      "${INPUT_NR}/*.j2k"
  48      "${INPUT_NR}/*.j2c"
  49      "${INPUT_NR}/*.jp2"
  50      "${INPUT_NR}/*.jpc"
  51      #"${INPUT_NR}/*.jpx"
  52      )
  53
  54 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  55   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  56   #get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  57   # cannot use longest extension function, since some name contains multiples
  58   # dots. Instead write out own shortest extension function:
  59   string(FIND ${INPUT_FILENAME_NAME} "." SHORTEST_EXT_POS REVERSE)
  60   string(SUBSTRING ${INPUT_FILENAME_NAME} 0 ${SHORTEST_EXT_POS} INPUT_FILENAME_NAME_WE)
  61   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
  62
  63   # Dump the input image
  64   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
  65            COMMAND opj_dump
  66                -i ${INPUT_FILENAME}
  67                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
  68                -v
  69                )
  70
  71   if(bad_jpeg2000)
  72     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
  73                          PROPERTIES WILL_FAIL TRUE)
  74
  75   else()
  76
  77     # Compare the dump output with the baseline
  78     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
  79                 COMMAND compare_dump_files
  80             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
  81             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
  82             )
  83
  84     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
  85                          PROPERTIES DEPENDS
  86                          NR-${INPUT_FILENAME_NAME}-dump)
  87   endif()
  88
  89 endforeach()
  90
  91
  92 #########################################################################
  93 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
  94 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
  95 # to know which files processed and with which options.
  96
  97 # Configure the test suite file:
  98 configure_file("test_suite.ctest.in"
  99                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
 100                @ONLY)
 101
 102 # Read the file into a list
 103 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
 104
 105 # Try to find and configure and read another test suite file
 106 file(GLOB TEST_SUITE_FILES *.ctest.in)
 107 if (TEST_SUITE_FILES)
 108   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
 109
 110     # Avoid to process the official test suite
 111     set(FILE_ALREADY_READ 0)
 112     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
 113     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 114
 115     if(NOT FILE_ALREADY_READ)
 116       # Configure the additional test suite file:
 117       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 118       configure_file("${TEST_SUITE_FILE}"
 119                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 120                      @ONLY)
 121       # Read the additional file into a list
 122       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 123       # Append the list of command
 124       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 125
 126     endif()
 127
 128   endforeach()
 129
 130 else()
 131
 132   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 133
 134 endif()
 135
 136
 137 set(nonregression_filenames_used)
 138 # Parse the command line found in the file(s)
 139 set(IT_TEST_ENC 0)
 140 set(IT_TEST_DEC 0)
 141 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 142
 143   set(IGNORE_LINE_FOUND 0)
 144
 145   # Replace space by ; to generate a list
 146   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 147
 148   # Check if the first argument begin by the comment sign
 149   list(GET CMD_ARG_LIST 0 EXE_NAME)
 150
 151   if(EXE_NAME)
 152     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 153   endif()
 154
 155   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 156
 157     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 158
 159   else()
 160
 161     # Check if the first argument begin by the failed sign
 162     set(FAILED_TEST_FOUND 0)
 163     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 164
 165     if (FAILED_TEST_FOUND)
 166       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 167       set(FAILED_TEST_FOUND_1 0)
 168       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 169
 170       if (FAILED_TEST_FOUND_1)
 171
 172         list(REMOVE_AT CMD_ARG_LIST 0)
 173
 174       else ()
 175
 176         set(FAILED_TEST_FOUND_2 0)
 177         list(GET CMD_ARG_LIST 1 EXE_NAME)
 178         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 179
 180         if (FAILED_TEST_FOUND_2)
 181
 182           list(REMOVE_AT CMD_ARG_LIST 0)
 183           list(REMOVE_AT CMD_ARG_LIST 0)
 184
 185         else ()
 186
 187           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 188
 189         endif ()
 190       endif ()
 191
 192     else ()
 193       # Check if the first argument is equal to opj_compress
 194       string(REGEX MATCH "^opj_compress$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 195
 196       if(EXE_NAME_FOUND)
 197
 198         string(REGEX MATCH "opj_compress" ENC_TEST_FOUND ${EXE_NAME})
 199
 200       else()
 201
 202         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 203
 204       endif()
 205
 206       list(REMOVE_AT CMD_ARG_LIST 0)
 207
 208     endif ()
 209
 210     # Parse the argument list to find the input filename and output filename
 211     set(CMD_ARG_LIST_2 "")
 212     set(ARG_POS 0)
 213     set(INPUT_ARG_POS 0)
 214     set(OUTPUT_ARG_POS 0)
 215
 216     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 217
 218       math(EXPR ARG_POS "${ARG_POS}+1" )
 219
 220       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 221       if(INPUT_ARG_FOUND)
 222         set(INPUT_ARG_POS ${ARG_POS})
 223         set(INPUT_ARG_FOUND 0)
 224       endif()
 225
 226       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 227       if(OUTPUT_ARG_FOUND)
 228         set(OUTPUT_ARG_POS ${ARG_POS})
 229         set(OUTPUT_ARG_FOUND 0)
 230       endif()
 231
 232       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 233
 234     endforeach()
 235
 236     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 237     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 238     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 239     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 240     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 241
 242     #-----
 243     # Now we can add the test suite corresponding to a line command in the file
 244     #-----
 245     # ENCODER TEST SUITE
 246     if(ENC_TEST_FOUND)
 247         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 248
 249         # Encode an image into the jpeg2000 format
 250         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 251           COMMAND opj_compress
 252           ${CMD_ARG_LIST_2}
 253         )
 254
 255         if(FAILED_TEST_FOUND)
 256             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 257         else()
 258
 259           # Dump the encoding file
 260           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 261             COMMAND opj_dump
 262             -i ${OUTPUT_FILENAME}
 263             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 264           )
 265           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 266                                PROPERTIES DEPENDS
 267                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 268
 269           # Compare the dump file with the baseline
 270           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 271             COMMAND compare_dump_files
 272             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 273             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 274           )
 275
 276           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 277                                PROPERTIES DEPENDS
 278                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 279
 280           # Decode the encoding file with kakadu expand command
 281           if (KDU_EXPAND_EXECUTABLE)
 282             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 283               COMMAND ${KDU_EXPAND_EXECUTABLE}
 284               -i ${OUTPUT_FILENAME}
 285               -o ${OUTPUT_FILENAME}.raw
 286               )
 287
 288             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 289                                  PROPERTIES DEPENDS
 290                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 291
 292             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 293             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 294               COMMAND compare_raw_files
 295               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 296               -t ${OUTPUT_FILENAME}.raw
 297             )
 298
 299             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 300                                  PROPERTIES DEPENDS
 301                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 302
 303           endif()
 304       endif()
 305
 306     # DECODER TEST SUITE
 307     else()
 308       string(FIND ${INPUT_FILENAME} "nonregression" nr_pos)
 309       if(${nr_pos} GREATER 0)
 310         list(APPEND nonregression_filenames_used ${INPUT_FILENAME_NAME})
 311       endif()
 312       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 313
 314       # Decode the input image
 315       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 316         COMMAND opj_decompress
 317         ${CMD_ARG_LIST_2}
 318       )
 319
 320       if(FAILED_TEST_FOUND)
 321
 322         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 323
 324       else()
 325         # if not failed, check against registered md5:
 326         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 327           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 328           -DOUTFILENAME:STRING=${OUTPUT_FILENAME}
 329           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 330
 331         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5
 332           PROPERTIES DEPENDS NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 333         )
 334
 335 # FIXME: add a compare2base function base on raw which
 336 # can output png diff files if necesary
 337 #  add_test(NR-${filename}-compare2base
 338 #      ${EXECUTABLE_OUTPUT_PATH}/compare_images
 339 #     -b ${BASELINE_NR}/opj_${filenameRef}
 340 #     -t ${TEMP}/${filename}.pgx
 341 #     -n ${nbComponents}
 342 #     -d
 343 #     -s b_t_
 344 #     )
 345 #
 346 #  set_tests_properties(NR-${filename}-compare2base
 347 #                       PROPERTIES DEPENDS
 348 #                       NR-${filename}-decode)
 349
 350       endif()
 351
 352     endif()
 353
 354   endif()
 355
 356 endforeach()
 357
 358 set(existing_filenames)
 359 foreach(f ${OPJ_DATA_NR_LIST})
 360   get_filename_component(ff ${f} NAME)
 361   list(APPEND existing_filenames ${ff})
 362 endforeach()
 363 list(REMOVE_ITEM existing_filenames ${nonregression_filenames_used})
 364
 365 # keep track of new addition:
 366 # if we reach here, then a J2K files was added but no test is present in
 367 # test_suite.ctest.in:
 368 foreach(found_but_no_test ${existing_filenames})
 369   add_test(NAME Found-But-No-Test-${found_but_no_test} COMMAND ${CMAKE_COMMAND} -E echo "${found_but_no_test}")
 370   set_tests_properties(Found-But-No-Test-${found_but_no_test} PROPERTIES WILL_FAIL TRUE)
 371 endforeach()