tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   4
   5 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   7 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
   8
   9
  10 set(INPUT_NR_PATH ${INPUT_NR})
  11 set(TEMP_PATH ${TEMP})
  12 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  13
  14 # need kdu_expand if possible
  15 find_package(KAKADU)
  16
  17 #########################################################################
  18 # GENERATION OF THE TEST SUITE (DUMP)
  19 # Dump all files with the selected extension inside the input directory
  20
  21 # technically opj_dump should simply parse these one, since syntax is ok.
  22 set(BLACKLIST_JPEG2000_TMP
  23     2539.pdf.SIGFPE.706.1712.jp2
  24     0290cb77c5df21828fa74cf2ab2c84d8.SIGFPE.d25.31.jp2
  25     26ccf3651020967f7778238ef5af08af.SIGFPE.d25.527.jp2
  26     4035.pdf.SIGSEGV.d8b.3375.jp2
  27     3635.pdf.asan.77.2930.jp2
  28    )
  29
  30 # Define a list of file which should be gracefully rejected:
  31 set(BLACKLIST_JPEG2000
  32     ${BLACKLIST_JPEG2000_TMP}
  33     broken.jp2
  34     broken2.jp2
  35     broken3.jp2
  36     broken4.jp2
  37     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  38     gdal_fuzzer_check_comp_dx_dy.jp2
  39     gdal_fuzzer_check_number_of_tiles.jp2
  40     gdal_fuzzer_unchecked_numresolutions.jp2
  41     mem-b2ace68c-1381.jp2
  42     1851.pdf.SIGSEGV.ce9.948.jp2
  43    )
  44
  45 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  46      "${INPUT_NR}/*.j2k"
  47      "${INPUT_NR}/*.j2c"
  48      "${INPUT_NR}/*.jp2"
  49      #"${INPUT_NR}/*.jpx"
  50      )
  51
  52 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  53   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  54   #get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  55   # cannot use longest extension function, since some name contains multiples
  56   # dots. Instead write out own shortest extension function:
  57   string(FIND ${INPUT_FILENAME_NAME} "." SHORTEST_EXT_POS REVERSE)
  58   string(SUBSTRING ${INPUT_FILENAME_NAME} 0 ${SHORTEST_EXT_POS} INPUT_FILENAME_NAME_WE)
  59   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
  60
  61   # Dump the input image
  62   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
  63            COMMAND opj_dump
  64                -i ${INPUT_FILENAME}
  65                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
  66                -v
  67                )
  68
  69   if(bad_jpeg2000)
  70     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
  71                          PROPERTIES WILL_FAIL TRUE)
  72
  73   else()
  74
  75     # Compare the dump output with the baseline
  76     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
  77                 COMMAND compare_dump_files
  78             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
  79             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
  80             )
  81
  82     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
  83                          PROPERTIES DEPENDS
  84                          NR-${INPUT_FILENAME_NAME}-dump)
  85   endif()
  86
  87 endforeach()
  88
  89
  90 #########################################################################
  91 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
  92 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
  93 # to know which files processed and with which options.
  94
  95 # Configure the test suite file:
  96 configure_file("test_suite.ctest.in"
  97                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
  98                @ONLY)
  99
 100 # Read the file into a list
 101 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
 102
 103 # Try to find and configure and read another test suite file
 104 file(GLOB TEST_SUITE_FILES *.ctest.in)
 105 if (TEST_SUITE_FILES)
 106   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
 107
 108     # Avoid to process the official test suite
 109     set(FILE_ALREADY_READ 0)
 110     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
 111     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 112
 113     if(NOT FILE_ALREADY_READ)
 114       # Configure the additional test suite file:
 115       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 116       configure_file("${TEST_SUITE_FILE}"
 117                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 118                      @ONLY)
 119       # Read the additional file into a list
 120       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 121       # Append the list of command
 122       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 123
 124     endif()
 125
 126   endforeach()
 127
 128 else()
 129
 130   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 131
 132 endif()
 133
 134
 135 # Parse the command line found in the file(s)
 136 set(IT_TEST_ENC 0)
 137 set(IT_TEST_DEC 0)
 138 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 139
 140   set(IGNORE_LINE_FOUND 0)
 141
 142   # Replace space by ; to generate a list
 143   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 144
 145   # Check if the first argument begin by the comment sign
 146   list(GET CMD_ARG_LIST 0 EXE_NAME)
 147
 148   if(EXE_NAME)
 149     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 150   endif()
 151
 152   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 153
 154     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 155
 156   else()
 157
 158     # Check if the first argument begin by the failed sign
 159     set(FAILED_TEST_FOUND 0)
 160     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 161
 162     if (FAILED_TEST_FOUND)
 163       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 164       set(FAILED_TEST_FOUND_1 0)
 165       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 166
 167       if (FAILED_TEST_FOUND_1)
 168
 169         list(REMOVE_AT CMD_ARG_LIST 0)
 170
 171       else ()
 172
 173         set(FAILED_TEST_FOUND_2 0)
 174         list(GET CMD_ARG_LIST 1 EXE_NAME)
 175         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 176
 177         if (FAILED_TEST_FOUND_2)
 178
 179           list(REMOVE_AT CMD_ARG_LIST 0)
 180           list(REMOVE_AT CMD_ARG_LIST 0)
 181
 182         else ()
 183
 184           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 185
 186         endif ()
 187       endif ()
 188
 189     else ()
 190       # Check if the first argument is equal to opj_compress
 191       string(REGEX MATCH "^opj_compress$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 192
 193       if(EXE_NAME_FOUND)
 194
 195         string(REGEX MATCH "opj_compress" ENC_TEST_FOUND ${EXE_NAME})
 196
 197       else()
 198
 199         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 200
 201       endif()
 202
 203       list(REMOVE_AT CMD_ARG_LIST 0)
 204
 205     endif ()
 206
 207     # Parse the argument list to find the input filename and output filename
 208     set(CMD_ARG_LIST_2 "")
 209     set(ARG_POS 0)
 210     set(INPUT_ARG_POS 0)
 211     set(OUTPUT_ARG_POS 0)
 212
 213     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 214
 215       math(EXPR ARG_POS "${ARG_POS}+1" )
 216
 217       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 218       if(INPUT_ARG_FOUND)
 219         set(INPUT_ARG_POS ${ARG_POS})
 220         set(INPUT_ARG_FOUND 0)
 221       endif()
 222
 223       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 224       if(OUTPUT_ARG_FOUND)
 225         set(OUTPUT_ARG_POS ${ARG_POS})
 226         set(OUTPUT_ARG_FOUND 0)
 227       endif()
 228
 229       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 230
 231     endforeach()
 232
 233     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 234     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 235     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 236     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 237     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 238
 239     #-----
 240     # Now we can add the test suite corresponding to a line command in the file
 241     #-----
 242
 243     # ENCODER TEST SUITE
 244     if(ENC_TEST_FOUND)
 245         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 246
 247         # Encode an image into the jpeg2000 format
 248         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 249           COMMAND opj_compress
 250           ${CMD_ARG_LIST_2}
 251         )
 252
 253         if(FAILED_TEST_FOUND)
 254             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 255         else()
 256
 257           # Dump the encoding file
 258           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 259             COMMAND opj_dump
 260             -i ${OUTPUT_FILENAME}
 261             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 262           )
 263           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 264                                PROPERTIES DEPENDS
 265                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 266
 267           # Compare the dump file with the baseline
 268           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 269             COMMAND compare_dump_files
 270             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 271             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 272           )
 273
 274           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 275                                PROPERTIES DEPENDS
 276                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 277
 278           # Decode the encoding file with kakadu expand command
 279           if (KDU_EXPAND_EXECUTABLE)
 280             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 281               COMMAND ${KDU_EXPAND_EXECUTABLE}
 282               -i ${OUTPUT_FILENAME}
 283               -o ${OUTPUT_FILENAME}.raw
 284               )
 285
 286             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 287                                  PROPERTIES DEPENDS
 288                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 289
 290             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 291             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 292               COMMAND compare_raw_files
 293               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 294               -t ${OUTPUT_FILENAME}.raw
 295             )
 296
 297             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 298                                  PROPERTIES DEPENDS
 299                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 300
 301           endif()
 302       endif()
 303
 304     # DECODER TEST SUITE
 305     else()
 306       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 307
 308       # Decode the input image
 309       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 310         COMMAND opj_decompress
 311         ${CMD_ARG_LIST_2}
 312       )
 313
 314       if(FAILED_TEST_FOUND)
 315
 316         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 317
 318       else()
 319         # if not failed, check against registered md5:
 320         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 321           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 322           -DFILENAME:STRING=${INPUT_FILENAME_NAME}
 323           -DOUTFILENAME:STRING=${OUTPUT_FILENAME}
 324           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 325
 326         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5
 327           PROPERTIES DEPENDS NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 328         )
 329
 330 # FIXME: add a compare2base function base on raw which
 331 # can output png diff files if necesary
 332 #  add_test(NR-${filename}-compare2base
 333 #      ${EXECUTABLE_OUTPUT_PATH}/compare_images
 334 #     -b ${BASELINE_NR}/opj_${filenameRef}
 335 #     -t ${TEMP}/${filename}.pgx
 336 #     -n ${nbComponents}
 337 #     -d
 338 #     -s b_t_
 339 #     )
 340 #
 341 #  set_tests_properties(NR-${filename}-compare2base
 342 #                       PROPERTIES DEPENDS
 343 #                       NR-${filename}-decode)
 344
 345       endif()
 346
 347     endif()
 348
 349   endif()
 350
 351 endforeach()