tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   4
   5 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   7 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
   8
   9
  10 set(INPUT_NR_PATH ${INPUT_NR})
  11 set(TEMP_PATH ${TEMP})
  12 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  13
  14 # need kdu_expand if possible
  15 find_package(KAKADU)
  16
  17 #########################################################################
  18 # GENERATION OF THE TEST SUITE (DUMP)
  19 # Dump all files with the selected extension inside the input directory
  20
  21 # technically opj_dump should simply parse these one, since syntax is ok.
  22 set(BLACKLIST_JPEG2000_TMP
  23     2539.pdf.SIGFPE.706.1712.jp2
  24     0290cb77c5df21828fa74cf2ab2c84d8.SIGFPE.d25.31.jp2
  25     26ccf3651020967f7778238ef5af08af.SIGFPE.d25.527.jp2
  26    )
  27
  28 # Define a list of file which should be gracefully rejected:
  29 set(BLACKLIST_JPEG2000
  30     ${BLACKLIST_JPEG2000_TMP}
  31     broken.jp2
  32     broken2.jp2
  33     broken3.jp2
  34     broken4.jp2
  35     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  36     gdal_fuzzer_check_comp_dx_dy.jp2
  37     gdal_fuzzer_check_number_of_tiles.jp2
  38     gdal_fuzzer_unchecked_numresolutions.jp2
  39     mem-b2ace68c-1381.jp2
  40     1851.pdf.SIGSEGV.ce9.948.jp2
  41    )
  42
  43 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  44      "${INPUT_NR}/*.j2k"
  45      "${INPUT_NR}/*.j2c"
  46      "${INPUT_NR}/*.jp2"
  47      #"${INPUT_NR}/*.jpx"
  48      )
  49
  50 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  51   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  52   #get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  53   # cannot use longest extension function, since some name contains multiples
  54   # dots. Instead write out own shortest extension function:
  55   string(FIND ${INPUT_FILENAME_NAME} "." SHORTEST_EXT_POS REVERSE)
  56   string(SUBSTRING ${INPUT_FILENAME_NAME} 0 ${SHORTEST_EXT_POS} INPUT_FILENAME_NAME_WE)
  57   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
  58
  59   # Dump the input image
  60   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
  61            COMMAND opj_dump
  62                -i ${INPUT_FILENAME}
  63                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
  64                -v
  65                )
  66
  67   if(bad_jpeg2000)
  68     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
  69                          PROPERTIES WILL_FAIL TRUE)
  70
  71   else()
  72
  73     # Compare the dump output with the baseline
  74     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
  75                 COMMAND compare_dump_files
  76             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
  77             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
  78             )
  79
  80     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
  81                          PROPERTIES DEPENDS
  82                          NR-${INPUT_FILENAME_NAME}-dump)
  83   endif()
  84
  85 endforeach()
  86
  87
  88 #########################################################################
  89 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
  90 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
  91 # to know which files processed and with which options.
  92
  93 # Configure the test suite file:
  94 configure_file("test_suite.ctest.in"
  95                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
  96                @ONLY)
  97
  98 # Read the file into a list
  99 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
 100
 101 # Try to find and configure and read another test suite file
 102 file(GLOB TEST_SUITE_FILES *.ctest.in)
 103 if (TEST_SUITE_FILES)
 104   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
 105
 106     # Avoid to process the official test suite
 107     set(FILE_ALREADY_READ 0)
 108     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
 109     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 110
 111     if(NOT FILE_ALREADY_READ)
 112       # Configure the additional test suite file:
 113       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 114       configure_file("${TEST_SUITE_FILE}"
 115                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 116                      @ONLY)
 117       # Read the additional file into a list
 118       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 119       # Append the list of command
 120       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 121
 122     endif()
 123
 124   endforeach()
 125
 126 else()
 127
 128   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 129
 130 endif()
 131
 132
 133 # Parse the command line found in the file(s)
 134 set(IT_TEST_ENC 0)
 135 set(IT_TEST_DEC 0)
 136 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 137
 138   set(IGNORE_LINE_FOUND 0)
 139
 140   # Replace space by ; to generate a list
 141   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 142
 143   # Check if the first argument begin by the comment sign
 144   list(GET CMD_ARG_LIST 0 EXE_NAME)
 145
 146   if(EXE_NAME)
 147     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 148   endif()
 149
 150   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 151
 152     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 153
 154   else()
 155
 156     # Check if the first argument begin by the failed sign
 157     set(FAILED_TEST_FOUND 0)
 158     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 159
 160     if (FAILED_TEST_FOUND)
 161       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 162       set(FAILED_TEST_FOUND_1 0)
 163       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 164
 165       if (FAILED_TEST_FOUND_1)
 166
 167         list(REMOVE_AT CMD_ARG_LIST 0)
 168
 169       else ()
 170
 171         set(FAILED_TEST_FOUND_2 0)
 172         list(GET CMD_ARG_LIST 1 EXE_NAME)
 173         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 174
 175         if (FAILED_TEST_FOUND_2)
 176
 177           list(REMOVE_AT CMD_ARG_LIST 0)
 178           list(REMOVE_AT CMD_ARG_LIST 0)
 179
 180         else ()
 181
 182           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 183
 184         endif ()
 185       endif ()
 186
 187     else ()
 188       # Check if the first argument is equal to opj_compress
 189       string(REGEX MATCH "^opj_compress$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 190
 191       if(EXE_NAME_FOUND)
 192
 193         string(REGEX MATCH "opj_compress" ENC_TEST_FOUND ${EXE_NAME})
 194
 195       else()
 196
 197         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 198
 199       endif()
 200
 201       list(REMOVE_AT CMD_ARG_LIST 0)
 202
 203     endif ()
 204
 205     # Parse the argument list to find the input filename and output filename
 206     set(CMD_ARG_LIST_2 "")
 207     set(ARG_POS 0)
 208     set(INPUT_ARG_POS 0)
 209     set(OUTPUT_ARG_POS 0)
 210
 211     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 212
 213       math(EXPR ARG_POS "${ARG_POS}+1" )
 214
 215       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 216       if(INPUT_ARG_FOUND)
 217         set(INPUT_ARG_POS ${ARG_POS})
 218         set(INPUT_ARG_FOUND 0)
 219       endif()
 220
 221       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 222       if(OUTPUT_ARG_FOUND)
 223         set(OUTPUT_ARG_POS ${ARG_POS})
 224         set(OUTPUT_ARG_FOUND 0)
 225       endif()
 226
 227       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 228
 229     endforeach()
 230
 231     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 232     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 233     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 234     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 235     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 236
 237     #-----
 238     # Now we can add the test suite corresponding to a line command in the file
 239     #-----
 240
 241     # ENCODER TEST SUITE
 242     if(ENC_TEST_FOUND)
 243         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 244
 245         # Encode an image into the jpeg2000 format
 246         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 247           COMMAND opj_compress
 248           ${CMD_ARG_LIST_2}
 249         )
 250
 251         if(FAILED_TEST_FOUND)
 252             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 253         else()
 254
 255           # Dump the encoding file
 256           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 257             COMMAND opj_dump
 258             -i ${OUTPUT_FILENAME}
 259             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 260           )
 261           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 262                                PROPERTIES DEPENDS
 263                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 264
 265           # Compare the dump file with the baseline
 266           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 267             COMMAND compare_dump_files
 268             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 269             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 270           )
 271
 272           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 273                                PROPERTIES DEPENDS
 274                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 275
 276           # Decode the encoding file with kakadu expand command
 277           if (KDU_EXPAND_EXECUTABLE)
 278             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 279               COMMAND ${KDU_EXPAND_EXECUTABLE}
 280               -i ${OUTPUT_FILENAME}
 281               -o ${OUTPUT_FILENAME}.raw
 282               )
 283
 284             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 285                                  PROPERTIES DEPENDS
 286                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 287
 288             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 289             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 290               COMMAND compareRAWimages
 291               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 292               -t ${OUTPUT_FILENAME}.raw
 293             )
 294
 295             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 296                                  PROPERTIES DEPENDS
 297                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 298
 299           endif()
 300       endif()
 301
 302     # DECODER TEST SUITE
 303     else()
 304       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 305
 306       # Decode the input image
 307       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 308         COMMAND opj_decompress
 309         ${CMD_ARG_LIST_2}
 310       )
 311
 312       if(FAILED_TEST_FOUND)
 313
 314         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 315
 316       else()
 317         # if not failed, check against registered md5:
 318         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 319           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 320           -DFILENAME:STRING=${INPUT_FILENAME_NAME}
 321           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 322
 323
 324 # FIXME: add a compare2base function base on raw which
 325 # can output png diff files if necesary
 326 #  add_test(NR-${filename}-compare2base
 327 #      ${EXECUTABLE_OUTPUT_PATH}/comparePGXimages
 328 #     -b ${BASELINE_NR}/opj_${filenameRef}
 329 #     -t ${TEMP}/${filename}.pgx
 330 #     -n ${nbComponents}
 331 #     -d
 332 #     -s b_t_
 333 #     )
 334 #
 335 #  set_tests_properties(NR-${filename}-compare2base
 336 #                       PROPERTIES DEPENDS
 337 #                       NR-${filename}-decode)
 338
 339       endif()
 340
 341     endif()
 342
 343   endif()
 344
 345 endforeach()