tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   4
   5 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   7 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
   8
   9
  10 set(INPUT_NR_PATH ${INPUT_NR})
  11 set(TEMP_PATH ${TEMP})
  12 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  13
  14 # need kdu_expand if possible
  15 find_package(KAKADU)
  16
  17 #########################################################################
  18 # GENERATION OF THE TEST SUITE (DUMP)
  19 # Dump all files with the selected extension inside the input directory
  20
  21 # Define a list of file which should be gracefully rejected:
  22 set(BLACKLIST_JPEG2000
  23     empty
  24    )
  25
  26 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  27      "${INPUT_NR}/*.j2k"
  28      "${INPUT_NR}/*.j2c"
  29      "${INPUT_NR}/*.jp2"
  30      #"${INPUT_NR}/*.jpx"
  31      )
  32
  33 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  34   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  35   get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  36   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
  37
  38   # Dump the input image
  39   add_test(NR-${INPUT_FILENAME_NAME}-dump
  40            ${EXECUTABLE_OUTPUT_PATH}/j2k_dump
  41                -i ${INPUT_FILENAME}
  42                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
  43                -v
  44                )
  45
  46   if(bad_jpeg2000)
  47     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
  48                          PROPERTIES WILL_FAIL TRUE)
  49
  50   else(bad_jpeg2000)
  51
  52     # Compare the dump output with the baseline
  53     add_test(NR-${INPUT_FILENAME_NAME}-compare_dump2base
  54                 ${EXECUTABLE_OUTPUT_PATH}/compare_dump_files
  55             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
  56             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
  57             )
  58
  59     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
  60                          PROPERTIES DEPENDS
  61                          NR-${INPUT_FILENAME_NAME}-dump)
  62   endif(bad_jpeg2000)
  63
  64 endforeach(INPUT_FILENAME)
  65
  66
  67 #########################################################################
  68 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
  69 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
  70 # to know which files processed and with which options.
  71
  72 # Configure the test suite file:
  73 configure_file("test_suite.ctest.in"
  74                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
  75                @ONLY)
  76
  77 # Read the file into a list
  78 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
  79
  80 # Try to find and configure and read another test suite file
  81 file(GLOB TEST_SUITE_FILES *.ctest.in)
  82 if (TEST_SUITE_FILES)
  83   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
  84
  85     # Avoid to process the official test suite
  86     set(FILE_ALREADY_READ 0)
  87     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
  88     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
  89
  90     if(NOT FILE_ALREADY_READ)
  91       # Configure the additional test suite file:
  92       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
  93       configure_file("${TEST_SUITE_FILE}"
  94                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
  95                      @ONLY)
  96       # Read the additional file into a list
  97       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
  98       # Append the list of command
  99       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 100
 101     endif(NOT FILE_ALREADY_READ)
 102
 103   endforeach(TEST_SUITE_FILE)
 104
 105 else(TEST_SUITE_FILES)
 106
 107   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 108
 109 endif(TEST_SUITE_FILES)
 110
 111
 112 # Parse the command line found in the file(s)
 113 set(IT_TEST_ENC 0)
 114 set(IT_TEST_DEC 0)
 115 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 116
 117   set(IGNORE_LINE_FOUND 0)
 118
 119   # Replace space by ; to generate a list
 120   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 121
 122   # Check if the first argument begin by the comment sign
 123   list(GET CMD_ARG_LIST 0 EXE_NAME)
 124
 125   if(EXE_NAME)
 126     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 127   endif(EXE_NAME)
 128
 129   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 130
 131     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 132
 133   else(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 134
 135     # Check if the first argument begin by the failed sign
 136     set(FAILED_TEST_FOUND 0)
 137     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 138
 139     if (FAILED_TEST_FOUND)
 140       # Manage the different cases with the failed sign to remove the first argument which must be image_to_j2k
 141       set(FAILED_TEST_FOUND_1 0)
 142       string(REGEX MATCH "^!image_to_j2k$|^!j2k_to_image$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 143
 144       if (FAILED_TEST_FOUND_1)
 145
 146         list(REMOVE_AT CMD_ARG_LIST 0)
 147
 148       else (FAILED_TEST_FOUND_1)
 149
 150         set(FAILED_TEST_FOUND_2 0)
 151         list(GET CMD_ARG_LIST 1 EXE_NAME)
 152         string(REGEX MATCH "^image_to_j2k$|^j2k_to_image$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 153
 154         if (FAILED_TEST_FOUND_2)
 155
 156           list(REMOVE_AT CMD_ARG_LIST 0)
 157           list(REMOVE_AT CMD_ARG_LIST 0)
 158
 159         else (FAILED_TEST_FOUND_2)
 160
 161           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use image_to_j2k or j2k_to_image)")
 162
 163         endif (FAILED_TEST_FOUND_2)
 164       endif (FAILED_TEST_FOUND_1)
 165
 166     else (FAILED_TEST_FOUND)
 167       # Check if the first argument is equal to image_to_j2k
 168       string(REGEX MATCH "^image_to_j2k$|^j2k_to_image$" EXE_NAME_FOUND ${EXE_NAME})
 169
 170       if(EXE_NAME_FOUND)
 171
 172         string(REGEX MATCH "image_to_j2k" ENC_TEST_FOUND ${EXE_NAME})
 173
 174       else(EXE_NAME_FOUND)
 175
 176         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use image_to_j2k)")
 177
 178       endif(EXE_NAME_FOUND)
 179
 180       list(REMOVE_AT CMD_ARG_LIST 0)
 181
 182     endif (FAILED_TEST_FOUND)
 183
 184     # Parse the argument list to find the input filename and output filename
 185     set(CMD_ARG_LIST_2 "")
 186     set(ARG_POS 0)
 187     set(INPUT_ARG_POS 0)
 188     set(OUTPUT_ARG_POS 0)
 189
 190     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 191
 192       math(EXPR ARG_POS "${ARG_POS}+1" )
 193
 194       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 195       if(INPUT_ARG_FOUND)
 196         set(INPUT_ARG_POS ${ARG_POS})
 197         set(INPUT_ARG_FOUND 0)
 198       endif(INPUT_ARG_FOUND)
 199
 200       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 201       if(OUTPUT_ARG_FOUND)
 202         set(OUTPUT_ARG_POS ${ARG_POS})
 203         set(OUTPUT_ARG_FOUND 0)
 204       endif(OUTPUT_ARG_FOUND)
 205
 206       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 207
 208     endforeach(CMD_ARG_ELT)
 209
 210     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 211     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 212     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 213     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 214     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 215
 216     #-----
 217     # Now we can add the test suite corresponding to a line command in the file
 218     #-----
 219
 220     # ENCODER TEST SUITE
 221     if(ENC_TEST_FOUND)
 222         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 223
 224         # Encode an image into the jpeg2000 format
 225         add_test(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 226           ${EXECUTABLE_OUTPUT_PATH}/image_to_j2k
 227           ${CMD_ARG_LIST_2}
 228         )
 229
 230         if(FAILED_TEST_FOUND)
 231             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 232         else(FAILED_TEST_FOUND)
 233
 234           # Dump the encoding file
 235           add_test(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 236             ${EXECUTABLE_OUTPUT_PATH}/j2k_dump
 237             -i ${OUTPUT_FILENAME}
 238             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 239           )
 240           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 241                                PROPERTIES DEPENDS
 242                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 243
 244           # Compare the dump file with the baseline
 245           add_test(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 246             ${EXECUTABLE_OUTPUT_PATH}/compare_dump_files
 247             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 248             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 249           )
 250
 251           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 252                                PROPERTIES DEPENDS
 253                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 254
 255           # Decode the encoding file with kakadu expand command
 256           if (KDU_EXPAND_EXECUTABLE)
 257             add_test(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 258               ${KDU_EXPAND_EXECUTABLE}
 259               -i ${OUTPUT_FILENAME}
 260               -o ${OUTPUT_FILENAME}.raw
 261               )
 262
 263             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 264                                  PROPERTIES DEPENDS
 265                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 266
 267             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 268             add_test(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 269               ${EXECUTABLE_OUTPUT_PATH}/compareRAWimages
 270               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 271               -t ${OUTPUT_FILENAME}.raw
 272             )
 273
 274             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 275                                  PROPERTIES DEPENDS
 276                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 277
 278           endif()
 279       endif(FAILED_TEST_FOUND)
 280
 281     # DECODER TEST SUITE
 282     else(ENC_TEST_FOUND)
 283       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 284
 285       # Decode the input image
 286       add_test(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 287         ${EXECUTABLE_OUTPUT_PATH}/j2k_to_image
 288         ${CMD_ARG_LIST_2}
 289       )
 290
 291       if(FAILED_TEST_FOUND)
 292
 293         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 294
 295       else(FAILED_TEST_FOUND)
 296
 297 # FIXME: add a compare2base function base on raw which
 298 # can output png diff files if necesary
 299 #  add_test(NR-${filename}-compare2base
 300 #      ${EXECUTABLE_OUTPUT_PATH}/comparePGXimages
 301 #     -b ${BASELINE_NR}/opj_${filenameRef}
 302 #     -t ${TEMP}/${filename}.pgx
 303 #     -n ${nbComponents}
 304 #     -d
 305 #     -s b_t_
 306 #     )
 307 #
 308 #  set_tests_properties(NR-${filename}-compare2base
 309 #                       PROPERTIES DEPENDS
 310 #                       NR-${filename}-decode)
 311
 312       endif(FAILED_TEST_FOUND)
 313
 314     endif(ENC_TEST_FOUND)
 315
 316   endif(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 317
 318 endforeach(OPJ_TEST_CMD_LINE)