CMakeLists.txt

   1 # Main CMakeLists.txt to build the OpenJPEG project using CMake (www.cmake.org)
   2 # Written by Mathieu Malaterre
   3
   4 # This CMake project will by default create a library called openjpeg
   5 # But if you want to use this project within your own (CMake) project
   6 # you will eventually like to prefix the library to avoid linking confusion
   7 # For this purpose you can define a CMake var: OPENJPEG_NAMESPACE to whatever you like
   8 # e.g.:
   9 # SET(OPENJPEG_NAMESPACE "GDCMOPENJPEG")
  10 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  11
  12 IF(COMMAND CMAKE_POLICY)
  13   CMAKE_POLICY(SET CMP0003 NEW)
  14 ENDIF(COMMAND CMAKE_POLICY)
  15
  16 IF(NOT OPENJPEG_NAMESPACE)
  17   SET(OPENJPEG_NAMESPACE "OPENJPEG")
  18   SET(OPENJPEG_STANDALONE 1)
  19 ENDIF(NOT OPENJPEG_NAMESPACE)
  20 # In all cases:
  21 STRING(TOLOWER ${OPENJPEG_NAMESPACE} OPENJPEG_LIBRARY_NAME)
  22
  23 PROJECT(${OPENJPEG_NAMESPACE} C)
  24
  25 # Do full dependency headers.
  26 INCLUDE_REGULAR_EXPRESSION("^.*$")
  27
  28 #-----------------------------------------------------------------------------
  29 # OPENJPEG version number, useful for packaging and doxygen doc:
  30 SET(OPENJPEG_VERSION_MAJOR 1)
  31 SET(OPENJPEG_VERSION_MINOR 5)
  32 SET(OPENJPEG_VERSION_BUILD 0)
  33 SET(OPENJPEG_VERSION
  34   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  35 SET(PACKAGE_VERSION
  36   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  37 SET(OPENJPEG_LIBRARY_PROPERTIES
  38   VERSION   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}"
  39   SOVERSION "${OPENJPEG_VERSION_MAJOR}"
  40 )
  41
  42 # --------------------------------------------------------------------------
  43 # Path to additional CMake modules
  44 SET(CMAKE_MODULE_PATH
  45     ${CMAKE_SOURCE_DIR}/CMake
  46     ${CMAKE_MODULE_PATH})
  47
  48 # --------------------------------------------------------------------------
  49 # On Visual Studio 8 MS deprecated C. This removes all 1.276E1265 security
  50 # warnings
  51 IF(WIN32)
  52   IF(NOT BORLAND)
  53     IF(NOT CYGWIN)
  54       IF(NOT MINGW)
  55         IF(NOT ITK_ENABLE_VISUAL_STUDIO_DEPRECATED_C_WARNINGS)
  56           ADD_DEFINITIONS(
  57             -D_CRT_FAR_MAPPINGS_NO_DEPRECATE
  58             -D_CRT_IS_WCTYPE_NO_DEPRECATE
  59             -D_CRT_MANAGED_FP_NO_DEPRECATE
  60             -D_CRT_NONSTDC_NO_DEPRECATE
  61             -D_CRT_SECURE_NO_DEPRECATE
  62             -D_CRT_SECURE_NO_DEPRECATE_GLOBALS
  63             -D_CRT_SETERRORMODE_BEEP_SLEEP_NO_DEPRECATE
  64             -D_CRT_TIME_FUNCTIONS_NO_DEPRECATE
  65             -D_CRT_VCCLRIT_NO_DEPRECATE
  66             -D_SCL_SECURE_NO_DEPRECATE
  67             )
  68         ENDIF(NOT ITK_ENABLE_VISUAL_STUDIO_DEPRECATED_C_WARNINGS)
  69       ENDIF(NOT MINGW)
  70     ENDIF(NOT CYGWIN)
  71   ENDIF(NOT BORLAND)
  72 ENDIF(WIN32)
  73
  74
  75 # --------------------------------------------------------------------------
  76 # Install directories
  77
  78 STRING(TOLOWER ${PROJECT_NAME} projectname)
  79 SET(OPENJPEG_INSTALL_SUBDIR "${projectname}-${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}")
  80
  81 IF(NOT OPENJPEG_INSTALL_BIN_DIR)
  82   SET(OPENJPEG_INSTALL_BIN_DIR "bin")
  83 ENDIF(NOT OPENJPEG_INSTALL_BIN_DIR)
  84
  85 IF(NOT OPENJPEG_INSTALL_LIB_DIR)
  86   SET(OPENJPEG_INSTALL_LIB_DIR "lib")
  87 ENDIF(NOT OPENJPEG_INSTALL_LIB_DIR)
  88
  89 IF(NOT OPENJPEG_INSTALL_SHARE_DIR)
  90   SET(OPENJPEG_INSTALL_SHARE_DIR "share")
  91 ENDIF(NOT OPENJPEG_INSTALL_SHARE_DIR)
  92
  93 IF(NOT OPENJPEG_INSTALL_DATA_DIR)
  94   SET(OPENJPEG_INSTALL_DATA_DIR "${OPENJPEG_INSTALL_SHARE_DIR}/${OPENJPEG_INSTALL_SUBDIR}")
  95 ENDIF(NOT OPENJPEG_INSTALL_DATA_DIR)
  96
  97 IF(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
  98   SET(OPENJPEG_INSTALL_INCLUDE_DIR "include/")
  99 ENDIF(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
 100
 101 IF(NOT OPENJPEG_INSTALL_MAN_DIR)
 102   SET(OPENJPEG_INSTALL_MAN_DIR "share/man/")
 103 ENDIF(NOT OPENJPEG_INSTALL_MAN_DIR)
 104
 105 IF(NOT OPENJPEG_INSTALL_DOC_DIR)
 106   SET(OPENJPEG_INSTALL_DOC_DIR "share/doc/${OPENJPEG_INSTALL_SUBDIR}")
 107 ENDIF(NOT OPENJPEG_INSTALL_DOC_DIR)
 108
 109 IF(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
 110   SET(OPENJPEG_INSTALL_PACKAGE_DIR "${OPENJPEG_INSTALL_SHARE_DIR}/${OPENJPEG_INSTALL_SUBDIR}")
 111 ENDIF(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
 112
 113 #-----------------------------------------------------------------------------
 114 # Big endian test:
 115 INCLUDE (${CMAKE_ROOT}/Modules/TestBigEndian.cmake)
 116 TEST_BIG_ENDIAN(OPJ_BIG_ENDIAN)
 117
 118 #-----------------------------------------------------------------------------
 119 # Setup file for setting custom ctest vars
 120 CONFIGURE_FILE(
 121   ${CMAKE_SOURCE_DIR}/CMake/CTestCustom.cmake.in
 122   ${CMAKE_BINARY_DIR}/CTestCustom.cmake
 123   @ONLY
 124   )
 125
 126 #-----------------------------------------------------------------------------
 127 # OpenJPEG build configuration options.
 128 OPTION(BUILD_SHARED_LIBS "Build OpenJPEG shared library and link executables against it." ON)
 129 SET (EXECUTABLE_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all executables.")
 130 SET (LIBRARY_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all libraries.")
 131 MARK_AS_ADVANCED(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
 132
 133 #-----------------------------------------------------------------------------
 134 # configure name mangling to allow multiple libraries to coexist
 135 # peacefully
 136 IF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 137 SET(MANGLE_PREFIX ${OPENJPEG_LIBRARY_NAME})
 138 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in
 139                ${CMAKE_CURRENT_BINARY_DIR}/openjpeg_mangle.h
 140                @ONLY)
 141 ENDIF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 142
 143 #-----------------------------------------------------------------------------
 144 # pkgconfig support
 145 IF(UNIX)
 146   CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libopenjpeg1.pc.cmake
 147     ${CMAKE_CURRENT_BINARY_DIR}/libopenjpeg1.pc @ONLY)
 148   INSTALL( FILES  ${CMAKE_CURRENT_BINARY_DIR}/libopenjpeg1.pc DESTINATION
 149     ${OPENJPEG_INSTALL_SHARE_DIR}/pkgconfig )
 150   INSTALL( CODE "EXECUTE_PROCESS(COMMAND ${CMAKE_COMMAND} -E create_symlink
 151   \"libopenjpeg1.pc\"
 152   \"\$ENV{DESTDIR}${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig/libopenjpeg.pc\")")
 153 ENDIF(UNIX)
 154
 155 #-----------------------------------------------------------------------------
 156 # Compiler specific flags:
 157 IF(CMAKE_COMPILER_IS_GNUCC)
 158   # For all builds, make sure openjpeg is std99 compliant:
 159   # SET(CMAKE_C_FLAGS "-Wall -std=c99 ${CMAKE_C_FLAGS}") # FIXME: this setting prevented us from setting a coverage build.
 160   # Do not use ffast-math for all build, it would produce incorrect results, only set for release:
 161   SET(CMAKE_C_FLAGS_RELEASE "-ffast-math ${CMAKE_C_FLAGS_RELEASE}")
 162 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 163
 164 #-----------------------------------------------------------------------------
 165 # opj_config.h generation (1/2)
 166 INCLUDE (${CMAKE_ROOT}/Modules/CheckIncludeFile.cmake)
 167 CHECK_INCLUDE_FILE("strings.h"      HAVE_STRINGS_H)
 168 CHECK_INCLUDE_FILE("inttypes.h"     HAVE_INTTYPES_H)
 169 CHECK_INCLUDE_FILE("memory.h"       HAVE_MEMORY_H)
 170 CHECK_INCLUDE_FILE("stdint.h"       HAVE_STDINT_H)
 171 CHECK_INCLUDE_FILE("stdlib.h"       HAVE_STDLIB_H)
 172 CHECK_INCLUDE_FILE("string.h"       HAVE_STRING_H)
 173 CHECK_INCLUDE_FILE("sys/stat.h"     HAVE_SYS_STAT_H)
 174 CHECK_INCLUDE_FILE("sys/types.h"    HAVE_SYS_TYPES_H)
 175 CHECK_INCLUDE_FILE("unistd.h"       HAVE_UNISTD_H)
 176
 177
 178 #-----------------------------------------------------------------------------
 179 # Build Library
 180 INCLUDE_DIRECTORIES(BEFORE ${OPENJPEG_BINARY_DIR})
 181 ADD_SUBDIRECTORY(libopenjpeg)
 182
 183 #-----------------------------------------------------------------------------
 184 # Build Applications
 185 OPTION(BUILD_CODEC "Build the CODEC executables" ON)
 186 OPTION(BUILD_MJ2 "Build the MJ2 executables." OFF)
 187 OPTION(BUILD_JPWL "Build the JPWL library and executables" OFF)
 188 OPTION(BUILD_JPIP "Build the JPIP library and executables." OFF)
 189 IF(BUILD_JPIP)
 190   OPTION(BUILD_JPIP_SERVER "Build the JPIP server." OFF)
 191 ENDIF(BUILD_JPIP)
 192 OPTION(BUILD_VIEWER "Build the OPJViewer executable (C++)" OFF)
 193 OPTION(BUILD_JAVA "Build the openjpeg jar (Java)" OFF)
 194 MARK_AS_ADVANCED(BUILD_VIEWER)
 195 MARK_AS_ADVANCED(BUILD_JAVA)
 196
 197 IF(BUILD_CODEC OR BUILD_MJ2)
 198   # OFF: It will only build 3rd party libs if they are not found on the system
 199   # ON: 3rd party libs will ALWAYS be build, and used
 200   OPTION(BUILD_THIRDPARTY "Build the thirdparty executables if it is needed" OFF)
 201   ADD_SUBDIRECTORY(thirdparty)
 202   ADD_SUBDIRECTORY(applications)
 203 ENDIF (BUILD_CODEC OR BUILD_MJ2)
 204
 205 #-----------------------------------------------------------------------------
 206 # opj_config.h generation (2/2)
 207 CONFIGURE_FILE("${OPENJPEG_SOURCE_DIR}/opj_config.h.cmake.in"
 208  "${OPENJPEG_BINARY_DIR}/opj_config.h"
 209  @ONLY
 210  )
 211
 212 #-----------------------------------------------------------------------------
 213 # Build DOCUMENTATION (not in ALL target and only if Doxygen is found)
 214 OPTION(BUILD_DOC "Build the HTML documentation (with doxygen if available)." ON)
 215 IF(BUILD_DOC)
 216     ADD_SUBDIRECTORY(doc)
 217 ENDIF(BUILD_DOC)
 218
 219 #-----------------------------------------------------------------------------
 220 # Buld Testing
 221 OPTION(BUILD_TESTING "Build the tests." OFF)
 222 IF(BUILD_TESTING)
 223   IF(BUILD_CODEC)
 224     ENABLE_TESTING()
 225     INCLUDE(CTest)
 226
 227     # Search openjpeg data needed for the tests
 228     # They could be found via svn on the OpenJPEG google code project
 229     # svn checkout http://openjpeg.googlecode.com/svn/data (about 70 Mo)
 230     FIND_PATH(OPJ_DATA_ROOT README-OPJ-Data
 231       PATHS
 232       $ENV{OPJ_DATA_ROOT}
 233       ${CMAKE_SOURCE_DIR}/../data
 234       )
 235
 236     # Add repository where to find tests
 237     ADD_SUBDIRECTORY(tests)
 238
 239   ELSE(BUILD_CODEC)
 240     message(FATAL_ERROR "You need build codec to run the tests")
 241   ENDIF(BUILD_CODEC)
 242 ENDIF(BUILD_TESTING)
 243
 244 #-----------------------------------------------------------------------------
 245 # install all targets referenced as OPENJPEGTargets
 246 INSTALL(EXPORT OpenJPEGTargets DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR})
 247 CONFIGURE_FILE( ${OPENJPEG_SOURCE_DIR}/CMake/OpenJPEGConfig.cmake.in
 248   ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 249   @ONLY
 250 )
 251 INSTALL( FILES ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 252   DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR}
 253 )
 254
 255 #-----------------------------------------------------------------------------
 256 # install CHANGES and LICENSE
 257 INSTALL(
 258   FILES       CHANGES
 259               LICENSE
 260   DESTINATION ${OPENJPEG_INSTALL_DOC_DIR})
 261
 262 INCLUDE (CMake/OpenJPEGCPack.cmake)