tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   4
   5 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   7 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
   8
   9
  10 set(INPUT_NR_PATH ${INPUT_NR})
  11 set(TEMP_PATH ${TEMP})
  12 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  13
  14 # need kdu_expand if possible
  15 find_package(KAKADU)
  16
  17 #########################################################################
  18 # GENERATION OF THE TEST SUITE (DUMP)
  19 # Dump all files with the selected extension inside the input directory
  20
  21 # Define a list of file which should be gracefully rejected:
  22 set(BLACKLIST_JPEG2000
  23     broken.jp2
  24     broken2.jp2
  25     broken3.jp2
  26     broken4.jp2
  27     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  28     gdal_fuzzer_check_comp_dx_dy.jp2
  29     gdal_fuzzer_check_number_of_tiles.jp2
  30     gdal_fuzzer_unchecked_numresolutions.jp2
  31     mem-b2ace68c-1381.jp2
  32    )
  33
  34 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  35      "${INPUT_NR}/*.j2k"
  36      "${INPUT_NR}/*.j2c"
  37      "${INPUT_NR}/*.jp2"
  38      #"${INPUT_NR}/*.jpx"
  39      )
  40
  41 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  42   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  43   get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  44   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
  45
  46   # Dump the input image
  47   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
  48            COMMAND opj_dump
  49                -i ${INPUT_FILENAME}
  50                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
  51                -v
  52                )
  53
  54   if(bad_jpeg2000)
  55     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
  56                          PROPERTIES WILL_FAIL TRUE)
  57
  58   else()
  59
  60     # Compare the dump output with the baseline
  61     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
  62                 COMMAND compare_dump_files
  63             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
  64             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
  65             )
  66
  67     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
  68                          PROPERTIES DEPENDS
  69                          NR-${INPUT_FILENAME_NAME}-dump)
  70   endif()
  71
  72 endforeach()
  73
  74
  75 #########################################################################
  76 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
  77 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
  78 # to know which files processed and with which options.
  79
  80 # Configure the test suite file:
  81 configure_file("test_suite.ctest.in"
  82                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
  83                @ONLY)
  84
  85 # Read the file into a list
  86 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
  87
  88 # Try to find and configure and read another test suite file
  89 file(GLOB TEST_SUITE_FILES *.ctest.in)
  90 if (TEST_SUITE_FILES)
  91   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
  92
  93     # Avoid to process the official test suite
  94     set(FILE_ALREADY_READ 0)
  95     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
  96     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
  97
  98     if(NOT FILE_ALREADY_READ)
  99       # Configure the additional test suite file:
 100       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 101       configure_file("${TEST_SUITE_FILE}"
 102                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 103                      @ONLY)
 104       # Read the additional file into a list
 105       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 106       # Append the list of command
 107       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 108
 109     endif()
 110
 111   endforeach()
 112
 113 else()
 114
 115   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 116
 117 endif()
 118
 119
 120 # Parse the command line found in the file(s)
 121 set(IT_TEST_ENC 0)
 122 set(IT_TEST_DEC 0)
 123 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 124
 125   set(IGNORE_LINE_FOUND 0)
 126
 127   # Replace space by ; to generate a list
 128   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 129
 130   # Check if the first argument begin by the comment sign
 131   list(GET CMD_ARG_LIST 0 EXE_NAME)
 132
 133   if(EXE_NAME)
 134     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 135   endif()
 136
 137   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 138
 139     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 140
 141   else()
 142
 143     # Check if the first argument begin by the failed sign
 144     set(FAILED_TEST_FOUND 0)
 145     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 146
 147     if (FAILED_TEST_FOUND)
 148       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 149       set(FAILED_TEST_FOUND_1 0)
 150       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 151
 152       if (FAILED_TEST_FOUND_1)
 153
 154         list(REMOVE_AT CMD_ARG_LIST 0)
 155
 156       else ()
 157
 158         set(FAILED_TEST_FOUND_2 0)
 159         list(GET CMD_ARG_LIST 1 EXE_NAME)
 160         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 161
 162         if (FAILED_TEST_FOUND_2)
 163
 164           list(REMOVE_AT CMD_ARG_LIST 0)
 165           list(REMOVE_AT CMD_ARG_LIST 0)
 166
 167         else ()
 168
 169           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 170
 171         endif ()
 172       endif ()
 173
 174     else ()
 175       # Check if the first argument is equal to opj_compress
 176       string(REGEX MATCH "^opj_compress$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 177
 178       if(EXE_NAME_FOUND)
 179
 180         string(REGEX MATCH "opj_compress" ENC_TEST_FOUND ${EXE_NAME})
 181
 182       else()
 183
 184         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 185
 186       endif()
 187
 188       list(REMOVE_AT CMD_ARG_LIST 0)
 189
 190     endif ()
 191
 192     # Parse the argument list to find the input filename and output filename
 193     set(CMD_ARG_LIST_2 "")
 194     set(ARG_POS 0)
 195     set(INPUT_ARG_POS 0)
 196     set(OUTPUT_ARG_POS 0)
 197
 198     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 199
 200       math(EXPR ARG_POS "${ARG_POS}+1" )
 201
 202       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 203       if(INPUT_ARG_FOUND)
 204         set(INPUT_ARG_POS ${ARG_POS})
 205         set(INPUT_ARG_FOUND 0)
 206       endif()
 207
 208       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 209       if(OUTPUT_ARG_FOUND)
 210         set(OUTPUT_ARG_POS ${ARG_POS})
 211         set(OUTPUT_ARG_FOUND 0)
 212       endif()
 213
 214       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 215
 216     endforeach()
 217
 218     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 219     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 220     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 221     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 222     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 223
 224     #-----
 225     # Now we can add the test suite corresponding to a line command in the file
 226     #-----
 227
 228     # ENCODER TEST SUITE
 229     if(ENC_TEST_FOUND)
 230         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 231
 232         # Encode an image into the jpeg2000 format
 233         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 234           COMMAND opj_compress
 235           ${CMD_ARG_LIST_2}
 236         )
 237
 238         if(FAILED_TEST_FOUND)
 239             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 240         else()
 241
 242           # Dump the encoding file
 243           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 244             COMMAND opj_dump
 245             -i ${OUTPUT_FILENAME}
 246             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 247           )
 248           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 249                                PROPERTIES DEPENDS
 250                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 251
 252           # Compare the dump file with the baseline
 253           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 254             COMMAND compare_dump_files
 255             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 256             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 257           )
 258
 259           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 260                                PROPERTIES DEPENDS
 261                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 262
 263           # Decode the encoding file with kakadu expand command
 264           if (KDU_EXPAND_EXECUTABLE)
 265             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 266               COMMAND ${KDU_EXPAND_EXECUTABLE}
 267               -i ${OUTPUT_FILENAME}
 268               -o ${OUTPUT_FILENAME}.raw
 269               )
 270
 271             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 272                                  PROPERTIES DEPENDS
 273                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 274
 275             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 276             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 277               COMMAND compareRAWimages
 278               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 279               -t ${OUTPUT_FILENAME}.raw
 280             )
 281
 282             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 283                                  PROPERTIES DEPENDS
 284                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 285
 286           endif()
 287       endif()
 288
 289     # DECODER TEST SUITE
 290     else()
 291       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 292
 293       # Decode the input image
 294       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 295         COMMAND opj_decompress
 296         ${CMD_ARG_LIST_2}
 297       )
 298
 299       if(FAILED_TEST_FOUND)
 300
 301         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 302
 303       else()
 304         # if not failed, check against registered md5:
 305         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 306           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 307           -DFILENAME:STRING=${INPUT_FILENAME_NAME}
 308           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 309
 310
 311 # FIXME: add a compare2base function base on raw which
 312 # can output png diff files if necesary
 313 #  add_test(NR-${filename}-compare2base
 314 #      ${EXECUTABLE_OUTPUT_PATH}/comparePGXimages
 315 #     -b ${BASELINE_NR}/opj_${filenameRef}
 316 #     -t ${TEMP}/${filename}.pgx
 317 #     -n ${nbComponents}
 318 #     -d
 319 #     -s b_t_
 320 #     )
 321 #
 322 #  set_tests_properties(NR-${filename}-compare2base
 323 #                       PROPERTIES DEPENDS
 324 #                       NR-${filename}-decode)
 325
 326       endif()
 327
 328     endif()
 329
 330   endif()
 331
 332 endforeach()