tools/ctest_scripts/travis-ci.cmake

   1 # -----------------------------------------------------------------------------
   2 # Travis-ci ctest script for OpenJPEG project
   3 # This will compile/run tests/upload to cdash OpenJPEG
   4 # Results will be available at: http://my.cdash.org/index.php?project=OPENJPEG
   5 # -----------------------------------------------------------------------------
   6
   7 cmake_minimum_required(VERSION 2.8)
   8
   9 set( ENV{LANG} en_US.UTF-8)
  10 set( CTEST_DASHBOARD_ROOT  "$ENV{PWD}/build" )
  11 set( CTEST_CMAKE_GENERATOR "Unix Makefiles")   # Always makefile in travis-ci environment
  12
  13 if ("$ENV{OPJ_BUILD_CONFIGURATION}" STREQUAL "")
  14   set( CTEST_BUILD_CONFIGURATION "Release")
  15 else()
  16         set( CTEST_BUILD_CONFIGURATION "$ENV{OPJ_BUILD_CONFIGURATION}")
  17 endif()
  18
  19 if ("$ENV{OPJ_SITE}" STREQUAL "")
  20   set( CTEST_SITE "Unknown")
  21 else()
  22         set( CTEST_SITE "$ENV{OPJ_SITE}")
  23 endif()
  24
  25 if ("$ENV{OPJ_BUILDNAME}" STREQUAL "")
  26   set( CTEST_BUILD_NAME "Unknown-${CTEST_BUILD_CONFIGURATION}")
  27 else()
  28         set( CTEST_BUILD_NAME "$ENV{OPJ_BUILDNAME}")
  29 endif()
  30
  31 if (NOT "$ENV{OPJ_CI_ARCH}" STREQUAL "")
  32         if (APPLE)
  33           set(CCFLAGS_ARCH "-arch $ENV{OPJ_CI_ARCH}")
  34         else()
  35                 if ("$ENV{OPJ_CI_ARCH}" MATCHES "^i[3-6]86$")
  36                         set(CCFLAGS_ARCH "-m32 -march=$ENV{OPJ_CI_ARCH}")
  37                 elseif ("$ENV{OPJ_CI_ARCH}" STREQUAL "x86_64")
  38                         set(CCFLAGS_ARCH "-m64")
  39                 endif()
  40         endif()
  41 endif()
  42
  43 if ("$ENV{OPJ_CI_ASAN}" STREQUAL "1")
  44         set(OPJ_HAS_MEMCHECK TRUE)
  45         set(CTEST_MEMORYCHECK_TYPE "AddressSanitizer")
  46         set(CCFLAGS_ARCH "${CCFLAGS_ARCH} -g -fsanitize=address -fno-omit-frame-pointer")
  47 endif()
  48
  49 if("$ENV{CC}" MATCHES ".*mingw.*")
  50         # We are trying to use mingw
  51         set(CTEST_CONFIGURE_OPTIONS "-DCMAKE_TOOLCHAIN_FILE=${CTEST_SCRIPT_DIRECTORY}/toolchain-mingw64.cmake")
  52 endif()
  53
  54 if(NOT "$ENV{OPJ_CI_SKIP_TESTS}" STREQUAL "1")
  55         # To execute part of the encoding test suite, kakadu binaries are needed to decode encoded image and compare
  56         # it to the baseline. Kakadu binaries are freely available for non-commercial purposes
  57         # at http://www.kakadusoftware.com.
  58         # Here's the copyright notice from kakadu:
  59         # Copyright is owned by NewSouth Innovations Pty Limited, commercial arm of the UNSW Australia in Sydney.
  60         # You are free to trial these executables and even to re-distribute them,
  61         # so long as such use or re-distribution is accompanied with this copyright notice and is not for commercial gain.
  62         # Note: Binaries can only be used for non-commercial purposes.
  63         if ("$ENV{OPJ_NONCOMMERCIAL}" STREQUAL "1" )
  64                 set(KDUPATH $ENV{PWD}/kdu)
  65                 set(ENV{LD_LIBRARY_PATH} ${KDUPATH})
  66                 set(ENV{PATH} $ENV{PATH}:${KDUPATH})
  67         endif()
  68         set(BUILD_TESTING "TRUE")
  69 else()
  70         set(BUILD_TESTING "FALSE")
  71 endif(NOT "$ENV{OPJ_CI_SKIP_TESTS}" STREQUAL "1")
  72
  73 # Options
  74 set( CACHE_CONTENTS "
  75
  76 # Build kind
  77 CMAKE_BUILD_TYPE:STRING=${CTEST_BUILD_CONFIGURATION}
  78
  79 # Warning level
  80 CMAKE_C_FLAGS:STRING= ${CCFLAGS_ARCH} -Wall -Wextra -Wconversion -Wno-unused-parameter -Wdeclaration-after-statement
  81
  82 # Use to activate the test suite
  83 BUILD_TESTING:BOOL=${BUILD_TESTING}
  84
  85 # Build Thirdparty, useful but not required for test suite
  86 BUILD_THIRDPARTY:BOOL=TRUE
  87
  88 # JPEG2000 test files are available with git clone https://github.com/uclouvain/openjpeg-data.git
  89 OPJ_DATA_ROOT:PATH=$ENV{PWD}/data
  90
  91 # jpylyzer is available with on GitHub: https://github.com/openpreserve/jpylyzer
  92 JPYLYZER_EXECUTABLE=$ENV{PWD}/jpylyzer/jpylyzer/jpylyzer.py
  93
  94 " )
  95
  96 #---------------------
  97 #1. openjpeg specific:
  98 set( CTEST_PROJECT_NAME "OPENJPEG" )
  99 if(NOT EXISTS $ENV{OPJ_SOURCE_DIR})
 100         message(FATAL_ERROR "OPJ_SOURCE_DIR not defined or does not exist:$ENV{OPJ_SOURCE_DIR}")
 101 endif()
 102 set( CTEST_SOURCE_DIRECTORY     "$ENV{OPJ_SOURCE_DIR}")
 103 set( CTEST_BINARY_DIRECTORY     "${CTEST_DASHBOARD_ROOT}")
 104
 105 #---------------------
 106 # Files to submit to the dashboard
 107 set (CTEST_NOTES_FILES
 108 ${CTEST_SCRIPT_DIRECTORY}/${CTEST_SCRIPT_NAME}
 109 ${CTEST_BINARY_DIRECTORY}/CMakeCache.txt )
 110
 111 ctest_empty_binary_directory( "${CTEST_BINARY_DIRECTORY}" )
 112 file(WRITE "${CTEST_BINARY_DIRECTORY}/CMakeCache.txt" "${CACHE_CONTENTS}")
 113
 114 # Perform a Experimental build
 115 ctest_start(Experimental)
 116 #ctest_update(SOURCE "${CTEST_SOURCE_DIRECTORY}")
 117 ctest_configure(BUILD "${CTEST_BINARY_DIRECTORY}" OPTIONS "${CTEST_CONFIGURE_OPTIONS}")
 118 ctest_read_custom_files(${CTEST_BINARY_DIRECTORY})
 119 ctest_build(BUILD "${CTEST_BINARY_DIRECTORY}")
 120 if(NOT "$ENV{OPJ_CI_SKIP_TESTS}" STREQUAL "1")
 121         ctest_test(BUILD "${CTEST_BINARY_DIRECTORY}" PARALLEL_LEVEL 2)
 122         if(OPJ_HAS_MEMCHECK)
 123                 ctest_memcheck(BUILD "${CTEST_BINARY_DIRECTORY}" PARALLEL_LEVEL 2)
 124         endif()
 125 endif()
 126 if ("$ENV{OPJ_DO_SUBMIT}" STREQUAL "1")
 127         ctest_submit()
 128 endif()
 129 #ctest_empty_binary_directory( "${CTEST_BINARY_DIRECTORY}" )