tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 cmake_minimum_required(VERSION 2.8.7)
   4
   5 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6
   7 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   8 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   9 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
  10
  11
  12 set(INPUT_NR_PATH ${INPUT_NR})
  13 set(TEMP_PATH ${TEMP})
  14 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  15
  16 # need kdu_expand if possible
  17 find_package(KAKADU)
  18 # need jpylyzer if possible
  19 find_package(JPYLYZER)
  20
  21 #########################################################################
  22 # GENERATION OF THE TEST SUITE (DUMP)
  23 # Dump all files with the selected extension inside the input directory
  24
  25 # technically opj_dump should simply parse these one, since syntax is ok.
  26 set(BLACKLIST_JPEG2000_TMP
  27     2539.pdf.SIGFPE.706.1712.jp2
  28     0290cb77c5df21828fa74cf2ab2c84d8.SIGFPE.d25.31.jp2
  29     26ccf3651020967f7778238ef5af08af.SIGFPE.d25.527.jp2
  30     4035.pdf.SIGSEGV.d8b.3375.jp2
  31     3635.pdf.asan.77.2930.jp2
  32     issue165.jp2
  33     #edf_c2_1103421.jp2
  34     edf_c2_1178956.jp2
  35     edf_c2_1000290.jp2
  36     #edf_c2_1000691.jp2 # ok
  37     #edf_c2_20.jp2 #looks ok as per kdu_jp2info
  38     edf_c2_1377017.jp2
  39     edf_c2_1002767.jp2
  40     edf_c2_10025.jp2
  41     edf_c2_1000234.jp2
  42     edf_c2_225881.jp2
  43     edf_c2_1000671.jp2
  44     #edf_c2_1013627.jp2 # weird box, but kdu_jp2info ok
  45     edf_c2_1015644.jp2
  46     edf_c2_101463.jp2
  47     edf_c2_1674177.jp2
  48     edf_c2_1673169.jp2
  49     issue418.jp2
  50     issue429.jp2
  51     issue427-null-image-size.jp2
  52     issue427-illegal-tile-offset.jp2
  53    )
  54
  55 # Define a list of file which should be gracefully rejected:
  56 set(BLACKLIST_JPEG2000
  57     ${BLACKLIST_JPEG2000_TMP}
  58     broken1.jp2
  59     broken2.jp2
  60     broken3.jp2
  61     broken4.jp2
  62     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  63     gdal_fuzzer_check_comp_dx_dy.jp2
  64     gdal_fuzzer_check_number_of_tiles.jp2
  65     gdal_fuzzer_unchecked_numresolutions.jp2
  66     mem-b2ace68c-1381.jp2
  67     1851.pdf.SIGSEGV.ce9.948.jp2
  68     1888.pdf.asan.35.988.jp2
  69     issue362-2863.jp2 #kdu_jp2info ok
  70     issue362-2866.jp2
  71     issue362-2894.jp2
  72     issue400.jp2 #kdu_jp2info ok
  73     issue364-38.jp2
  74     issue364-903.jp2 #kdu_jp2info ok
  75     issue393.jp2 #kdu_jp2info ok
  76     issue408.jp2 #kdu_jp2info ok
  77     issue420.jp2 #kdu_jp2info ok
  78     27ac957758a35d00d6765a0c86350d9c.SIGFPE.d25.537.jpc #kdu_jp2info crash
  79     3672da2f1f67bbecad27d7181b4e9d7c.SIGFPE.d25.805.jpc #kdu_jp2info crash
  80     issue476.jp2 #kdu_jp2info ok
  81     issue475.jp2 #kdu_jp2info ok
  82     issue413.jp2 #kdu_jp2info ok
  83    )
  84
  85 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  86      "${INPUT_NR}/*.j2k"
  87      "${INPUT_NR}/*.j2c"
  88      "${INPUT_NR}/*.jp2"
  89      "${INPUT_NR}/*.jpc"
  90      #"${INPUT_NR}/*.jpx"
  91      )
  92
  93 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  94   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  95   #get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  96   # cannot use longest extension function, since some name contains multiples
  97   # dots. Instead write out own shortest extension function:
  98   string(FIND ${INPUT_FILENAME_NAME} "." SHORTEST_EXT_POS REVERSE)
  99   string(SUBSTRING ${INPUT_FILENAME_NAME} 0 ${SHORTEST_EXT_POS} INPUT_FILENAME_NAME_WE)
 100   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
 101
 102   # Dump the input image
 103   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
 104            COMMAND opj_dump
 105                -i ${INPUT_FILENAME}
 106                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
 107                -v
 108                )
 109
 110   if(bad_jpeg2000)
 111     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
 112                          PROPERTIES WILL_FAIL TRUE)
 113
 114   else()
 115
 116     # Compare the dump output with the baseline
 117     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
 118                 COMMAND compare_dump_files
 119             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
 120             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
 121             )
 122
 123     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
 124                          PROPERTIES DEPENDS
 125                          NR-${INPUT_FILENAME_NAME}-dump)
 126   endif()
 127
 128 endforeach()
 129
 130
 131 #########################################################################
 132 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
 133 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
 134 # to know which files processed and with which options.
 135
 136 # Configure the test suite file:
 137 configure_file("test_suite.ctest.in"
 138                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
 139                @ONLY)
 140
 141 # Read the file into a list
 142 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
 143
 144 # Try to find and configure and read another test suite file
 145 file(GLOB TEST_SUITE_FILES *.ctest.in)
 146 if (TEST_SUITE_FILES)
 147   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
 148
 149     # Avoid to process the official test suite
 150     set(FILE_ALREADY_READ 0)
 151     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
 152     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 153
 154     if(NOT FILE_ALREADY_READ)
 155       # Configure the additional test suite file:
 156       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 157       configure_file("${TEST_SUITE_FILE}"
 158                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 159                      @ONLY)
 160       # Read the additional file into a list
 161       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 162       # Append the list of command
 163       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 164
 165     endif()
 166
 167   endforeach()
 168
 169 else()
 170
 171   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 172
 173 endif()
 174
 175
 176 set(nonregression_filenames_used)
 177 # Parse the command line found in the file(s)
 178 set(IT_TEST_ENC 0)
 179 set(IT_TEST_DEC 0)
 180 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 181
 182   set(IGNORE_LINE_FOUND 0)
 183
 184   # Replace space by ; to generate a list
 185   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 186
 187   # Check if the first argument begin by the comment sign
 188   list(GET CMD_ARG_LIST 0 EXE_NAME)
 189
 190   if(EXE_NAME)
 191     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 192   endif()
 193
 194   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 195
 196     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 197
 198   else()
 199
 200     # Check if the first argument begin by the failed sign
 201     set(FAILED_TEST_FOUND 0)
 202     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 203
 204     if (FAILED_TEST_FOUND)
 205       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 206       set(FAILED_TEST_FOUND_1 0)
 207       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 208
 209       if (FAILED_TEST_FOUND_1)
 210
 211         list(REMOVE_AT CMD_ARG_LIST 0)
 212
 213       else ()
 214
 215         set(FAILED_TEST_FOUND_2 0)
 216         list(GET CMD_ARG_LIST 1 EXE_NAME)
 217         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 218
 219         if (FAILED_TEST_FOUND_2)
 220
 221           list(REMOVE_AT CMD_ARG_LIST 0)
 222           list(REMOVE_AT CMD_ARG_LIST 0)
 223
 224         else ()
 225
 226           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 227
 228         endif ()
 229       endif ()
 230
 231     else ()
 232       # Check if the first argument is equal to opj_compress
 233       string(REGEX MATCH "^opj_compress$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 234
 235       if(EXE_NAME_FOUND)
 236
 237         string(REGEX MATCH "opj_compress" ENC_TEST_FOUND ${EXE_NAME})
 238
 239       else()
 240
 241         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 242
 243       endif()
 244
 245       list(REMOVE_AT CMD_ARG_LIST 0)
 246
 247     endif ()
 248
 249     # Parse the argument list to find the input filename and output filename
 250     set(CMD_ARG_LIST_2 "")
 251     set(ARG_POS 0)
 252     set(INPUT_ARG_POS 0)
 253     set(OUTPUT_ARG_POS 0)
 254
 255     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 256
 257       math(EXPR ARG_POS "${ARG_POS}+1" )
 258
 259       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 260       if(INPUT_ARG_FOUND)
 261         set(INPUT_ARG_POS ${ARG_POS})
 262         set(INPUT_ARG_FOUND 0)
 263       endif()
 264
 265       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 266       if(OUTPUT_ARG_FOUND)
 267         set(OUTPUT_ARG_POS ${ARG_POS})
 268         set(OUTPUT_ARG_FOUND 0)
 269       endif()
 270
 271       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 272
 273     endforeach()
 274
 275     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 276     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 277     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 278     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 279     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 280
 281     #-----
 282     # Now we can add the test suite corresponding to a line command in the file
 283     #-----
 284     # ENCODER TEST SUITE
 285     if(ENC_TEST_FOUND)
 286         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 287
 288         # Encode an image into the jpeg2000 format
 289         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 290           COMMAND opj_compress
 291           ${CMD_ARG_LIST_2}
 292         )
 293
 294         if(FAILED_TEST_FOUND)
 295             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 296         else()
 297
 298           # Dump the encoding file
 299           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 300             COMMAND opj_dump
 301             -i ${OUTPUT_FILENAME}
 302             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 303           )
 304           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 305                                PROPERTIES DEPENDS
 306                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 307
 308           # Compare the dump file with the baseline
 309           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 310             COMMAND compare_dump_files
 311             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 312             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 313           )
 314
 315           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 316                                PROPERTIES DEPENDS
 317                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 318
 319           # Decode the encoding file with kakadu expand command
 320           if (KDU_EXPAND_EXECUTABLE)
 321             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 322               COMMAND ${KDU_EXPAND_EXECUTABLE}
 323               -i ${OUTPUT_FILENAME}
 324               -o ${OUTPUT_FILENAME}.raw
 325               )
 326
 327             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 328                                  PROPERTIES DEPENDS
 329                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 330
 331             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 332             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 333               COMMAND compare_raw_files
 334               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 335               -t ${OUTPUT_FILENAME}.raw
 336             )
 337
 338             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 339                                  PROPERTIES DEPENDS
 340                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 341
 342           endif()
 343
 344           # Test the encoded file is a valid JP2 file
 345           if (JPYLYZER_EXECUTABLE)
 346             if (${OUTPUT_FILENAME} MATCHES "\\.jp2$")
 347               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser
 348                 COMMAND ${JPYLYZER_EXECUTABLE}
 349                 ${OUTPUT_FILENAME}
 350                 )
 351               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser PROPERTIES
 352                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 353                 PASS_REGULAR_EXPRESSION "<isValidJP2>True</isValidJP2>"
 354                 )
 355             endif()
 356           endif(JPYLYZER_EXECUTABLE)
 357
 358           # If lossless compression (simple test is 4 arguments), decompress & compare
 359           list(LENGTH CMD_ARG_LIST_2 ARG_COUNT)
 360           if (ARG_COUNT EQUAL 4)
 361             # can we compare with the input image ?
 362             if (${INPUT_FILENAME_NAME} MATCHES "\\.tif$")
 363               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 364                 COMMAND opj_decompress -i ${OUTPUT_FILENAME} -o ${OUTPUT_FILENAME}.lossless.tif
 365                 )
 366               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode PROPERTIES
 367                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 368                 )
 369               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare
 370                 COMMAND compare_images -b ${INPUT_FILENAME} -t ${OUTPUT_FILENAME}.lossless.tif -n 1 -d
 371                 )
 372               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare PROPERTIES
 373                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 374                 )
 375             endif()
 376           endif()
 377       endif()
 378
 379     # DECODER TEST SUITE
 380     else()
 381       string(FIND ${INPUT_FILENAME} "nonregression" nr_pos)
 382       if(${nr_pos} GREATER 0)
 383         list(APPEND nonregression_filenames_used ${INPUT_FILENAME_NAME})
 384       endif()
 385       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 386
 387       # Decode the input image
 388       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 389         COMMAND opj_decompress
 390         ${CMD_ARG_LIST_2}
 391       )
 392
 393       if(FAILED_TEST_FOUND)
 394
 395         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 396
 397       else()
 398         # if not failed, check against registered md5:
 399         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 400           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 401           -DOUTFILENAME:STRING=${OUTPUT_FILENAME}
 402           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 403
 404         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5
 405           PROPERTIES DEPENDS NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 406         )
 407
 408 # FIXME: add a compare2base function base on raw which
 409 # can output png diff files if necessary
 410 #  add_test(NR-${filename}-compare2base
 411 #      ${EXECUTABLE_OUTPUT_PATH}/compare_images
 412 #     -b ${BASELINE_NR}/opj_${filenameRef}
 413 #     -t ${TEMP}/${filename}.pgx
 414 #     -n ${nbComponents}
 415 #     -d
 416 #     -s b_t_
 417 #     )
 418 #
 419 #  set_tests_properties(NR-${filename}-compare2base
 420 #                       PROPERTIES DEPENDS
 421 #                       NR-${filename}-decode)
 422
 423       endif()
 424
 425     endif()
 426
 427   endif()
 428
 429 endforeach()
 430
 431 set(existing_filenames)
 432 foreach(f ${OPJ_DATA_NR_LIST})
 433   get_filename_component(ff ${f} NAME)
 434   list(APPEND existing_filenames ${ff})
 435 endforeach()
 436 if(existing_filenames)
 437 list(REMOVE_ITEM existing_filenames ${nonregression_filenames_used})
 438 endif()
 439
 440 # keep track of new addition:
 441 # if we reach here, then a J2K files was added but no test is present in
 442 # test_suite.ctest.in:
 443 foreach(found_but_no_test ${existing_filenames})
 444   add_test(NAME Found-But-No-Test-${found_but_no_test} COMMAND ${CMAKE_COMMAND} -E echo "${found_but_no_test}")
 445   set_tests_properties(Found-But-No-Test-${found_but_no_test} PROPERTIES WILL_FAIL TRUE)
 446 endforeach()