tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   4
   5 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   7 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
   8
   9
  10 set(INPUT_NR_PATH ${INPUT_NR})
  11 set(TEMP_PATH ${TEMP})
  12 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  13
  14 # need kdu_expand if possible
  15 find_package(KAKADU)
  16 # need jpylyzer if possible
  17 find_package(JPYLYZER)
  18
  19 #########################################################################
  20 # GENERATION OF THE TEST SUITE (DUMP)
  21 # Dump all files with the selected extension inside the input directory
  22
  23 # technically opj_dump should simply parse these one, since syntax is ok.
  24 set(BLACKLIST_JPEG2000_TMP
  25     2539.pdf.SIGFPE.706.1712.jp2
  26     0290cb77c5df21828fa74cf2ab2c84d8.SIGFPE.d25.31.jp2
  27     26ccf3651020967f7778238ef5af08af.SIGFPE.d25.527.jp2
  28     4035.pdf.SIGSEGV.d8b.3375.jp2
  29     3635.pdf.asan.77.2930.jp2
  30     issue165.jp2
  31     #edf_c2_1103421.jp2
  32     edf_c2_1178956.jp2
  33     edf_c2_1000290.jp2
  34     #edf_c2_1000691.jp2 # ok
  35     #edf_c2_20.jp2 #looks ok as per kdu_jp2info
  36     edf_c2_1377017.jp2
  37     edf_c2_1002767.jp2
  38     #edf_c2_10025.jp2
  39     edf_c2_1000234.jp2
  40     edf_c2_225881.jp2
  41     edf_c2_1000671.jp2
  42     #edf_c2_1013627.jp2 # weird box, but kdu_jp2info ok
  43     edf_c2_1015644.jp2
  44     edf_c2_101463.jp2
  45     edf_c2_1674177.jp2
  46     edf_c2_1673169.jp2
  47     issue429.jp2
  48     issue427-null-image-size.jp2
  49     issue427-illegal-tile-offset.jp2
  50    )
  51
  52 # Define a list of file which should be gracefully rejected:
  53 set(BLACKLIST_JPEG2000
  54     ${BLACKLIST_JPEG2000_TMP}
  55     broken1.jp2
  56     broken2.jp2
  57     broken3.jp2
  58     broken4.jp2
  59     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  60     gdal_fuzzer_check_comp_dx_dy.jp2
  61     gdal_fuzzer_check_number_of_tiles.jp2
  62     gdal_fuzzer_unchecked_numresolutions.jp2
  63     mem-b2ace68c-1381.jp2
  64     1851.pdf.SIGSEGV.ce9.948.jp2
  65     1888.pdf.asan.35.988.jp2
  66     issue362-2863.jp2 #kdu_jp2info ok
  67     issue362-2866.jp2
  68     issue362-2894.jp2
  69     issue400.jp2 #kdu_jp2info ok
  70     issue364-38.jp2
  71     issue364-903.jp2 #kdu_jp2info ok
  72     issue393.jp2 #kdu_jp2info ok
  73     issue408.jp2 #kdu_jp2info ok
  74     issue420.jp2 #kdu_jp2info ok
  75     27ac957758a35d00d6765a0c86350d9c.SIGFPE.d25.537.jpc #kdu_jp2info crash
  76     3672da2f1f67bbecad27d7181b4e9d7c.SIGFPE.d25.805.jpc #kdu_jp2info crash
  77     issue476.jp2 #kdu_jp2info ok
  78     issue475.jp2 #kdu_jp2info ok
  79     issue413.jp2 #kdu_jp2info ok
  80    )
  81
  82 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  83      "${INPUT_NR}/*.j2k"
  84      "${INPUT_NR}/*.j2c"
  85      "${INPUT_NR}/*.jp2"
  86      "${INPUT_NR}/*.jpc"
  87      #"${INPUT_NR}/*.jpx"
  88      )
  89
  90 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  91   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  92   #get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  93   # cannot use longest extension function, since some name contains multiples
  94   # dots. Instead write out own shortest extension function:
  95   string(FIND ${INPUT_FILENAME_NAME} "." SHORTEST_EXT_POS REVERSE)
  96   string(SUBSTRING ${INPUT_FILENAME_NAME} 0 ${SHORTEST_EXT_POS} INPUT_FILENAME_NAME_WE)
  97   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
  98
  99   # Dump the input image
 100   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
 101            COMMAND opj_dump
 102                -i ${INPUT_FILENAME}
 103                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
 104                -v
 105                )
 106
 107   if(bad_jpeg2000)
 108     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
 109                          PROPERTIES WILL_FAIL TRUE)
 110
 111   else()
 112
 113     # Compare the dump output with the baseline
 114     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
 115                 COMMAND compare_dump_files
 116             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
 117             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
 118             )
 119
 120     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
 121                          PROPERTIES DEPENDS
 122                          NR-${INPUT_FILENAME_NAME}-dump)
 123   endif()
 124
 125 endforeach()
 126
 127
 128 #########################################################################
 129 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
 130 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
 131 # to know which files processed and with which options.
 132
 133 # Configure the test suite file:
 134 configure_file("test_suite.ctest.in"
 135                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
 136                @ONLY)
 137
 138 # Read the file into a list
 139 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
 140
 141 # Try to find and configure and read another test suite file
 142 file(GLOB TEST_SUITE_FILES *.ctest.in)
 143 if (TEST_SUITE_FILES)
 144   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
 145
 146     # Avoid to process the official test suite
 147     set(FILE_ALREADY_READ 0)
 148     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
 149     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 150
 151     if(NOT FILE_ALREADY_READ)
 152       # Configure the additional test suite file:
 153       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 154       configure_file("${TEST_SUITE_FILE}"
 155                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 156                      @ONLY)
 157       # Read the additional file into a list
 158       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 159       # Append the list of command
 160       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 161
 162     endif()
 163
 164   endforeach()
 165
 166 else()
 167
 168   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 169
 170 endif()
 171
 172
 173 set(nonregression_filenames_used)
 174 # Parse the command line found in the file(s)
 175 set(IT_TEST_ENC 0)
 176 set(IT_TEST_DEC 0)
 177 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 178
 179   set(IGNORE_LINE_FOUND 0)
 180
 181   # Replace space by ; to generate a list
 182   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 183
 184   # Check if the first argument begin by the comment sign
 185   list(GET CMD_ARG_LIST 0 EXE_NAME)
 186
 187   if(EXE_NAME)
 188     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 189   endif()
 190
 191   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 192
 193     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 194
 195   else()
 196
 197     # Check if the first argument begin by the failed sign
 198     set(FAILED_TEST_FOUND 0)
 199     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 200
 201     if (FAILED_TEST_FOUND)
 202       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 203       set(FAILED_TEST_FOUND_1 0)
 204       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 205
 206       if (FAILED_TEST_FOUND_1)
 207
 208         list(REMOVE_AT CMD_ARG_LIST 0)
 209
 210       else ()
 211
 212         set(FAILED_TEST_FOUND_2 0)
 213         list(GET CMD_ARG_LIST 1 EXE_NAME)
 214         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 215
 216         if (FAILED_TEST_FOUND_2)
 217
 218           list(REMOVE_AT CMD_ARG_LIST 0)
 219           list(REMOVE_AT CMD_ARG_LIST 0)
 220
 221         else ()
 222
 223           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 224
 225         endif ()
 226       endif ()
 227
 228     else ()
 229       # Check if the first argument is equal to opj_compress
 230       string(REGEX MATCH "^opj_compress$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 231
 232       if(EXE_NAME_FOUND)
 233
 234         string(REGEX MATCH "opj_compress" ENC_TEST_FOUND ${EXE_NAME})
 235
 236       else()
 237
 238         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 239
 240       endif()
 241
 242       list(REMOVE_AT CMD_ARG_LIST 0)
 243
 244     endif ()
 245
 246     # Parse the argument list to find the input filename and output filename
 247     set(CMD_ARG_LIST_2 "")
 248     set(ARG_POS 0)
 249     set(INPUT_ARG_POS 0)
 250     set(OUTPUT_ARG_POS 0)
 251
 252     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 253
 254       math(EXPR ARG_POS "${ARG_POS}+1" )
 255
 256       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 257       if(INPUT_ARG_FOUND)
 258         set(INPUT_ARG_POS ${ARG_POS})
 259         set(INPUT_ARG_FOUND 0)
 260       endif()
 261
 262       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 263       if(OUTPUT_ARG_FOUND)
 264         set(OUTPUT_ARG_POS ${ARG_POS})
 265         set(OUTPUT_ARG_FOUND 0)
 266       endif()
 267
 268       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 269
 270     endforeach()
 271
 272     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 273     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 274     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 275     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 276     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 277
 278     #-----
 279     # Now we can add the test suite corresponding to a line command in the file
 280     #-----
 281     # ENCODER TEST SUITE
 282     if(ENC_TEST_FOUND)
 283         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 284
 285         # Encode an image into the jpeg2000 format
 286         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 287           COMMAND opj_compress
 288           ${CMD_ARG_LIST_2}
 289         )
 290
 291         if(FAILED_TEST_FOUND)
 292             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 293         else()
 294
 295           # Dump the encoding file
 296           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 297             COMMAND opj_dump
 298             -i ${OUTPUT_FILENAME}
 299             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 300           )
 301           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 302                                PROPERTIES DEPENDS
 303                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 304
 305           # Compare the dump file with the baseline
 306           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 307             COMMAND compare_dump_files
 308             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 309             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 310           )
 311
 312           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 313                                PROPERTIES DEPENDS
 314                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 315
 316           # Decode the encoding file with kakadu expand command
 317           if (KDU_EXPAND_EXECUTABLE)
 318             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 319               COMMAND ${KDU_EXPAND_EXECUTABLE}
 320               -i ${OUTPUT_FILENAME}
 321               -o ${OUTPUT_FILENAME}.raw
 322               )
 323
 324             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 325                                  PROPERTIES DEPENDS
 326                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 327
 328             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 329             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 330               COMMAND compare_raw_files
 331               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 332               -t ${OUTPUT_FILENAME}.raw
 333             )
 334
 335             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 336                                  PROPERTIES DEPENDS
 337                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 338
 339           endif()
 340
 341           # Test the encoded file is a valid JP2 file
 342           if (JPYLYZER_EXECUTABLE)
 343             if (${OUTPUT_FILENAME} MATCHES "\\.jp2$")
 344               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser
 345                 COMMAND ${JPYLYZER_EXECUTABLE}
 346                 ${OUTPUT_FILENAME}
 347                 )
 348               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser PROPERTIES
 349                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 350                 PASS_REGULAR_EXPRESSION "<isValidJP2>True</isValidJP2>"
 351                 )
 352             endif()
 353           endif(JPYLYZER_EXECUTABLE)
 354       endif()
 355
 356     # DECODER TEST SUITE
 357     else()
 358       string(FIND ${INPUT_FILENAME} "nonregression" nr_pos)
 359       if(${nr_pos} GREATER 0)
 360         list(APPEND nonregression_filenames_used ${INPUT_FILENAME_NAME})
 361       endif()
 362       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 363
 364       # Decode the input image
 365       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 366         COMMAND opj_decompress
 367         ${CMD_ARG_LIST_2}
 368       )
 369
 370       if(FAILED_TEST_FOUND)
 371
 372         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 373
 374       else()
 375         # if not failed, check against registered md5:
 376         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 377           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 378           -DOUTFILENAME:STRING=${OUTPUT_FILENAME}
 379           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 380
 381         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5
 382           PROPERTIES DEPENDS NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 383         )
 384
 385 # FIXME: add a compare2base function base on raw which
 386 # can output png diff files if necesary
 387 #  add_test(NR-${filename}-compare2base
 388 #      ${EXECUTABLE_OUTPUT_PATH}/compare_images
 389 #     -b ${BASELINE_NR}/opj_${filenameRef}
 390 #     -t ${TEMP}/${filename}.pgx
 391 #     -n ${nbComponents}
 392 #     -d
 393 #     -s b_t_
 394 #     )
 395 #
 396 #  set_tests_properties(NR-${filename}-compare2base
 397 #                       PROPERTIES DEPENDS
 398 #                       NR-${filename}-decode)
 399
 400       endif()
 401
 402     endif()
 403
 404   endif()
 405
 406 endforeach()
 407
 408 set(existing_filenames)
 409 foreach(f ${OPJ_DATA_NR_LIST})
 410   get_filename_component(ff ${f} NAME)
 411   list(APPEND existing_filenames ${ff})
 412 endforeach()
 413 if(existing_filenames)
 414 list(REMOVE_ITEM existing_filenames ${nonregression_filenames_used})
 415 endif()
 416
 417 # keep track of new addition:
 418 # if we reach here, then a J2K files was added but no test is present in
 419 # test_suite.ctest.in:
 420 foreach(found_but_no_test ${existing_filenames})
 421   add_test(NAME Found-But-No-Test-${found_but_no_test} COMMAND ${CMAKE_COMMAND} -E echo "${found_but_no_test}")
 422   set_tests_properties(Found-But-No-Test-${found_but_no_test} PROPERTIES WILL_FAIL TRUE)
 423 endforeach()