tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   4
   5 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   7 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
   8
   9
  10 set(INPUT_NR_PATH ${INPUT_NR})
  11 set(TEMP_PATH ${TEMP})
  12 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  13
  14 # need kdu_expand if possible
  15 find_package(KAKADU)
  16
  17 #########################################################################
  18 # GENERATION OF THE TEST SUITE (DUMP)
  19 # Dump all files with the selected extension inside the input directory
  20
  21 # Define a list of file which should be gracefully rejected:
  22 set(BLACKLIST_JPEG2000
  23     broken.jp2
  24     broken2.jp2
  25     broken3.jp2
  26     broken4.jp2
  27     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  28     gdal_fuzzer_check_comp_dx_dy.jp2
  29     gdal_fuzzer_check_number_of_tiles.jp2
  30     gdal_fuzzer_unchecked_numresolutions.jp2
  31    )
  32
  33 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  34      "${INPUT_NR}/*.j2k"
  35      "${INPUT_NR}/*.j2c"
  36      "${INPUT_NR}/*.jp2"
  37      #"${INPUT_NR}/*.jpx"
  38      )
  39
  40 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  41   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  42   get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  43   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
  44
  45   # Dump the input image
  46   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
  47            COMMAND opj_dump
  48                -i ${INPUT_FILENAME}
  49                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
  50                -v
  51                )
  52
  53   if(bad_jpeg2000)
  54     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
  55                          PROPERTIES WILL_FAIL TRUE)
  56
  57   else()
  58
  59     # Compare the dump output with the baseline
  60     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
  61                 COMMAND compare_dump_files
  62             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
  63             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
  64             )
  65
  66     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
  67                          PROPERTIES DEPENDS
  68                          NR-${INPUT_FILENAME_NAME}-dump)
  69   endif()
  70
  71 endforeach()
  72
  73
  74 #########################################################################
  75 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
  76 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
  77 # to know which files processed and with which options.
  78
  79 # Configure the test suite file:
  80 configure_file("test_suite.ctest.in"
  81                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
  82                @ONLY)
  83
  84 # Read the file into a list
  85 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
  86
  87 # Try to find and configure and read another test suite file
  88 file(GLOB TEST_SUITE_FILES *.ctest.in)
  89 if (TEST_SUITE_FILES)
  90   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
  91
  92     # Avoid to process the official test suite
  93     set(FILE_ALREADY_READ 0)
  94     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
  95     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
  96
  97     if(NOT FILE_ALREADY_READ)
  98       # Configure the additional test suite file:
  99       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 100       configure_file("${TEST_SUITE_FILE}"
 101                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 102                      @ONLY)
 103       # Read the additional file into a list
 104       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 105       # Append the list of command
 106       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 107
 108     endif()
 109
 110   endforeach()
 111
 112 else()
 113
 114   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 115
 116 endif()
 117
 118
 119 # Parse the command line found in the file(s)
 120 set(IT_TEST_ENC 0)
 121 set(IT_TEST_DEC 0)
 122 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 123
 124   set(IGNORE_LINE_FOUND 0)
 125
 126   # Replace space by ; to generate a list
 127   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 128
 129   # Check if the first argument begin by the comment sign
 130   list(GET CMD_ARG_LIST 0 EXE_NAME)
 131
 132   if(EXE_NAME)
 133     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 134   endif()
 135
 136   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 137
 138     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 139
 140   else()
 141
 142     # Check if the first argument begin by the failed sign
 143     set(FAILED_TEST_FOUND 0)
 144     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 145
 146     if (FAILED_TEST_FOUND)
 147       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 148       set(FAILED_TEST_FOUND_1 0)
 149       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 150
 151       if (FAILED_TEST_FOUND_1)
 152
 153         list(REMOVE_AT CMD_ARG_LIST 0)
 154
 155       else ()
 156
 157         set(FAILED_TEST_FOUND_2 0)
 158         list(GET CMD_ARG_LIST 1 EXE_NAME)
 159         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 160
 161         if (FAILED_TEST_FOUND_2)
 162
 163           list(REMOVE_AT CMD_ARG_LIST 0)
 164           list(REMOVE_AT CMD_ARG_LIST 0)
 165
 166         else ()
 167
 168           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 169
 170         endif ()
 171       endif ()
 172
 173     else ()
 174       # Check if the first argument is equal to opj_compress
 175       string(REGEX MATCH "^opj_compress$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 176
 177       if(EXE_NAME_FOUND)
 178
 179         string(REGEX MATCH "opj_compress" ENC_TEST_FOUND ${EXE_NAME})
 180
 181       else()
 182
 183         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 184
 185       endif()
 186
 187       list(REMOVE_AT CMD_ARG_LIST 0)
 188
 189     endif ()
 190
 191     # Parse the argument list to find the input filename and output filename
 192     set(CMD_ARG_LIST_2 "")
 193     set(ARG_POS 0)
 194     set(INPUT_ARG_POS 0)
 195     set(OUTPUT_ARG_POS 0)
 196
 197     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 198
 199       math(EXPR ARG_POS "${ARG_POS}+1" )
 200
 201       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 202       if(INPUT_ARG_FOUND)
 203         set(INPUT_ARG_POS ${ARG_POS})
 204         set(INPUT_ARG_FOUND 0)
 205       endif()
 206
 207       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 208       if(OUTPUT_ARG_FOUND)
 209         set(OUTPUT_ARG_POS ${ARG_POS})
 210         set(OUTPUT_ARG_FOUND 0)
 211       endif()
 212
 213       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 214
 215     endforeach()
 216
 217     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 218     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 219     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 220     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 221     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 222
 223     #-----
 224     # Now we can add the test suite corresponding to a line command in the file
 225     #-----
 226
 227     # ENCODER TEST SUITE
 228     if(ENC_TEST_FOUND)
 229         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 230
 231         # Encode an image into the jpeg2000 format
 232         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 233           COMMAND opj_compress
 234           ${CMD_ARG_LIST_2}
 235         )
 236
 237         if(FAILED_TEST_FOUND)
 238             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 239         else()
 240
 241           # Dump the encoding file
 242           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 243             COMMAND opj_dump
 244             -i ${OUTPUT_FILENAME}
 245             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 246           )
 247           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 248                                PROPERTIES DEPENDS
 249                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 250
 251           # Compare the dump file with the baseline
 252           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 253             COMMAND compare_dump_files
 254             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 255             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 256           )
 257
 258           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 259                                PROPERTIES DEPENDS
 260                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 261
 262           # Decode the encoding file with kakadu expand command
 263           if (KDU_EXPAND_EXECUTABLE)
 264             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 265               COMMAND ${KDU_EXPAND_EXECUTABLE}
 266               -i ${OUTPUT_FILENAME}
 267               -o ${OUTPUT_FILENAME}.raw
 268               )
 269
 270             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 271                                  PROPERTIES DEPENDS
 272                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 273
 274             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 275             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 276               COMMAND compareRAWimages
 277               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 278               -t ${OUTPUT_FILENAME}.raw
 279             )
 280
 281             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 282                                  PROPERTIES DEPENDS
 283                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 284
 285           endif()
 286       endif()
 287
 288     # DECODER TEST SUITE
 289     else()
 290       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 291
 292       # Decode the input image
 293       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 294         COMMAND opj_decompress
 295         ${CMD_ARG_LIST_2}
 296       )
 297
 298       if(FAILED_TEST_FOUND)
 299
 300         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 301
 302       else()
 303
 304 # FIXME: add a compare2base function base on raw which
 305 # can output png diff files if necesary
 306 #  add_test(NR-${filename}-compare2base
 307 #      ${EXECUTABLE_OUTPUT_PATH}/comparePGXimages
 308 #     -b ${BASELINE_NR}/opj_${filenameRef}
 309 #     -t ${TEMP}/${filename}.pgx
 310 #     -n ${nbComponents}
 311 #     -d
 312 #     -s b_t_
 313 #     )
 314 #
 315 #  set_tests_properties(NR-${filename}-compare2base
 316 #                       PROPERTIES DEPENDS
 317 #                       NR-${filename}-decode)
 318
 319       endif()
 320
 321     endif()
 322
 323   endif()
 324
 325 endforeach()