tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   4
   5 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   7 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
   8
   9
  10 set(INPUT_NR_PATH ${INPUT_NR})
  11 set(TEMP_PATH ${TEMP})
  12 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  13
  14 # need kdu_expand if possible
  15 find_package(KAKADU)
  16
  17 #########################################################################
  18 # GENERATION OF THE TEST SUITE (DUMP)
  19 # Dump all files with the selected extension inside the input directory
  20
  21 # technically opj_dump should simply parse these one, since syntax is ok.
  22 set(BLACKLIST_JPEG2000_TMP
  23     2539.pdf.SIGFPE.706.1712.jp2
  24     0290cb77c5df21828fa74cf2ab2c84d8.SIGFPE.d25.31.jp2
  25     26ccf3651020967f7778238ef5af08af.SIGFPE.d25.527.jp2
  26     4035.pdf.SIGSEGV.d8b.3375.jp2
  27     3635.pdf.asan.77.2930.jp2
  28     issue165.jp2
  29     #edf_c2_1103421.jp2
  30     edf_c2_1178956.jp2
  31     edf_c2_1000290.jp2
  32     #edf_c2_1000691.jp2 # ok
  33     #edf_c2_20.jp2 #looks ok as per kdu_jp2info
  34     edf_c2_1377017.jp2
  35     edf_c2_1002767.jp2
  36     #edf_c2_10025.jp2
  37     edf_c2_1000234.jp2
  38     edf_c2_225881.jp2
  39     edf_c2_1000671.jp2
  40     #edf_c2_1013627.jp2 # weird box, but kdu_jp2info ok
  41     edf_c2_1015644.jp2
  42     edf_c2_101463.jp2
  43     edf_c2_1674177.jp2
  44     edf_c2_1673169.jp2
  45     issue429.jp2
  46     issue427-null-image-size.jp2
  47    )
  48
  49 # Define a list of file which should be gracefully rejected:
  50 set(BLACKLIST_JPEG2000
  51     ${BLACKLIST_JPEG2000_TMP}
  52     broken.jp2
  53     broken2.jp2
  54     broken3.jp2
  55     broken4.jp2
  56     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  57     gdal_fuzzer_check_comp_dx_dy.jp2
  58     gdal_fuzzer_check_number_of_tiles.jp2
  59     gdal_fuzzer_unchecked_numresolutions.jp2
  60     mem-b2ace68c-1381.jp2
  61     1851.pdf.SIGSEGV.ce9.948.jp2
  62     1888.pdf.asan.35.988.jp2
  63     issue362-2863.jp2 #kdu_jp2info ok
  64     issue362-2866.jp2
  65     issue362-2894.jp2
  66     issue400.jp2 #kdu_jp2info ok
  67     issue364-38.jp2
  68     issue364-903.jp2 #kdu_jp2info ok
  69     issue393.jp2 #kdu_jp2info ok
  70     issue408.jp2 #kdu_jp2info ok
  71     issue420.jp2 #kdu_jp2info ok
  72    )
  73
  74 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  75      "${INPUT_NR}/*.j2k"
  76      "${INPUT_NR}/*.j2c"
  77      "${INPUT_NR}/*.jp2"
  78      "${INPUT_NR}/*.jpc"
  79      #"${INPUT_NR}/*.jpx"
  80      )
  81
  82 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  83   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  84   #get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  85   # cannot use longest extension function, since some name contains multiples
  86   # dots. Instead write out own shortest extension function:
  87   string(FIND ${INPUT_FILENAME_NAME} "." SHORTEST_EXT_POS REVERSE)
  88   string(SUBSTRING ${INPUT_FILENAME_NAME} 0 ${SHORTEST_EXT_POS} INPUT_FILENAME_NAME_WE)
  89   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
  90
  91   # Dump the input image
  92   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
  93            COMMAND opj_dump
  94                -i ${INPUT_FILENAME}
  95                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
  96                -v
  97                )
  98
  99   if(bad_jpeg2000)
 100     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
 101                          PROPERTIES WILL_FAIL TRUE)
 102
 103   else()
 104
 105     # Compare the dump output with the baseline
 106     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
 107                 COMMAND compare_dump_files
 108             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
 109             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
 110             )
 111
 112     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
 113                          PROPERTIES DEPENDS
 114                          NR-${INPUT_FILENAME_NAME}-dump)
 115   endif()
 116
 117 endforeach()
 118
 119
 120 #########################################################################
 121 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
 122 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
 123 # to know which files processed and with which options.
 124
 125 # Configure the test suite file:
 126 configure_file("test_suite.ctest.in"
 127                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
 128                @ONLY)
 129
 130 # Read the file into a list
 131 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
 132
 133 # Try to find and configure and read another test suite file
 134 file(GLOB TEST_SUITE_FILES *.ctest.in)
 135 if (TEST_SUITE_FILES)
 136   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
 137
 138     # Avoid to process the official test suite
 139     set(FILE_ALREADY_READ 0)
 140     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
 141     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 142
 143     if(NOT FILE_ALREADY_READ)
 144       # Configure the additional test suite file:
 145       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 146       configure_file("${TEST_SUITE_FILE}"
 147                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 148                      @ONLY)
 149       # Read the additional file into a list
 150       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 151       # Append the list of command
 152       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 153
 154     endif()
 155
 156   endforeach()
 157
 158 else()
 159
 160   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 161
 162 endif()
 163
 164
 165 set(nonregression_filenames_used)
 166 # Parse the command line found in the file(s)
 167 set(IT_TEST_ENC 0)
 168 set(IT_TEST_DEC 0)
 169 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 170
 171   set(IGNORE_LINE_FOUND 0)
 172
 173   # Replace space by ; to generate a list
 174   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 175
 176   # Check if the first argument begin by the comment sign
 177   list(GET CMD_ARG_LIST 0 EXE_NAME)
 178
 179   if(EXE_NAME)
 180     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 181   endif()
 182
 183   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 184
 185     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 186
 187   else()
 188
 189     # Check if the first argument begin by the failed sign
 190     set(FAILED_TEST_FOUND 0)
 191     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 192
 193     if (FAILED_TEST_FOUND)
 194       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 195       set(FAILED_TEST_FOUND_1 0)
 196       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 197
 198       if (FAILED_TEST_FOUND_1)
 199
 200         list(REMOVE_AT CMD_ARG_LIST 0)
 201
 202       else ()
 203
 204         set(FAILED_TEST_FOUND_2 0)
 205         list(GET CMD_ARG_LIST 1 EXE_NAME)
 206         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 207
 208         if (FAILED_TEST_FOUND_2)
 209
 210           list(REMOVE_AT CMD_ARG_LIST 0)
 211           list(REMOVE_AT CMD_ARG_LIST 0)
 212
 213         else ()
 214
 215           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 216
 217         endif ()
 218       endif ()
 219
 220     else ()
 221       # Check if the first argument is equal to opj_compress
 222       string(REGEX MATCH "^opj_compress$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 223
 224       if(EXE_NAME_FOUND)
 225
 226         string(REGEX MATCH "opj_compress" ENC_TEST_FOUND ${EXE_NAME})
 227
 228       else()
 229
 230         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 231
 232       endif()
 233
 234       list(REMOVE_AT CMD_ARG_LIST 0)
 235
 236     endif ()
 237
 238     # Parse the argument list to find the input filename and output filename
 239     set(CMD_ARG_LIST_2 "")
 240     set(ARG_POS 0)
 241     set(INPUT_ARG_POS 0)
 242     set(OUTPUT_ARG_POS 0)
 243
 244     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 245
 246       math(EXPR ARG_POS "${ARG_POS}+1" )
 247
 248       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 249       if(INPUT_ARG_FOUND)
 250         set(INPUT_ARG_POS ${ARG_POS})
 251         set(INPUT_ARG_FOUND 0)
 252       endif()
 253
 254       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 255       if(OUTPUT_ARG_FOUND)
 256         set(OUTPUT_ARG_POS ${ARG_POS})
 257         set(OUTPUT_ARG_FOUND 0)
 258       endif()
 259
 260       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 261
 262     endforeach()
 263
 264     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 265     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 266     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 267     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 268     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 269
 270     #-----
 271     # Now we can add the test suite corresponding to a line command in the file
 272     #-----
 273     # ENCODER TEST SUITE
 274     if(ENC_TEST_FOUND)
 275         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 276
 277         # Encode an image into the jpeg2000 format
 278         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 279           COMMAND opj_compress
 280           ${CMD_ARG_LIST_2}
 281         )
 282
 283         if(FAILED_TEST_FOUND)
 284             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 285         else()
 286
 287           # Dump the encoding file
 288           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 289             COMMAND opj_dump
 290             -i ${OUTPUT_FILENAME}
 291             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 292           )
 293           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 294                                PROPERTIES DEPENDS
 295                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 296
 297           # Compare the dump file with the baseline
 298           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 299             COMMAND compare_dump_files
 300             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 301             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 302           )
 303
 304           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 305                                PROPERTIES DEPENDS
 306                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 307
 308           # Decode the encoding file with kakadu expand command
 309           if (KDU_EXPAND_EXECUTABLE)
 310             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 311               COMMAND ${KDU_EXPAND_EXECUTABLE}
 312               -i ${OUTPUT_FILENAME}
 313               -o ${OUTPUT_FILENAME}.raw
 314               )
 315
 316             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 317                                  PROPERTIES DEPENDS
 318                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 319
 320             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 321             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 322               COMMAND compare_raw_files
 323               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 324               -t ${OUTPUT_FILENAME}.raw
 325             )
 326
 327             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 328                                  PROPERTIES DEPENDS
 329                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 330
 331           endif()
 332       endif()
 333
 334     # DECODER TEST SUITE
 335     else()
 336       string(FIND ${INPUT_FILENAME} "nonregression" nr_pos)
 337       if(${nr_pos} GREATER 0)
 338         list(APPEND nonregression_filenames_used ${INPUT_FILENAME_NAME})
 339       endif()
 340       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 341
 342       # Decode the input image
 343       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 344         COMMAND opj_decompress
 345         ${CMD_ARG_LIST_2}
 346       )
 347
 348       if(FAILED_TEST_FOUND)
 349
 350         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 351
 352       else()
 353         # if not failed, check against registered md5:
 354         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 355           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 356           -DOUTFILENAME:STRING=${OUTPUT_FILENAME}
 357           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 358
 359         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5
 360           PROPERTIES DEPENDS NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 361         )
 362
 363 # FIXME: add a compare2base function base on raw which
 364 # can output png diff files if necesary
 365 #  add_test(NR-${filename}-compare2base
 366 #      ${EXECUTABLE_OUTPUT_PATH}/compare_images
 367 #     -b ${BASELINE_NR}/opj_${filenameRef}
 368 #     -t ${TEMP}/${filename}.pgx
 369 #     -n ${nbComponents}
 370 #     -d
 371 #     -s b_t_
 372 #     )
 373 #
 374 #  set_tests_properties(NR-${filename}-compare2base
 375 #                       PROPERTIES DEPENDS
 376 #                       NR-${filename}-decode)
 377
 378       endif()
 379
 380     endif()
 381
 382   endif()
 383
 384 endforeach()
 385
 386 set(existing_filenames)
 387 foreach(f ${OPJ_DATA_NR_LIST})
 388   get_filename_component(ff ${f} NAME)
 389   list(APPEND existing_filenames ${ff})
 390 endforeach()
 391 if(existing_filenames)
 392 list(REMOVE_ITEM existing_filenames ${nonregression_filenames_used})
 393 endif()
 394
 395 # keep track of new addition:
 396 # if we reach here, then a J2K files was added but no test is present in
 397 # test_suite.ctest.in:
 398 foreach(found_but_no_test ${existing_filenames})
 399   add_test(NAME Found-But-No-Test-${found_but_no_test} COMMAND ${CMAKE_COMMAND} -E echo "${found_but_no_test}")
 400   set_tests_properties(Found-But-No-Test-${found_but_no_test} PROPERTIES WILL_FAIL TRUE)
 401 endforeach()