tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   4
   5 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   7 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
   8
   9
  10 set(INPUT_NR_PATH ${INPUT_NR})
  11 set(TEMP_PATH ${TEMP})
  12 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  13
  14 # need kdu_expand if possible
  15 find_package(KAKADU)
  16
  17 #########################################################################
  18 # GENERATION OF THE TEST SUITE (DUMP)
  19 # Dump all files with the selected extension inside the input directory
  20
  21 # technically opj_dump should simply parse these one, since syntax is ok.
  22 set(BLACKLIST_JPEG2000_TMP
  23     2539.pdf.SIGFPE.706.1712.jp2
  24     0290cb77c5df21828fa74cf2ab2c84d8.SIGFPE.d25.31.jp2
  25     26ccf3651020967f7778238ef5af08af.SIGFPE.d25.527.jp2
  26     4035.pdf.SIGSEGV.d8b.3375.jp2
  27    )
  28
  29 # Define a list of file which should be gracefully rejected:
  30 set(BLACKLIST_JPEG2000
  31     ${BLACKLIST_JPEG2000_TMP}
  32     broken.jp2
  33     broken2.jp2
  34     broken3.jp2
  35     broken4.jp2
  36     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  37     gdal_fuzzer_check_comp_dx_dy.jp2
  38     gdal_fuzzer_check_number_of_tiles.jp2
  39     gdal_fuzzer_unchecked_numresolutions.jp2
  40     mem-b2ace68c-1381.jp2
  41     1851.pdf.SIGSEGV.ce9.948.jp2
  42    )
  43
  44 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  45      "${INPUT_NR}/*.j2k"
  46      "${INPUT_NR}/*.j2c"
  47      "${INPUT_NR}/*.jp2"
  48      #"${INPUT_NR}/*.jpx"
  49      )
  50
  51 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  52   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  53   #get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  54   # cannot use longest extension function, since some name contains multiples
  55   # dots. Instead write out own shortest extension function:
  56   string(FIND ${INPUT_FILENAME_NAME} "." SHORTEST_EXT_POS REVERSE)
  57   string(SUBSTRING ${INPUT_FILENAME_NAME} 0 ${SHORTEST_EXT_POS} INPUT_FILENAME_NAME_WE)
  58   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
  59
  60   # Dump the input image
  61   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
  62            COMMAND opj_dump
  63                -i ${INPUT_FILENAME}
  64                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
  65                -v
  66                )
  67
  68   if(bad_jpeg2000)
  69     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
  70                          PROPERTIES WILL_FAIL TRUE)
  71
  72   else()
  73
  74     # Compare the dump output with the baseline
  75     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
  76                 COMMAND compare_dump_files
  77             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
  78             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
  79             )
  80
  81     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
  82                          PROPERTIES DEPENDS
  83                          NR-${INPUT_FILENAME_NAME}-dump)
  84   endif()
  85
  86 endforeach()
  87
  88
  89 #########################################################################
  90 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
  91 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
  92 # to know which files processed and with which options.
  93
  94 # Configure the test suite file:
  95 configure_file("test_suite.ctest.in"
  96                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
  97                @ONLY)
  98
  99 # Read the file into a list
 100 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
 101
 102 # Try to find and configure and read another test suite file
 103 file(GLOB TEST_SUITE_FILES *.ctest.in)
 104 if (TEST_SUITE_FILES)
 105   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
 106
 107     # Avoid to process the official test suite
 108     set(FILE_ALREADY_READ 0)
 109     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
 110     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 111
 112     if(NOT FILE_ALREADY_READ)
 113       # Configure the additional test suite file:
 114       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 115       configure_file("${TEST_SUITE_FILE}"
 116                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 117                      @ONLY)
 118       # Read the additional file into a list
 119       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 120       # Append the list of command
 121       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 122
 123     endif()
 124
 125   endforeach()
 126
 127 else()
 128
 129   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 130
 131 endif()
 132
 133
 134 # Parse the command line found in the file(s)
 135 set(IT_TEST_ENC 0)
 136 set(IT_TEST_DEC 0)
 137 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 138
 139   set(IGNORE_LINE_FOUND 0)
 140
 141   # Replace space by ; to generate a list
 142   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 143
 144   # Check if the first argument begin by the comment sign
 145   list(GET CMD_ARG_LIST 0 EXE_NAME)
 146
 147   if(EXE_NAME)
 148     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 149   endif()
 150
 151   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 152
 153     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 154
 155   else()
 156
 157     # Check if the first argument begin by the failed sign
 158     set(FAILED_TEST_FOUND 0)
 159     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 160
 161     if (FAILED_TEST_FOUND)
 162       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 163       set(FAILED_TEST_FOUND_1 0)
 164       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 165
 166       if (FAILED_TEST_FOUND_1)
 167
 168         list(REMOVE_AT CMD_ARG_LIST 0)
 169
 170       else ()
 171
 172         set(FAILED_TEST_FOUND_2 0)
 173         list(GET CMD_ARG_LIST 1 EXE_NAME)
 174         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 175
 176         if (FAILED_TEST_FOUND_2)
 177
 178           list(REMOVE_AT CMD_ARG_LIST 0)
 179           list(REMOVE_AT CMD_ARG_LIST 0)
 180
 181         else ()
 182
 183           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 184
 185         endif ()
 186       endif ()
 187
 188     else ()
 189       # Check if the first argument is equal to opj_compress
 190       string(REGEX MATCH "^opj_compress$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 191
 192       if(EXE_NAME_FOUND)
 193
 194         string(REGEX MATCH "opj_compress" ENC_TEST_FOUND ${EXE_NAME})
 195
 196       else()
 197
 198         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 199
 200       endif()
 201
 202       list(REMOVE_AT CMD_ARG_LIST 0)
 203
 204     endif ()
 205
 206     # Parse the argument list to find the input filename and output filename
 207     set(CMD_ARG_LIST_2 "")
 208     set(ARG_POS 0)
 209     set(INPUT_ARG_POS 0)
 210     set(OUTPUT_ARG_POS 0)
 211
 212     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 213
 214       math(EXPR ARG_POS "${ARG_POS}+1" )
 215
 216       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 217       if(INPUT_ARG_FOUND)
 218         set(INPUT_ARG_POS ${ARG_POS})
 219         set(INPUT_ARG_FOUND 0)
 220       endif()
 221
 222       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 223       if(OUTPUT_ARG_FOUND)
 224         set(OUTPUT_ARG_POS ${ARG_POS})
 225         set(OUTPUT_ARG_FOUND 0)
 226       endif()
 227
 228       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 229
 230     endforeach()
 231
 232     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 233     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 234     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 235     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 236     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 237
 238     #-----
 239     # Now we can add the test suite corresponding to a line command in the file
 240     #-----
 241
 242     # ENCODER TEST SUITE
 243     if(ENC_TEST_FOUND)
 244         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 245
 246         # Encode an image into the jpeg2000 format
 247         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 248           COMMAND opj_compress
 249           ${CMD_ARG_LIST_2}
 250         )
 251
 252         if(FAILED_TEST_FOUND)
 253             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 254         else()
 255
 256           # Dump the encoding file
 257           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 258             COMMAND opj_dump
 259             -i ${OUTPUT_FILENAME}
 260             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 261           )
 262           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 263                                PROPERTIES DEPENDS
 264                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 265
 266           # Compare the dump file with the baseline
 267           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 268             COMMAND compare_dump_files
 269             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 270             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 271           )
 272
 273           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 274                                PROPERTIES DEPENDS
 275                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 276
 277           # Decode the encoding file with kakadu expand command
 278           if (KDU_EXPAND_EXECUTABLE)
 279             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 280               COMMAND ${KDU_EXPAND_EXECUTABLE}
 281               -i ${OUTPUT_FILENAME}
 282               -o ${OUTPUT_FILENAME}.raw
 283               )
 284
 285             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 286                                  PROPERTIES DEPENDS
 287                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 288
 289             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 290             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 291               COMMAND compareRAWimages
 292               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 293               -t ${OUTPUT_FILENAME}.raw
 294             )
 295
 296             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 297                                  PROPERTIES DEPENDS
 298                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 299
 300           endif()
 301       endif()
 302
 303     # DECODER TEST SUITE
 304     else()
 305       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 306
 307       # Decode the input image
 308       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 309         COMMAND opj_decompress
 310         ${CMD_ARG_LIST_2}
 311       )
 312
 313       if(FAILED_TEST_FOUND)
 314
 315         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 316
 317       else()
 318         # if not failed, check against registered md5:
 319         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 320           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 321           -DFILENAME:STRING=${INPUT_FILENAME_NAME}
 322           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 323
 324
 325 # FIXME: add a compare2base function base on raw which
 326 # can output png diff files if necesary
 327 #  add_test(NR-${filename}-compare2base
 328 #      ${EXECUTABLE_OUTPUT_PATH}/comparePGXimages
 329 #     -b ${BASELINE_NR}/opj_${filenameRef}
 330 #     -t ${TEMP}/${filename}.pgx
 331 #     -n ${nbComponents}
 332 #     -d
 333 #     -s b_t_
 334 #     )
 335 #
 336 #  set_tests_properties(NR-${filename}-compare2base
 337 #                       PROPERTIES DEPENDS
 338 #                       NR-${filename}-decode)
 339
 340       endif()
 341
 342     endif()
 343
 344   endif()
 345
 346 endforeach()