tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   4
   5 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   7 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
   8
   9
  10 set(INPUT_NR_PATH ${INPUT_NR})
  11 set(TEMP_PATH ${TEMP})
  12 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  13
  14 # need kdu_expand if possible
  15 find_package(KAKADU)
  16
  17 #########################################################################
  18 # GENERATION OF THE TEST SUITE (DUMP)
  19 # Dump all files with the selected extension inside the input directory
  20
  21 # technically opj_dump should simply parse these one, since syntax is ok.
  22 set(BLACKLIST_JPEG2000_TMP
  23     2539.pdf.SIGFPE.706.1712.jp2
  24     0290cb77c5df21828fa74cf2ab2c84d8.SIGFPE.d25.31.jp2
  25     26ccf3651020967f7778238ef5af08af.SIGFPE.d25.527.jp2
  26     4035.pdf.SIGSEGV.d8b.3375.jp2
  27     3635.pdf.asan.77.2930.jp2
  28     issue165.jp2
  29     #edf_c2_1103421.jp2
  30     edf_c2_1178956.jp2
  31     edf_c2_1000290.jp2
  32     #edf_c2_1000691.jp2 # ok
  33     #edf_c2_20.jp2 #looks ok as per kdu_jp2info
  34     edf_c2_1377017.jp2
  35     edf_c2_1002767.jp2
  36     #edf_c2_10025.jp2
  37     edf_c2_1000234.jp2
  38     edf_c2_225881.jp2
  39     edf_c2_1000671.jp2
  40     #edf_c2_1013627.jp2 # weird box, but kdu_jp2info ok
  41     edf_c2_1015644.jp2
  42     edf_c2_101463.jp2
  43     edf_c2_1674177.jp2
  44     edf_c2_1673169.jp2
  45    )
  46
  47 # Define a list of file which should be gracefully rejected:
  48 set(BLACKLIST_JPEG2000
  49     ${BLACKLIST_JPEG2000_TMP}
  50     broken.jp2
  51     broken2.jp2
  52     broken3.jp2
  53     broken4.jp2
  54     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  55     gdal_fuzzer_check_comp_dx_dy.jp2
  56     gdal_fuzzer_check_number_of_tiles.jp2
  57     gdal_fuzzer_unchecked_numresolutions.jp2
  58     mem-b2ace68c-1381.jp2
  59     1851.pdf.SIGSEGV.ce9.948.jp2
  60    )
  61
  62 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  63      "${INPUT_NR}/*.j2k"
  64      "${INPUT_NR}/*.j2c"
  65      "${INPUT_NR}/*.jp2"
  66      "${INPUT_NR}/*.jpc"
  67      #"${INPUT_NR}/*.jpx"
  68      )
  69
  70 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  71   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  72   #get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  73   # cannot use longest extension function, since some name contains multiples
  74   # dots. Instead write out own shortest extension function:
  75   string(FIND ${INPUT_FILENAME_NAME} "." SHORTEST_EXT_POS REVERSE)
  76   string(SUBSTRING ${INPUT_FILENAME_NAME} 0 ${SHORTEST_EXT_POS} INPUT_FILENAME_NAME_WE)
  77   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
  78
  79   # Dump the input image
  80   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
  81            COMMAND opj_dump
  82                -i ${INPUT_FILENAME}
  83                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
  84                -v
  85                )
  86
  87   if(bad_jpeg2000)
  88     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
  89                          PROPERTIES WILL_FAIL TRUE)
  90
  91   else()
  92
  93     # Compare the dump output with the baseline
  94     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
  95                 COMMAND compare_dump_files
  96             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
  97             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
  98             )
  99
 100     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
 101                          PROPERTIES DEPENDS
 102                          NR-${INPUT_FILENAME_NAME}-dump)
 103   endif()
 104
 105 endforeach()
 106
 107
 108 #########################################################################
 109 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
 110 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
 111 # to know which files processed and with which options.
 112
 113 # Configure the test suite file:
 114 configure_file("test_suite.ctest.in"
 115                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
 116                @ONLY)
 117
 118 # Read the file into a list
 119 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
 120
 121 # Try to find and configure and read another test suite file
 122 file(GLOB TEST_SUITE_FILES *.ctest.in)
 123 if (TEST_SUITE_FILES)
 124   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
 125
 126     # Avoid to process the official test suite
 127     set(FILE_ALREADY_READ 0)
 128     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
 129     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 130
 131     if(NOT FILE_ALREADY_READ)
 132       # Configure the additional test suite file:
 133       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 134       configure_file("${TEST_SUITE_FILE}"
 135                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 136                      @ONLY)
 137       # Read the additional file into a list
 138       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 139       # Append the list of command
 140       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 141
 142     endif()
 143
 144   endforeach()
 145
 146 else()
 147
 148   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 149
 150 endif()
 151
 152
 153 set(nonregression_filenames_used)
 154 # Parse the command line found in the file(s)
 155 set(IT_TEST_ENC 0)
 156 set(IT_TEST_DEC 0)
 157 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 158
 159   set(IGNORE_LINE_FOUND 0)
 160
 161   # Replace space by ; to generate a list
 162   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 163
 164   # Check if the first argument begin by the comment sign
 165   list(GET CMD_ARG_LIST 0 EXE_NAME)
 166
 167   if(EXE_NAME)
 168     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 169   endif()
 170
 171   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 172
 173     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 174
 175   else()
 176
 177     # Check if the first argument begin by the failed sign
 178     set(FAILED_TEST_FOUND 0)
 179     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 180
 181     if (FAILED_TEST_FOUND)
 182       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 183       set(FAILED_TEST_FOUND_1 0)
 184       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 185
 186       if (FAILED_TEST_FOUND_1)
 187
 188         list(REMOVE_AT CMD_ARG_LIST 0)
 189
 190       else ()
 191
 192         set(FAILED_TEST_FOUND_2 0)
 193         list(GET CMD_ARG_LIST 1 EXE_NAME)
 194         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 195
 196         if (FAILED_TEST_FOUND_2)
 197
 198           list(REMOVE_AT CMD_ARG_LIST 0)
 199           list(REMOVE_AT CMD_ARG_LIST 0)
 200
 201         else ()
 202
 203           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 204
 205         endif ()
 206       endif ()
 207
 208     else ()
 209       # Check if the first argument is equal to opj_compress
 210       string(REGEX MATCH "^opj_compress$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 211
 212       if(EXE_NAME_FOUND)
 213
 214         string(REGEX MATCH "opj_compress" ENC_TEST_FOUND ${EXE_NAME})
 215
 216       else()
 217
 218         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 219
 220       endif()
 221
 222       list(REMOVE_AT CMD_ARG_LIST 0)
 223
 224     endif ()
 225
 226     # Parse the argument list to find the input filename and output filename
 227     set(CMD_ARG_LIST_2 "")
 228     set(ARG_POS 0)
 229     set(INPUT_ARG_POS 0)
 230     set(OUTPUT_ARG_POS 0)
 231
 232     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 233
 234       math(EXPR ARG_POS "${ARG_POS}+1" )
 235
 236       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 237       if(INPUT_ARG_FOUND)
 238         set(INPUT_ARG_POS ${ARG_POS})
 239         set(INPUT_ARG_FOUND 0)
 240       endif()
 241
 242       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 243       if(OUTPUT_ARG_FOUND)
 244         set(OUTPUT_ARG_POS ${ARG_POS})
 245         set(OUTPUT_ARG_FOUND 0)
 246       endif()
 247
 248       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 249
 250     endforeach()
 251
 252     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 253     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 254     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 255     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 256     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 257
 258     #-----
 259     # Now we can add the test suite corresponding to a line command in the file
 260     #-----
 261     # ENCODER TEST SUITE
 262     if(ENC_TEST_FOUND)
 263         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 264
 265         # Encode an image into the jpeg2000 format
 266         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 267           COMMAND opj_compress
 268           ${CMD_ARG_LIST_2}
 269         )
 270
 271         if(FAILED_TEST_FOUND)
 272             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 273         else()
 274
 275           # Dump the encoding file
 276           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 277             COMMAND opj_dump
 278             -i ${OUTPUT_FILENAME}
 279             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 280           )
 281           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 282                                PROPERTIES DEPENDS
 283                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 284
 285           # Compare the dump file with the baseline
 286           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 287             COMMAND compare_dump_files
 288             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 289             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 290           )
 291
 292           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 293                                PROPERTIES DEPENDS
 294                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 295
 296           # Decode the encoding file with kakadu expand command
 297           if (KDU_EXPAND_EXECUTABLE)
 298             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 299               COMMAND ${KDU_EXPAND_EXECUTABLE}
 300               -i ${OUTPUT_FILENAME}
 301               -o ${OUTPUT_FILENAME}.raw
 302               )
 303
 304             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 305                                  PROPERTIES DEPENDS
 306                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 307
 308             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 309             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 310               COMMAND compare_raw_files
 311               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 312               -t ${OUTPUT_FILENAME}.raw
 313             )
 314
 315             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 316                                  PROPERTIES DEPENDS
 317                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 318
 319           endif()
 320       endif()
 321
 322     # DECODER TEST SUITE
 323     else()
 324       string(FIND ${INPUT_FILENAME} "nonregression" nr_pos)
 325       if(${nr_pos} GREATER 0)
 326         list(APPEND nonregression_filenames_used ${INPUT_FILENAME_NAME})
 327       endif()
 328       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 329
 330       # Decode the input image
 331       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 332         COMMAND opj_decompress
 333         ${CMD_ARG_LIST_2}
 334       )
 335
 336       if(FAILED_TEST_FOUND)
 337
 338         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 339
 340       else()
 341         # if not failed, check against registered md5:
 342         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 343           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 344           -DOUTFILENAME:STRING=${OUTPUT_FILENAME}
 345           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 346
 347         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5
 348           PROPERTIES DEPENDS NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 349         )
 350
 351 # FIXME: add a compare2base function base on raw which
 352 # can output png diff files if necesary
 353 #  add_test(NR-${filename}-compare2base
 354 #      ${EXECUTABLE_OUTPUT_PATH}/compare_images
 355 #     -b ${BASELINE_NR}/opj_${filenameRef}
 356 #     -t ${TEMP}/${filename}.pgx
 357 #     -n ${nbComponents}
 358 #     -d
 359 #     -s b_t_
 360 #     )
 361 #
 362 #  set_tests_properties(NR-${filename}-compare2base
 363 #                       PROPERTIES DEPENDS
 364 #                       NR-${filename}-decode)
 365
 366       endif()
 367
 368     endif()
 369
 370   endif()
 371
 372 endforeach()
 373
 374 set(existing_filenames)
 375 foreach(f ${OPJ_DATA_NR_LIST})
 376   get_filename_component(ff ${f} NAME)
 377   list(APPEND existing_filenames ${ff})
 378 endforeach()
 379 if(existing_filenames)
 380 list(REMOVE_ITEM existing_filenames ${nonregression_filenames_used})
 381 endif()
 382
 383 # keep track of new addition:
 384 # if we reach here, then a J2K files was added but no test is present in
 385 # test_suite.ctest.in:
 386 foreach(found_but_no_test ${existing_filenames})
 387   add_test(NAME Found-But-No-Test-${found_but_no_test} COMMAND ${CMAKE_COMMAND} -E echo "${found_but_no_test}")
 388   set_tests_properties(Found-But-No-Test-${found_but_no_test} PROPERTIES WILL_FAIL TRUE)
 389 endforeach()