tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 cmake_minimum_required(VERSION 2.8.7)
   4
   5 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6
   7 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   8 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   9 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
  10
  11
  12 set(INPUT_NR_PATH ${INPUT_NR})
  13 set(TEMP_PATH ${TEMP})
  14 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  15
  16 # need kdu_expand if possible
  17 find_package(KAKADU)
  18 # need jpylyzer if possible
  19 find_package(JPYLYZER)
  20
  21 #########################################################################
  22 # GENERATION OF THE TEST SUITE (DUMP)
  23 # Dump all files with the selected extension inside the input directory
  24
  25 # technically opj_dump should simply parse these one, since syntax is ok.
  26 set(BLACKLIST_JPEG2000_TMP
  27     2539.pdf.SIGFPE.706.1712.jp2
  28     0290cb77c5df21828fa74cf2ab2c84d8.SIGFPE.d25.31.jp2
  29     26ccf3651020967f7778238ef5af08af.SIGFPE.d25.527.jp2
  30     4035.pdf.SIGSEGV.d8b.3375.jp2
  31     3635.pdf.asan.77.2930.jp2
  32     issue165.jp2
  33     #edf_c2_1103421.jp2
  34     edf_c2_1178956.jp2
  35     edf_c2_1000290.jp2
  36     #edf_c2_1000691.jp2 # ok
  37     edf_c2_1377017.jp2
  38     edf_c2_1002767.jp2
  39     edf_c2_10025.jp2
  40     edf_c2_1000234.jp2
  41     edf_c2_225881.jp2
  42     edf_c2_1000671.jp2
  43     #edf_c2_1013627.jp2 # weird box, but kdu_jp2info ok
  44     edf_c2_1015644.jp2
  45     edf_c2_101463.jp2
  46     edf_c2_1674177.jp2
  47     edf_c2_1673169.jp2
  48     issue418.jp2
  49     issue429.jp2
  50     issue427-null-image-size.jp2
  51     issue427-illegal-tile-offset.jp2
  52     issue495.jp2
  53     issue820.jp2
  54    )
  55
  56 # Define a list of file which should be gracefully rejected:
  57 set(BLACKLIST_JPEG2000
  58     ${BLACKLIST_JPEG2000_TMP}
  59     broken1.jp2
  60     broken2.jp2
  61     broken3.jp2
  62     broken4.jp2
  63     edf_c2_20.jp2 #may look ok as per kdu_jp2info, but inspection it reveals that the transformation value is out of range
  64     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  65     gdal_fuzzer_check_comp_dx_dy.jp2
  66     gdal_fuzzer_check_number_of_tiles.jp2
  67     gdal_fuzzer_unchecked_numresolutions.jp2
  68     mem-b2ace68c-1381.jp2
  69     1851.pdf.SIGSEGV.ce9.948.jp2
  70     1888.pdf.asan.35.988.jp2
  71     issue362-2863.jp2 #kdu_jp2info ok
  72     issue362-2866.jp2
  73     issue362-2894.jp2
  74     issue400.jp2 #kdu_jp2info ok
  75     issue364-38.jp2
  76     issue364-903.jp2 #kdu_jp2info ok
  77     issue393.jp2 #kdu_jp2info ok
  78     issue408.jp2 #kdu_jp2info ok
  79     issue420.jp2 #kdu_jp2info ok
  80     27ac957758a35d00d6765a0c86350d9c.SIGFPE.d25.537.jpc #kdu_jp2info crash
  81     3672da2f1f67bbecad27d7181b4e9d7c.SIGFPE.d25.805.jpc #kdu_jp2info crash
  82     issue475.jp2 #kdu_jp2info ok
  83     issue413.jp2 #kdu_jp2info ok
  84     issue823.jp2 #kdu_jp2info ok
  85     issue826.jp2 #inspection reveales that the transformation value is out of range
  86     oss-fuzz2785.jp2 #inspection reveales that the transformation value is out of range
  87    )
  88
  89 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  90      "${INPUT_NR}/*.j2k"
  91      "${INPUT_NR}/*.j2c"
  92      "${INPUT_NR}/*.jp2"
  93      "${INPUT_NR}/*.jpc"
  94      "${INPUT_NR}/*.jph"
  95      #"${INPUT_NR}/*.jpx"
  96      )
  97
  98 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  99   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 100   #get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 101   # cannot use longest extension function, since some name contains multiples
 102   # dots. Instead write out own shortest extension function:
 103   string(FIND ${INPUT_FILENAME_NAME} "." SHORTEST_EXT_POS REVERSE)
 104   string(SUBSTRING ${INPUT_FILENAME_NAME} 0 ${SHORTEST_EXT_POS} INPUT_FILENAME_NAME_WE)
 105   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
 106
 107   # Dump the input image
 108   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
 109            COMMAND opj_dump
 110                -i ${INPUT_FILENAME}
 111                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
 112                -v
 113                )
 114
 115   if(bad_jpeg2000)
 116     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
 117                          PROPERTIES WILL_FAIL TRUE)
 118
 119   else()
 120
 121     # Compare the dump output with the baseline
 122     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
 123                 COMMAND compare_dump_files
 124             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
 125             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
 126             )
 127
 128     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
 129                          PROPERTIES DEPENDS
 130                          NR-${INPUT_FILENAME_NAME}-dump)
 131   endif()
 132
 133 endforeach()
 134
 135
 136 #########################################################################
 137 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
 138 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
 139 # to know which files processed and with which options.
 140
 141 # Configure the test suite file:
 142 configure_file("test_suite.ctest.in"
 143                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
 144                @ONLY)
 145
 146 # Read the file into a list
 147 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
 148
 149 # Try to find and configure and read another test suite file
 150 file(GLOB TEST_SUITE_FILES *.ctest.in)
 151 if (TEST_SUITE_FILES)
 152   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
 153
 154     # Avoid to process the official test suite
 155     set(FILE_ALREADY_READ 0)
 156     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
 157     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 158
 159     if(NOT FILE_ALREADY_READ)
 160       # Configure the additional test suite file:
 161       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 162       configure_file("${TEST_SUITE_FILE}"
 163                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 164                      @ONLY)
 165       # Read the additional file into a list
 166       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 167       # Append the list of command
 168       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 169
 170     endif()
 171
 172   endforeach()
 173
 174 else()
 175
 176   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 177
 178 endif()
 179
 180
 181 set(nonregression_filenames_used)
 182 # Parse the command line found in the file(s)
 183 set(IT_TEST_ENC 0)
 184 set(IT_TEST_DEC 0)
 185 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 186
 187   set(IGNORE_LINE_FOUND 0)
 188
 189   # Replace space by ; to generate a list
 190   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 191
 192   # Check if the first argument begin by the comment sign
 193   list(GET CMD_ARG_LIST 0 EXE_NAME)
 194
 195   if(EXE_NAME)
 196     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 197   endif()
 198
 199   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 200
 201     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 202
 203   else()
 204
 205     # Check if the first argument begin by the failed sign
 206     set(FAILED_TEST_FOUND 0)
 207     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 208
 209     if (FAILED_TEST_FOUND)
 210       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 211       set(FAILED_TEST_FOUND_1 0)
 212       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 213
 214       if (FAILED_TEST_FOUND_1)
 215
 216         list(REMOVE_AT CMD_ARG_LIST 0)
 217
 218       else ()
 219
 220         set(FAILED_TEST_FOUND_2 0)
 221         list(GET CMD_ARG_LIST 1 EXE_NAME)
 222         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 223
 224         if (FAILED_TEST_FOUND_2)
 225
 226           list(REMOVE_AT CMD_ARG_LIST 0)
 227           list(REMOVE_AT CMD_ARG_LIST 0)
 228
 229         else ()
 230
 231           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 232
 233         endif ()
 234       endif ()
 235
 236     else ()
 237       # Check if the first argument is equal to opj_compress
 238       string(REGEX MATCH "^opj_compress$|^opj_compress_no_raw$|^opj_compress_no_raw_lossless$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 239
 240       if(EXE_NAME_FOUND)
 241
 242         string(REGEX MATCH "^opj_compress$|^opj_compress_no_raw$|^opj_compress_no_raw_lossless$" ENC_TEST_FOUND ${EXE_NAME})
 243         string(REGEX MATCH "^opj_compress_no_raw$|^opj_compress_no_raw_lossless$" NO_RAW ${EXE_NAME})
 244         string(REGEX MATCH "opj_compress_no_raw_lossless" LOSSLESS ${EXE_NAME})
 245
 246       else()
 247
 248         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 249
 250       endif()
 251
 252       list(REMOVE_AT CMD_ARG_LIST 0)
 253
 254       if(ENC_TEST_FOUND)
 255
 256         # Parse lines like opj_compress lossy-check { -n 3 -m 0:0:0 -p 0:0:0 } ...
 257         set(LOSSY_CHECK_ARG_LIST "")
 258         list(GET CMD_ARG_LIST 0 NEXT_ARG)
 259         string(REGEX MATCH "^lossy-check$" LOSSY_CHECK ${NEXT_ARG})
 260         if(LOSSY_CHECK)
 261             list(REMOVE_AT CMD_ARG_LIST 0)
 262             list(GET CMD_ARG_LIST 0 NEXT_ARG)
 263             string(REGEX MATCH "^{$" FOUND_OPEN_CURL ${NEXT_ARG})
 264             if(NOT FOUND_OPEN_CURL)
 265                 message( FATAL_ERROR "'{' expected after lossy-check")
 266             endif()
 267             list(REMOVE_AT CMD_ARG_LIST 0)
 268             while(TRUE)
 269                 list(GET CMD_ARG_LIST 0 NEXT_ARG)
 270                 list(REMOVE_AT CMD_ARG_LIST 0)
 271                 string(REGEX MATCH "^}$" FOUND_CLOSE_CURL ${NEXT_ARG})
 272                 if(FOUND_CLOSE_CURL)
 273                     break()
 274                 endif()
 275                 list (APPEND LOSSY_CHECK_ARG_LIST ${NEXT_ARG})
 276             endwhile()
 277         endif()
 278       endif()
 279
 280     endif ()
 281
 282     # Parse the argument list to find the input filename and output filename
 283     set(CMD_ARG_LIST_2 "")
 284     set(ARG_POS 0)
 285     set(INPUT_ARG_POS 0)
 286     set(OUTPUT_ARG_POS 0)
 287
 288     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 289
 290       math(EXPR ARG_POS "${ARG_POS}+1" )
 291
 292       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 293       if(INPUT_ARG_FOUND)
 294         set(INPUT_ARG_POS ${ARG_POS})
 295         set(INPUT_ARG_FOUND 0)
 296       endif()
 297
 298       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 299       if(OUTPUT_ARG_FOUND)
 300         set(OUTPUT_ARG_POS ${ARG_POS})
 301         set(OUTPUT_ARG_FOUND 0)
 302       endif()
 303
 304       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 305
 306     endforeach()
 307
 308     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 309     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 310     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 311     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 312     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 313
 314     #-----
 315     # Now we can add the test suite corresponding to a line command in the file
 316     #-----
 317     # ENCODER TEST SUITE
 318     if(ENC_TEST_FOUND)
 319         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 320
 321         # Encode an image into the jpeg2000 format
 322         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 323           COMMAND opj_compress
 324           ${CMD_ARG_LIST_2}
 325         )
 326
 327         if(FAILED_TEST_FOUND)
 328             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 329         else()
 330
 331           # Dump the encoding file
 332           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 333             COMMAND opj_dump
 334             -i ${OUTPUT_FILENAME}
 335             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 336           )
 337           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 338                                PROPERTIES DEPENDS
 339                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 340
 341           # Compare the dump file with the baseline
 342           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 343             COMMAND compare_dump_files
 344             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 345             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 346           )
 347
 348           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 349                                PROPERTIES DEPENDS
 350                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 351
 352           if(LOSSY_CHECK)
 353             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 354             COMMAND opj_decompress
 355             -i ${OUTPUT_FILENAME}
 356             -o ${OUTPUT_FILENAME}.tif
 357             )
 358
 359             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 360                                 PROPERTIES DEPENDS
 361                                 NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 362
 363             # Compare the decoding file with original one, using tolerance
 364             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 365             COMMAND compare_images
 366             -b ${INPUT_FILENAME}
 367             -t ${OUTPUT_FILENAME}.tif
 368             -s bXtY
 369             ${LOSSY_CHECK_ARG_LIST}
 370             )
 371
 372             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 373                                 PROPERTIES DEPENDS
 374                                 NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 375
 376           # Decode the encoding file with kakadu expand command
 377           elseif (KDU_EXPAND_EXECUTABLE)
 378             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 379               COMMAND ${KDU_EXPAND_EXECUTABLE}
 380               -i ${OUTPUT_FILENAME}
 381               -o ${OUTPUT_FILENAME}.raw
 382               )
 383
 384             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 385                                  PROPERTIES DEPENDS
 386                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 387
 388             if(NOT NO_RAW)
 389                 # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 390                 add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 391                 COMMAND compare_raw_files
 392                 -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 393                 -t ${OUTPUT_FILENAME}.raw
 394                 )
 395
 396                 set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 397                                     PROPERTIES DEPENDS
 398                                     NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 399             endif()
 400           endif()
 401
 402           # Test the encoded file is a valid JP2 file
 403           if (JPYLYZER_EXECUTABLE)
 404             if (${OUTPUT_FILENAME} MATCHES "\\.jp2$")
 405               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser
 406                 COMMAND ${JPYLYZER_EXECUTABLE}
 407                 ${OUTPUT_FILENAME}
 408                 )
 409               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser PROPERTIES
 410                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 411                 PASS_REGULAR_EXPRESSION "<isValidJP2>True</isValidJP2>"
 412                 )
 413             endif()
 414           endif(JPYLYZER_EXECUTABLE)
 415
 416           # If lossless compression (simple test is 4 arguments), decompress & compare
 417           list(LENGTH CMD_ARG_LIST_2 ARG_COUNT)
 418           if ((ARG_COUNT EQUAL 4) OR LOSSLESS)
 419             # can we compare with the input image ?
 420             if (${INPUT_FILENAME_NAME} MATCHES "\\.tif$")
 421               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 422                 COMMAND opj_decompress -i ${OUTPUT_FILENAME} -o ${OUTPUT_FILENAME}.lossless.tif
 423                 )
 424               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode PROPERTIES
 425                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 426                 )
 427               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare
 428                 COMMAND compare_images -b ${INPUT_FILENAME} -t ${OUTPUT_FILENAME}.lossless.tif -n 1 -d
 429                 )
 430               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare PROPERTIES
 431                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 432                 )
 433             endif()
 434           endif()
 435       endif()
 436
 437     # DECODER TEST SUITE
 438     else()
 439       string(FIND ${INPUT_FILENAME} "nonregression" nr_pos)
 440       if(${nr_pos} GREATER 0)
 441         list(APPEND nonregression_filenames_used ${INPUT_FILENAME_NAME})
 442       endif()
 443       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 444
 445       # Decode the input image
 446       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 447         COMMAND opj_decompress
 448         ${CMD_ARG_LIST_2}
 449       )
 450
 451       if(FAILED_TEST_FOUND)
 452
 453         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 454
 455       else()
 456         # if not failed, check against registered md5:
 457         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 458           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 459           -DOUTFILENAME:STRING=${OUTPUT_FILENAME}
 460           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 461
 462         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5
 463           PROPERTIES DEPENDS NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 464         )
 465
 466 # FIXME: add a compare2base function base on raw which
 467 # can output png diff files if necessary
 468 #  add_test(NR-${filename}-compare2base
 469 #      ${EXECUTABLE_OUTPUT_PATH}/compare_images
 470 #     -b ${BASELINE_NR}/opj_${filenameRef}
 471 #     -t ${TEMP}/${filename}.pgx
 472 #     -n ${nbComponents}
 473 #     -d
 474 #     -s b_t_
 475 #     )
 476 #
 477 #  set_tests_properties(NR-${filename}-compare2base
 478 #                       PROPERTIES DEPENDS
 479 #                       NR-${filename}-decode)
 480
 481       endif()
 482
 483     endif()
 484
 485   endif()
 486
 487 endforeach()
 488
 489 set(existing_filenames)
 490 foreach(f ${OPJ_DATA_NR_LIST})
 491   get_filename_component(ff ${f} NAME)
 492   list(APPEND existing_filenames ${ff})
 493 endforeach()
 494 if(existing_filenames)
 495 list(REMOVE_ITEM existing_filenames ${nonregression_filenames_used})
 496 endif()
 497
 498 # keep track of new addition:
 499 # if we reach here, then a J2K files was added but no test is present in
 500 # test_suite.ctest.in:
 501 foreach(found_but_no_test ${existing_filenames})
 502   add_test(NAME Found-But-No-Test-${found_but_no_test} COMMAND ${CMAKE_COMMAND} -E echo "${found_but_no_test}")
 503   set_tests_properties(Found-But-No-Test-${found_but_no_test} PROPERTIES WILL_FAIL TRUE)
 504 endforeach()