CMakeLists.txt

   1 # Main CMakeLists.txt to build the OpenJPEG project using CMake (www.cmake.org)
   2 # Written by Mathieu Malaterre
   3
   4 # This CMake project will by default create a library called openjpeg
   5 # But if you want to use this project within your own (CMake) project
   6 # you will eventually like to prefix the library to avoid linking confusion
   7 # For this purpose you can define a CMake var: OPENJPEG_NAMESPACE to whatever you like
   8 # e.g.:
   9 # SET(OPENJPEG_NAMESPACE "GDCMOPENJPEG")
  10 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  11
  12 IF(COMMAND CMAKE_POLICY)
  13   CMAKE_POLICY(SET CMP0003 NEW)
  14 ENDIF(COMMAND CMAKE_POLICY)
  15
  16 IF(NOT OPENJPEG_NAMESPACE)
  17   SET(OPENJPEG_NAMESPACE "OPENJPEG")
  18   SET(OPENJPEG_STANDALONE 1)
  19 ENDIF(NOT OPENJPEG_NAMESPACE)
  20 # In all cases:
  21 STRING(TOLOWER ${OPENJPEG_NAMESPACE} OPENJPEG_LIBRARY_NAME)
  22
  23 PROJECT(${OPENJPEG_NAMESPACE} C)
  24
  25 # Do full dependency headers.
  26 INCLUDE_REGULAR_EXPRESSION("^.*$")
  27
  28 #-----------------------------------------------------------------------------
  29 # OPENJPEG version number, useful for packaging and doxygen doc:
  30 SET(OPENJPEG_VERSION_MAJOR 1)
  31 SET(OPENJPEG_VERSION_MINOR 5)
  32 SET(OPENJPEG_VERSION_BUILD 0)
  33 SET(OPENJPEG_VERSION
  34   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  35 SET(PACKAGE_VERSION
  36   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}")
  37 SET(OPENJPEG_LIBRARY_PROPERTIES
  38   VERSION   "${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}.${OPENJPEG_VERSION_BUILD}"
  39   SOVERSION "${OPENJPEG_VERSION_MAJOR}"
  40 )
  41
  42 # --------------------------------------------------------------------------
  43 # Path to additional CMake modules
  44 SET(CMAKE_MODULE_PATH
  45     ${CMAKE_SOURCE_DIR}/CMake
  46     ${CMAKE_MODULE_PATH})
  47
  48 # --------------------------------------------------------------------------
  49 # On Visual Studio 8 MS deprecated C. This removes all 1.276E1265 security
  50 # warnings
  51 IF(WIN32)
  52   IF(NOT BORLAND)
  53     IF(NOT CYGWIN)
  54       IF(NOT MINGW)
  55         IF(NOT ITK_ENABLE_VISUAL_STUDIO_DEPRECATED_C_WARNINGS)
  56           ADD_DEFINITIONS(
  57             -D_CRT_FAR_MAPPINGS_NO_DEPRECATE
  58             -D_CRT_IS_WCTYPE_NO_DEPRECATE
  59             -D_CRT_MANAGED_FP_NO_DEPRECATE
  60             -D_CRT_NONSTDC_NO_DEPRECATE
  61             -D_CRT_SECURE_NO_DEPRECATE
  62             -D_CRT_SECURE_NO_DEPRECATE_GLOBALS
  63             -D_CRT_SETERRORMODE_BEEP_SLEEP_NO_DEPRECATE
  64             -D_CRT_TIME_FUNCTIONS_NO_DEPRECATE
  65             -D_CRT_VCCLRIT_NO_DEPRECATE
  66             -D_SCL_SECURE_NO_DEPRECATE
  67             )
  68         ENDIF(NOT ITK_ENABLE_VISUAL_STUDIO_DEPRECATED_C_WARNINGS)
  69       ENDIF(NOT MINGW)
  70     ENDIF(NOT CYGWIN)
  71   ENDIF(NOT BORLAND)
  72 ENDIF(WIN32)
  73
  74
  75 # --------------------------------------------------------------------------
  76 # Install directories
  77
  78 STRING(TOLOWER ${PROJECT_NAME} projectname)
  79 SET(OPENJPEG_INSTALL_SUBDIR "${projectname}-${OPENJPEG_VERSION_MAJOR}.${OPENJPEG_VERSION_MINOR}")
  80
  81 IF(NOT OPENJPEG_INSTALL_BIN_DIR)
  82   SET(OPENJPEG_INSTALL_BIN_DIR "bin")
  83 ENDIF(NOT OPENJPEG_INSTALL_BIN_DIR)
  84
  85 IF(NOT OPENJPEG_INSTALL_LIB_DIR)
  86   SET(OPENJPEG_INSTALL_LIB_DIR "lib")
  87 ENDIF(NOT OPENJPEG_INSTALL_LIB_DIR)
  88
  89 IF(NOT OPENJPEG_INSTALL_DATA_DIR)
  90   SET(OPENJPEG_INSTALL_DATA_DIR "share/${OPENJPEG_INSTALL_SUBDIR}")
  91 ENDIF(NOT OPENJPEG_INSTALL_DATA_DIR)
  92
  93 IF(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
  94   SET(OPENJPEG_INSTALL_INCLUDE_DIR "include/")
  95 ENDIF(NOT OPENJPEG_INSTALL_INCLUDE_DIR)
  96
  97 IF(NOT OPENJPEG_INSTALL_MAN_DIR)
  98   SET(OPENJPEG_INSTALL_MAN_DIR "share/man/")
  99 ENDIF(NOT OPENJPEG_INSTALL_MAN_DIR)
 100
 101 IF(NOT OPENJPEG_INSTALL_DOC_DIR)
 102   SET(OPENJPEG_INSTALL_DOC_DIR "share/doc/${OPENJPEG_INSTALL_SUBDIR}")
 103 ENDIF(NOT OPENJPEG_INSTALL_DOC_DIR)
 104
 105 IF(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
 106   SET(OPENJPEG_INSTALL_PACKAGE_DIR ${OPENJPEG_INSTALL_LIB_DIR}/${OPENJPEG_INSTALL_SUBDIR}
 107     CACHE INTERNAL "")
 108 ENDIF(NOT OPENJPEG_INSTALL_PACKAGE_DIR)
 109
 110 #-----------------------------------------------------------------------------
 111 # Big endian test:
 112 INCLUDE (${CMAKE_ROOT}/Modules/TestBigEndian.cmake)
 113 TEST_BIG_ENDIAN(OPJ_BIG_ENDIAN)
 114
 115 #-----------------------------------------------------------------------------
 116 # Setup file for setting custom ctest vars
 117 CONFIGURE_FILE(
 118   ${CMAKE_SOURCE_DIR}/CMake/CTestCustom.cmake.in
 119   ${CMAKE_BINARY_DIR}/CTestCustom.cmake
 120   @ONLY
 121   )
 122
 123 #-----------------------------------------------------------------------------
 124 # OpenJPEG build configuration options.
 125 OPTION(BUILD_SHARED_LIBS "Build OpenJPEG shared library and link executables against it." ON)
 126 SET (EXECUTABLE_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all executables.")
 127 SET (LIBRARY_OUTPUT_PATH ${OPENJPEG_BINARY_DIR}/bin CACHE PATH "Single output directory for building all libraries.")
 128 MARK_AS_ADVANCED(LIBRARY_OUTPUT_PATH EXECUTABLE_OUTPUT_PATH)
 129
 130 #-----------------------------------------------------------------------------
 131 # configure name mangling to allow multiple libraries to coexist
 132 # peacefully
 133 IF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 134 SET(MANGLE_PREFIX ${OPENJPEG_LIBRARY_NAME})
 135 CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in
 136                ${CMAKE_CURRENT_BINARY_DIR}/openjpeg_mangle.h
 137                @ONLY)
 138 ENDIF(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg_mangle.h.in)
 139
 140 #-----------------------------------------------------------------------------
 141 # pkgconfig support
 142 IF(UNIX)
 143   CONFIGURE_FILE(${CMAKE_CURRENT_SOURCE_DIR}/libopenjpeg1.pc.cmake
 144     ${CMAKE_CURRENT_BINARY_DIR}/libopenjpeg1.pc @ONLY)
 145   INSTALL( FILES  ${CMAKE_CURRENT_BINARY_DIR}/libopenjpeg1.pc DESTINATION
 146     ${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig )
 147   INSTALL( CODE "EXECUTE_PROCESS(COMMAND ${CMAKE_COMMAND} -E create_symlink
 148   \"libopenjpeg1.pc\"
 149   \"\$ENV{DESTDIR}${OPENJPEG_INSTALL_LIB_DIR}/pkgconfig/libopenjpeg.pc\")")
 150 ENDIF(UNIX)
 151
 152 #-----------------------------------------------------------------------------
 153 # Compiler specific flags:
 154 IF(CMAKE_COMPILER_IS_GNUCC)
 155   # For all builds, make sure openjpeg is std99 compliant:
 156   # SET(CMAKE_C_FLAGS "-Wall -std=c99 ${CMAKE_C_FLAGS}") # FIXME: this setting prevented us from setting a coverage build.
 157   # Do not use ffast-math for all build, it would produce incorrect results, only set for release:
 158   SET(CMAKE_C_FLAGS_RELEASE "-ffast-math ${CMAKE_C_FLAGS_RELEASE}")
 159 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 160
 161 #-----------------------------------------------------------------------------
 162 # opj_config.h generation (1/2)
 163 INCLUDE (${CMAKE_ROOT}/Modules/CheckIncludeFile.cmake)
 164 CHECK_INCLUDE_FILE("strings.h"       HAVE_STRINGS_H)
 165 CHECK_INCLUDE_FILE("inttypes.h"       HAVE_INTTYPES_H)
 166 CHECK_INCLUDE_FILE("memory.h"       HAVE_MEMORY_H)
 167 CHECK_INCLUDE_FILE("stdint.h"       HAVE_STDINT_H)
 168 CHECK_INCLUDE_FILE("stdlib.h"       HAVE_STDLIB_H)
 169 CHECK_INCLUDE_FILE("string.h"       HAVE_STRING_H)
 170 CHECK_INCLUDE_FILE("sys/stat.h"       HAVE_SYS_STAT_H)
 171 CHECK_INCLUDE_FILE("sys/types.h"       HAVE_SYS_TYPES_H)
 172 CHECK_INCLUDE_FILE("unistd.h"       HAVE_UNISTD_H)
 173
 174
 175 #-----------------------------------------------------------------------------
 176 # Build Library
 177 INCLUDE_DIRECTORIES(BEFORE ${OPENJPEG_BINARY_DIR})
 178 ADD_SUBDIRECTORY(libopenjpeg)
 179
 180 #-----------------------------------------------------------------------------
 181 # Build Applications
 182 OPTION(BUILD_CODEC "Build the CODEC executables" ON)
 183 OPTION(BUILD_MJ2 "Build the MJ2 executables." OFF)
 184 OPTION(BUILD_JPIP "Build the JPIP library and executables." OFF)
 185 OPTION(BUILD_VIEWER "Build the OPJViewer executable (C++)" OFF)
 186 MARK_AS_ADVANCED(BUILD_VIEWER)
 187
 188 IF(BUILD_JPIP)
 189  FIND_PACKAGE(CURL)
 190 ENDIF (BUILD_JPIP)
 191
 192 IF(NOT CURL_FOUND)
 193  IF(BUILD_JPIP)
 194   message(WARNING "You must have libcurl installed to use JPIP")
 195  ENDIF (BUILD_JPIP)
 196  SET(BUILD_JPIP OFF)
 197 ENDIF (NOT CURL_FOUND)
 198
 199 # Try to find lib Z
 200 FIND_PACKAGE(ZLIB)
 201
 202 IF(BUILD_CODEC OR BUILD_MJ2 OR BUILD_JPIP)
 203   OPTION(BUILD_THIRDPARTY "Build the thirdparty executables if it is needed" OFF)
 204   ADD_SUBDIRECTORY(thirdparty)
 205   ADD_SUBDIRECTORY(applications)
 206 ENDIF (BUILD_CODEC OR BUILD_MJ2 OR BUILD_JPIP)
 207
 208 #-----------------------------------------------------------------------------
 209 # opj_config.h generation (2/2)
 210 CONFIGURE_FILE("${OPENJPEG_SOURCE_DIR}/opj_config.h.cmake.in"
 211  "${OPENJPEG_BINARY_DIR}/opj_config.h"
 212  @ONLY
 213  )
 214
 215 #-----------------------------------------------------------------------------
 216 # Build JPWL-flavoured library and executables
 217 OPTION(BUILD_JPWL "Build the JPWL library and executables" OFF)
 218
 219 #-----------------------------------------------------------------------------
 220 # Build DOCUMENTATION (not in ALL target and only if Doxygen is found)
 221 OPTION(BUILD_DOC "Build the HTML documentation (with doxygen if available)." OFF)
 222 IF(BUILD_DOC)
 223     ADD_SUBDIRECTORY(doc)
 224 ENDIF(BUILD_DOC)
 225
 226 #-----------------------------------------------------------------------------
 227 # Buld Testing
 228 OPTION(BUILD_TESTING "Build the tests." OFF)
 229 IF(BUILD_TESTING)
 230   IF(BUILD_CODEC)
 231     ENABLE_TESTING()
 232     INCLUDE(CTest)
 233
 234     # Search openjpeg data needed for the tests
 235     # They could be found via svn on the OpenJPEG google code project
 236     # svn checkout http://openjpeg.googlecode.com/svn/data (about 70 Mo)
 237     FIND_PATH(OPJ_DATA_ROOT README-OPJ-Data
 238       PATHS
 239       $ENV{OPJ_DATA_ROOT}
 240       ${CMAKE_SOURCE_DIR}/../data
 241       )
 242
 243     # Add repository where to find tests
 244     ADD_SUBDIRECTORY(tests)
 245
 246   ELSE(BUILD_CODEC)
 247     message(FATAL_ERROR "You need build codec to run the tests")
 248   ENDIF(BUILD_CODEC)
 249 ENDIF(BUILD_TESTING)
 250
 251 #-----------------------------------------------------------------------------
 252 # install all targets referenced as OPENJPEGTargets
 253 INSTALL(EXPORT OpenJPEGTargets DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR})
 254 CONFIGURE_FILE( ${OPENJPEG_SOURCE_DIR}/CMake/OpenJPEGConfig.cmake.in
 255   ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 256   @ONLY
 257 )
 258 INSTALL( FILES ${OPENJPEG_BINARY_DIR}/OpenJPEGConfig.cmake
 259   DESTINATION ${OPENJPEG_INSTALL_PACKAGE_DIR}
 260 )
 261
 262 #-----------------------------------------------------------------------------
 263 # install CHANGES and LICENSE
 264 INSTALL(
 265   FILES       CHANGES
 266               LICENSE
 267   DESTINATION ${OPENJPEG_INSTALL_DOC_DIR})
 268
 269 INCLUDE (CMake/OpenJPEGCPack.cmake)