tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 cmake_minimum_required(VERSION 2.8.7)
   4
   5 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6
   7 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   8 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   9 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
  10
  11
  12 set(INPUT_NR_PATH ${INPUT_NR})
  13 set(TEMP_PATH ${TEMP})
  14 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  15
  16 # need kdu_expand if possible
  17 find_package(KAKADU)
  18 # need jpylyzer if possible
  19 find_package(JPYLYZER)
  20
  21 #########################################################################
  22 # GENERATION OF THE TEST SUITE (DUMP)
  23 # Dump all files with the selected extension inside the input directory
  24
  25 # technically opj_dump should simply parse these one, since syntax is ok.
  26 set(BLACKLIST_JPEG2000_TMP
  27     2539.pdf.SIGFPE.706.1712.jp2
  28     0290cb77c5df21828fa74cf2ab2c84d8.SIGFPE.d25.31.jp2
  29     26ccf3651020967f7778238ef5af08af.SIGFPE.d25.527.jp2
  30     4035.pdf.SIGSEGV.d8b.3375.jp2
  31     3635.pdf.asan.77.2930.jp2
  32     issue165.jp2
  33     #edf_c2_1103421.jp2
  34     edf_c2_1178956.jp2
  35     edf_c2_1000290.jp2
  36     #edf_c2_1000691.jp2 # ok
  37     #edf_c2_20.jp2 #looks ok as per kdu_jp2info
  38     edf_c2_1377017.jp2
  39     edf_c2_1002767.jp2
  40     edf_c2_10025.jp2
  41     edf_c2_1000234.jp2
  42     edf_c2_225881.jp2
  43     edf_c2_1000671.jp2
  44     #edf_c2_1013627.jp2 # weird box, but kdu_jp2info ok
  45     edf_c2_1015644.jp2
  46     edf_c2_101463.jp2
  47     edf_c2_1674177.jp2
  48     edf_c2_1673169.jp2
  49     issue418.jp2
  50     issue429.jp2
  51     issue427-null-image-size.jp2
  52     issue427-illegal-tile-offset.jp2
  53     issue495.jp2
  54     issue820.jp2
  55    )
  56
  57 # Define a list of file which should be gracefully rejected:
  58 set(BLACKLIST_JPEG2000
  59     ${BLACKLIST_JPEG2000_TMP}
  60     broken1.jp2
  61     broken2.jp2
  62     broken3.jp2
  63     broken4.jp2
  64     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  65     gdal_fuzzer_check_comp_dx_dy.jp2
  66     gdal_fuzzer_check_number_of_tiles.jp2
  67     gdal_fuzzer_unchecked_numresolutions.jp2
  68     mem-b2ace68c-1381.jp2
  69     1851.pdf.SIGSEGV.ce9.948.jp2
  70     1888.pdf.asan.35.988.jp2
  71     issue362-2863.jp2 #kdu_jp2info ok
  72     issue362-2866.jp2
  73     issue362-2894.jp2
  74     issue400.jp2 #kdu_jp2info ok
  75     issue364-38.jp2
  76     issue364-903.jp2 #kdu_jp2info ok
  77     issue393.jp2 #kdu_jp2info ok
  78     issue408.jp2 #kdu_jp2info ok
  79     issue420.jp2 #kdu_jp2info ok
  80     27ac957758a35d00d6765a0c86350d9c.SIGFPE.d25.537.jpc #kdu_jp2info crash
  81     3672da2f1f67bbecad27d7181b4e9d7c.SIGFPE.d25.805.jpc #kdu_jp2info crash
  82     issue475.jp2 #kdu_jp2info ok
  83     issue413.jp2 #kdu_jp2info ok
  84     issue823.jp2 #kdu_jp2info ok
  85    )
  86
  87 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  88      "${INPUT_NR}/*.j2k"
  89      "${INPUT_NR}/*.j2c"
  90      "${INPUT_NR}/*.jp2"
  91      "${INPUT_NR}/*.jpc"
  92      #"${INPUT_NR}/*.jpx"
  93      )
  94
  95 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  96   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  97   #get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  98   # cannot use longest extension function, since some name contains multiples
  99   # dots. Instead write out own shortest extension function:
 100   string(FIND ${INPUT_FILENAME_NAME} "." SHORTEST_EXT_POS REVERSE)
 101   string(SUBSTRING ${INPUT_FILENAME_NAME} 0 ${SHORTEST_EXT_POS} INPUT_FILENAME_NAME_WE)
 102   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
 103
 104   # Dump the input image
 105   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
 106            COMMAND opj_dump
 107                -i ${INPUT_FILENAME}
 108                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
 109                -v
 110                )
 111
 112   if(bad_jpeg2000)
 113     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
 114                          PROPERTIES WILL_FAIL TRUE)
 115
 116   else()
 117
 118     # Compare the dump output with the baseline
 119     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
 120                 COMMAND compare_dump_files
 121             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
 122             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
 123             )
 124
 125     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
 126                          PROPERTIES DEPENDS
 127                          NR-${INPUT_FILENAME_NAME}-dump)
 128   endif()
 129
 130 endforeach()
 131
 132
 133 #########################################################################
 134 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
 135 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
 136 # to know which files processed and with which options.
 137
 138 # Configure the test suite file:
 139 configure_file("test_suite.ctest.in"
 140                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
 141                @ONLY)
 142
 143 # Read the file into a list
 144 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
 145
 146 # Try to find and configure and read another test suite file
 147 file(GLOB TEST_SUITE_FILES *.ctest.in)
 148 if (TEST_SUITE_FILES)
 149   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
 150
 151     # Avoid to process the official test suite
 152     set(FILE_ALREADY_READ 0)
 153     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
 154     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 155
 156     if(NOT FILE_ALREADY_READ)
 157       # Configure the additional test suite file:
 158       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 159       configure_file("${TEST_SUITE_FILE}"
 160                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 161                      @ONLY)
 162       # Read the additional file into a list
 163       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 164       # Append the list of command
 165       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 166
 167     endif()
 168
 169   endforeach()
 170
 171 else()
 172
 173   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 174
 175 endif()
 176
 177
 178 set(nonregression_filenames_used)
 179 # Parse the command line found in the file(s)
 180 set(IT_TEST_ENC 0)
 181 set(IT_TEST_DEC 0)
 182 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 183
 184   set(IGNORE_LINE_FOUND 0)
 185
 186   # Replace space by ; to generate a list
 187   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 188
 189   # Check if the first argument begin by the comment sign
 190   list(GET CMD_ARG_LIST 0 EXE_NAME)
 191
 192   if(EXE_NAME)
 193     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 194   endif()
 195
 196   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 197
 198     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 199
 200   else()
 201
 202     # Check if the first argument begin by the failed sign
 203     set(FAILED_TEST_FOUND 0)
 204     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 205
 206     if (FAILED_TEST_FOUND)
 207       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 208       set(FAILED_TEST_FOUND_1 0)
 209       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 210
 211       if (FAILED_TEST_FOUND_1)
 212
 213         list(REMOVE_AT CMD_ARG_LIST 0)
 214
 215       else ()
 216
 217         set(FAILED_TEST_FOUND_2 0)
 218         list(GET CMD_ARG_LIST 1 EXE_NAME)
 219         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 220
 221         if (FAILED_TEST_FOUND_2)
 222
 223           list(REMOVE_AT CMD_ARG_LIST 0)
 224           list(REMOVE_AT CMD_ARG_LIST 0)
 225
 226         else ()
 227
 228           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 229
 230         endif ()
 231       endif ()
 232
 233     else ()
 234       # Check if the first argument is equal to opj_compress
 235       string(REGEX MATCH "^opj_compress$|^opj_compress_no_raw$|^opj_compress_no_raw_lossless$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 236
 237       if(EXE_NAME_FOUND)
 238
 239         string(REGEX MATCH "^opj_compress$|^opj_compress_no_raw$|^opj_compress_no_raw_lossless$" ENC_TEST_FOUND ${EXE_NAME})
 240         string(REGEX MATCH "^opj_compress_no_raw$|^opj_compress_no_raw_lossless$" NO_RAW ${EXE_NAME})
 241         string(REGEX MATCH "opj_compress_no_raw_lossless" LOSSLESS ${EXE_NAME})
 242
 243       else()
 244
 245         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 246
 247       endif()
 248
 249       list(REMOVE_AT CMD_ARG_LIST 0)
 250
 251       if(ENC_TEST_FOUND)
 252
 253         # Parse lines like opj_compress lossy-check { -n 3 -m 0:0:0 -p 0:0:0 } ...
 254         set(LOSSY_CHECK_ARG_LIST "")
 255         list(GET CMD_ARG_LIST 0 NEXT_ARG)
 256         string(REGEX MATCH "^lossy-check$" LOSSY_CHECK ${NEXT_ARG})
 257         if(LOSSY_CHECK)
 258             list(REMOVE_AT CMD_ARG_LIST 0)
 259             list(GET CMD_ARG_LIST 0 NEXT_ARG)
 260             string(REGEX MATCH "^{$" FOUND_OPEN_CURL ${NEXT_ARG})
 261             if(NOT FOUND_OPEN_CURL)
 262                 message( FATAL_ERROR "'{' expected after lossy-check")
 263             endif()
 264             list(REMOVE_AT CMD_ARG_LIST 0)
 265             while(TRUE)
 266                 list(GET CMD_ARG_LIST 0 NEXT_ARG)
 267                 list(REMOVE_AT CMD_ARG_LIST 0)
 268                 string(REGEX MATCH "^}$" FOUND_CLOSE_CURL ${NEXT_ARG})
 269                 if(FOUND_CLOSE_CURL)
 270                     break()
 271                 endif()
 272                 list (APPEND LOSSY_CHECK_ARG_LIST ${NEXT_ARG})
 273             endwhile()
 274         endif()
 275       endif()
 276
 277     endif ()
 278
 279     # Parse the argument list to find the input filename and output filename
 280     set(CMD_ARG_LIST_2 "")
 281     set(ARG_POS 0)
 282     set(INPUT_ARG_POS 0)
 283     set(OUTPUT_ARG_POS 0)
 284
 285     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 286
 287       math(EXPR ARG_POS "${ARG_POS}+1" )
 288
 289       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 290       if(INPUT_ARG_FOUND)
 291         set(INPUT_ARG_POS ${ARG_POS})
 292         set(INPUT_ARG_FOUND 0)
 293       endif()
 294
 295       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 296       if(OUTPUT_ARG_FOUND)
 297         set(OUTPUT_ARG_POS ${ARG_POS})
 298         set(OUTPUT_ARG_FOUND 0)
 299       endif()
 300
 301       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 302
 303     endforeach()
 304
 305     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 306     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 307     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 308     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 309     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 310
 311     #-----
 312     # Now we can add the test suite corresponding to a line command in the file
 313     #-----
 314     # ENCODER TEST SUITE
 315     if(ENC_TEST_FOUND)
 316         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 317
 318         # Encode an image into the jpeg2000 format
 319         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 320           COMMAND opj_compress
 321           ${CMD_ARG_LIST_2}
 322         )
 323
 324         if(FAILED_TEST_FOUND)
 325             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 326         else()
 327
 328           # Dump the encoding file
 329           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 330             COMMAND opj_dump
 331             -i ${OUTPUT_FILENAME}
 332             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 333           )
 334           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 335                                PROPERTIES DEPENDS
 336                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 337
 338           # Compare the dump file with the baseline
 339           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 340             COMMAND compare_dump_files
 341             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 342             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 343           )
 344
 345           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 346                                PROPERTIES DEPENDS
 347                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 348
 349           if(LOSSY_CHECK)
 350             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 351             COMMAND opj_decompress
 352             -i ${OUTPUT_FILENAME}
 353             -o ${OUTPUT_FILENAME}.tif
 354             )
 355
 356             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 357                                 PROPERTIES DEPENDS
 358                                 NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 359
 360             # Compare the decoding file with original one, using tolerance
 361             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 362             COMMAND compare_images
 363             -b ${INPUT_FILENAME}
 364             -t ${OUTPUT_FILENAME}.tif
 365             -s bXtY
 366             ${LOSSY_CHECK_ARG_LIST}
 367             )
 368
 369             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 370                                 PROPERTIES DEPENDS
 371                                 NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 372
 373           # Decode the encoding file with kakadu expand command
 374           elseif (KDU_EXPAND_EXECUTABLE)
 375             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 376               COMMAND ${KDU_EXPAND_EXECUTABLE}
 377               -i ${OUTPUT_FILENAME}
 378               -o ${OUTPUT_FILENAME}.raw
 379               )
 380
 381             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 382                                  PROPERTIES DEPENDS
 383                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 384
 385             if(NOT NO_RAW)
 386                 # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 387                 add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 388                 COMMAND compare_raw_files
 389                 -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 390                 -t ${OUTPUT_FILENAME}.raw
 391                 )
 392
 393                 set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 394                                     PROPERTIES DEPENDS
 395                                     NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 396             endif()
 397           endif()
 398
 399           # Test the encoded file is a valid JP2 file
 400           if (JPYLYZER_EXECUTABLE)
 401             if (${OUTPUT_FILENAME} MATCHES "\\.jp2$")
 402               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser
 403                 COMMAND ${JPYLYZER_EXECUTABLE}
 404                 ${OUTPUT_FILENAME}
 405                 )
 406               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser PROPERTIES
 407                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 408                 PASS_REGULAR_EXPRESSION "<isValidJP2>True</isValidJP2>"
 409                 )
 410             endif()
 411           endif(JPYLYZER_EXECUTABLE)
 412
 413           # If lossless compression (simple test is 4 arguments), decompress & compare
 414           list(LENGTH CMD_ARG_LIST_2 ARG_COUNT)
 415           if ((ARG_COUNT EQUAL 4) OR LOSSLESS)
 416             # can we compare with the input image ?
 417             if (${INPUT_FILENAME_NAME} MATCHES "\\.tif$")
 418               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 419                 COMMAND opj_decompress -i ${OUTPUT_FILENAME} -o ${OUTPUT_FILENAME}.lossless.tif
 420                 )
 421               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode PROPERTIES
 422                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 423                 )
 424               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare
 425                 COMMAND compare_images -b ${INPUT_FILENAME} -t ${OUTPUT_FILENAME}.lossless.tif -n 1 -d
 426                 )
 427               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare PROPERTIES
 428                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 429                 )
 430             endif()
 431           endif()
 432       endif()
 433
 434     # DECODER TEST SUITE
 435     else()
 436       string(FIND ${INPUT_FILENAME} "nonregression" nr_pos)
 437       if(${nr_pos} GREATER 0)
 438         list(APPEND nonregression_filenames_used ${INPUT_FILENAME_NAME})
 439       endif()
 440       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 441
 442       # Decode the input image
 443       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 444         COMMAND opj_decompress
 445         ${CMD_ARG_LIST_2}
 446       )
 447
 448       if(FAILED_TEST_FOUND)
 449
 450         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 451
 452       else()
 453         # if not failed, check against registered md5:
 454         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 455           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 456           -DOUTFILENAME:STRING=${OUTPUT_FILENAME}
 457           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 458
 459         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5
 460           PROPERTIES DEPENDS NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 461         )
 462
 463 # FIXME: add a compare2base function base on raw which
 464 # can output png diff files if necessary
 465 #  add_test(NR-${filename}-compare2base
 466 #      ${EXECUTABLE_OUTPUT_PATH}/compare_images
 467 #     -b ${BASELINE_NR}/opj_${filenameRef}
 468 #     -t ${TEMP}/${filename}.pgx
 469 #     -n ${nbComponents}
 470 #     -d
 471 #     -s b_t_
 472 #     )
 473 #
 474 #  set_tests_properties(NR-${filename}-compare2base
 475 #                       PROPERTIES DEPENDS
 476 #                       NR-${filename}-decode)
 477
 478       endif()
 479
 480     endif()
 481
 482   endif()
 483
 484 endforeach()
 485
 486 set(existing_filenames)
 487 foreach(f ${OPJ_DATA_NR_LIST})
 488   get_filename_component(ff ${f} NAME)
 489   list(APPEND existing_filenames ${ff})
 490 endforeach()
 491 if(existing_filenames)
 492 list(REMOVE_ITEM existing_filenames ${nonregression_filenames_used})
 493 endif()
 494
 495 # keep track of new addition:
 496 # if we reach here, then a J2K files was added but no test is present in
 497 # test_suite.ctest.in:
 498 foreach(found_but_no_test ${existing_filenames})
 499   add_test(NAME Found-But-No-Test-${found_but_no_test} COMMAND ${CMAKE_COMMAND} -E echo "${found_but_no_test}")
 500   set_tests_properties(Found-But-No-Test-${found_but_no_test} PROPERTIES WILL_FAIL TRUE)
 501 endforeach()