src/lib/openjp2/CMakeLists.txt

   1 include_regular_expression("^.*$")
   2
   3 #
   4 install( FILES  ${CMAKE_CURRENT_BINARY_DIR}/opj_config.h
   5  DESTINATION ${OPENJPEG_INSTALL_INCLUDE_DIR} COMPONENT Headers)
   6
   7 include_directories(
   8   ${${OPENJPEG_NAMESPACE}_BINARY_DIR}/src/lib/openjp2 # opj_config.h and opj_config_private.h
   9 )
  10 # Defines the source code for the library
  11 set(OPENJPEG_SRCS
  12   ${CMAKE_CURRENT_SOURCE_DIR}/thread.c
  13   ${CMAKE_CURRENT_SOURCE_DIR}/thread.h
  14   ${CMAKE_CURRENT_SOURCE_DIR}/bio.c
  15   ${CMAKE_CURRENT_SOURCE_DIR}/bio.h
  16   ${CMAKE_CURRENT_SOURCE_DIR}/cio.c
  17   ${CMAKE_CURRENT_SOURCE_DIR}/cio.h
  18   ${CMAKE_CURRENT_SOURCE_DIR}/dwt.c
  19   ${CMAKE_CURRENT_SOURCE_DIR}/dwt.h
  20   ${CMAKE_CURRENT_SOURCE_DIR}/event.c
  21   ${CMAKE_CURRENT_SOURCE_DIR}/event.h
  22   ${CMAKE_CURRENT_SOURCE_DIR}/image.c
  23   ${CMAKE_CURRENT_SOURCE_DIR}/image.h
  24   ${CMAKE_CURRENT_SOURCE_DIR}/invert.c
  25   ${CMAKE_CURRENT_SOURCE_DIR}/invert.h
  26   ${CMAKE_CURRENT_SOURCE_DIR}/j2k.c
  27   ${CMAKE_CURRENT_SOURCE_DIR}/j2k.h
  28   ${CMAKE_CURRENT_SOURCE_DIR}/jp2.c
  29   ${CMAKE_CURRENT_SOURCE_DIR}/jp2.h
  30   ${CMAKE_CURRENT_SOURCE_DIR}/mct.c
  31   ${CMAKE_CURRENT_SOURCE_DIR}/mct.h
  32   ${CMAKE_CURRENT_SOURCE_DIR}/mqc.c
  33   ${CMAKE_CURRENT_SOURCE_DIR}/mqc.h
  34   ${CMAKE_CURRENT_SOURCE_DIR}/mqc_inl.h
  35   ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg.c
  36   ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg.h
  37   ${CMAKE_CURRENT_SOURCE_DIR}/opj_clock.c
  38   ${CMAKE_CURRENT_SOURCE_DIR}/opj_clock.h
  39   ${CMAKE_CURRENT_SOURCE_DIR}/pi.c
  40   ${CMAKE_CURRENT_SOURCE_DIR}/pi.h
  41   ${CMAKE_CURRENT_SOURCE_DIR}/t1.c
  42   ${CMAKE_CURRENT_SOURCE_DIR}/t1.h
  43   ${CMAKE_CURRENT_SOURCE_DIR}/t2.c
  44   ${CMAKE_CURRENT_SOURCE_DIR}/t2.h
  45   ${CMAKE_CURRENT_SOURCE_DIR}/tcd.c
  46   ${CMAKE_CURRENT_SOURCE_DIR}/tcd.h
  47   ${CMAKE_CURRENT_SOURCE_DIR}/tgt.c
  48   ${CMAKE_CURRENT_SOURCE_DIR}/tgt.h
  49   ${CMAKE_CURRENT_SOURCE_DIR}/function_list.c
  50   ${CMAKE_CURRENT_SOURCE_DIR}/function_list.h
  51   ${CMAKE_CURRENT_SOURCE_DIR}/opj_codec.h
  52   ${CMAKE_CURRENT_SOURCE_DIR}/opj_includes.h
  53   ${CMAKE_CURRENT_SOURCE_DIR}/opj_intmath.h
  54   ${CMAKE_CURRENT_SOURCE_DIR}/opj_malloc.c
  55   ${CMAKE_CURRENT_SOURCE_DIR}/opj_malloc.h
  56   ${CMAKE_CURRENT_SOURCE_DIR}/opj_stdint.h
  57   ${CMAKE_CURRENT_SOURCE_DIR}/sparse_array.c
  58   ${CMAKE_CURRENT_SOURCE_DIR}/sparse_array.h
  59 )
  60 if(BUILD_JPIP)
  61   add_definitions(-DUSE_JPIP)
  62   set(OPENJPEG_SRCS
  63     ${OPENJPEG_SRCS}
  64     ${CMAKE_CURRENT_SOURCE_DIR}/cidx_manager.c
  65     ${CMAKE_CURRENT_SOURCE_DIR}/cidx_manager.h
  66     ${CMAKE_CURRENT_SOURCE_DIR}/phix_manager.c
  67     ${CMAKE_CURRENT_SOURCE_DIR}/ppix_manager.c
  68     ${CMAKE_CURRENT_SOURCE_DIR}/thix_manager.c
  69     ${CMAKE_CURRENT_SOURCE_DIR}/tpix_manager.c
  70     ${CMAKE_CURRENT_SOURCE_DIR}/indexbox_manager.h
  71   )
  72 endif()
  73
  74 option(OPJ_DISABLE_TPSOT_FIX "Disable TPsot==TNsot fix. See https://github.com/uclouvain/openjpeg/issues/254." OFF)
  75 if(OPJ_DISABLE_TPSOT_FIX)
  76   add_definitions(-DOPJ_DISABLE_TPSOT_FIX)
  77 endif()
  78
  79 # Special case for old i586-mingw32msvc-gcc cross compiler
  80 if(NOT WIN32 AND CMAKE_COMPILER_IS_GNUCC AND CMAKE_C_COMPILER MATCHES ".*mingw32msvc.*" )
  81   set(WIN32 YES)
  82 endif()
  83
  84 # Build the library
  85 if(WIN32)
  86   if(BUILD_SHARED_LIBS)
  87     add_definitions(-DOPJ_EXPORTS)
  88   else()
  89     add_definitions(-DOPJ_STATIC)
  90   endif()
  91   add_library(${OPENJPEG_LIBRARY_NAME} ${OPENJPEG_SRCS})
  92   set(INSTALL_LIBS ${OPENJPEG_LIBRARY_NAME})
  93 else()
  94   if(BUILD_SHARED_LIBS AND BUILD_STATIC_LIBS)
  95     # Builds both static and dynamic libs
  96     add_library(${OPENJPEG_LIBRARY_NAME} SHARED ${OPENJPEG_SRCS})
  97     add_library(openjp2_static STATIC ${OPENJPEG_SRCS})
  98     set_target_properties(openjp2_static PROPERTIES OUTPUT_NAME ${OPENJPEG_LIBRARY_NAME})
  99     set(INSTALL_LIBS ${OPENJPEG_LIBRARY_NAME} openjp2_static)
 100   else()
 101     add_library(${OPENJPEG_LIBRARY_NAME} ${OPENJPEG_SRCS})
 102   endif()
 103 endif()
 104
 105 if(UNIX)
 106   target_link_libraries(${OPENJPEG_LIBRARY_NAME} m)
 107 endif()
 108 set_target_properties(${OPENJPEG_LIBRARY_NAME} PROPERTIES ${OPENJPEG_LIBRARY_PROPERTIES})
 109 if(${CMAKE_VERSION} VERSION_GREATER "2.8.11")
 110   target_compile_options(${OPENJPEG_LIBRARY_NAME} PRIVATE ${OPENJP2_COMPILE_OPTIONS})
 111 endif()
 112
 113 # Install library
 114 install(TARGETS ${INSTALL_LIBS}
 115   EXPORT OpenJPEGTargets
 116   RUNTIME DESTINATION ${OPENJPEG_INSTALL_BIN_DIR} COMPONENT Applications
 117   LIBRARY DESTINATION ${OPENJPEG_INSTALL_LIB_DIR} COMPONENT Libraries
 118   ARCHIVE DESTINATION ${OPENJPEG_INSTALL_LIB_DIR} COMPONENT Libraries
 119 )
 120
 121 # Install includes files
 122 install(FILES openjpeg.h opj_stdint.h
 123   DESTINATION ${OPENJPEG_INSTALL_INCLUDE_DIR} COMPONENT Headers
 124 )
 125
 126 if(BUILD_DOC)
 127 # install man page of the library
 128 install(
 129   FILES       ${OPENJPEG_SOURCE_DIR}/doc/man/man3/libopenjp2.3
 130   DESTINATION ${OPENJPEG_INSTALL_MAN_DIR}/man3)
 131 endif()
 132
 133 if(BUILD_LUTS_GENERATOR)
 134 # internal utility to generate t1_luts.h (part of the jp2 lib)
 135 # no need to install:
 136   add_executable(t1_generate_luts t1_generate_luts.c)
 137   if(UNIX)
 138     target_link_libraries(t1_generate_luts m)
 139   endif()
 140 endif()
 141
 142 # Experimental option; let's how cppcheck performs
 143 # Implementation details:
 144 # I could not figure out how to easily upload a file to CDash. Instead simply
 145 # pretend cppcheck is part of the Build step. Technically cppcheck can even
 146 # output gcc formatted error/warning report
 147 # Another implementation detail: I could not redirect error to the error
 148 # catching mechanism something is busted in cmake 2.8.5, I had to use the
 149 # warning regex to catch them.
 150 if(OPENJPEG_CPPCHECK)
 151   find_package(CPPCHECK REQUIRED)
 152   foreach(f ${OPENJPEG_SRCS})
 153     # cppcheck complains about too many configuration, pretend to be WIN32:
 154     add_custom_command(TARGET ${OPENJPEG_LIBRARY_NAME}
 155       COMMAND ${CPPCHECK_EXECUTABLE} -DWIN32 ${f})
 156   endforeach()
 157 endif()
 158
 159 if(OPJ_USE_DSYMUTIL)
 160   if(BUILD_SHARED_LIBS)
 161     add_custom_command(TARGET ${OPENJPEG_LIBRARY_NAME} POST_BUILD
 162     COMMAND "dsymutil" "$<TARGET_SONAME_FILE:${OPENJPEG_LIBRARY_NAME}>"
 163     COMMENT "dsymutil $<TARGET_SONAME_FILE:${OPENJPEG_LIBRARY_NAME}>"
 164     DEPENDS ${OPENJPEG_LIBRARY_NAME})
 165   endif()
 166 endif()
 167
 168 #################################################################################
 169 # threading configuration
 170 #################################################################################
 171 set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
 172
 173 option(OPJ_USE_THREAD "Build with thread/mutex support " ON)
 174 if(NOT OPJ_USE_THREAD)
 175    add_definitions( -DMUTEX_stub)
 176 endif(NOT OPJ_USE_THREAD)
 177
 178 find_package(Threads QUIET)
 179
 180 if(OPJ_USE_THREAD AND WIN32 AND NOT Threads_FOUND )
 181     add_definitions( -DMUTEX_win32)
 182     set(Threads_FOUND YES)
 183 endif()
 184
 185 if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_WIN32_THREADS_INIT )
 186    add_definitions( -DMUTEX_win32)
 187 endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_WIN32_THREADS_INIT )
 188
 189 if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT )
 190    add_definitions( -DMUTEX_pthread)
 191 endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT )
 192
 193 if(OPJ_USE_THREAD AND NOT Threads_FOUND)
 194   message(FATAL_ERROR "No thread library found and thread/mutex support is required by OPJ_USE_THREAD option")
 195 endif(OPJ_USE_THREAD AND NOT Threads_FOUND)
 196
 197 if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 198    TARGET_LINK_LIBRARIES(${OPENJPEG_LIBRARY_NAME} ${CMAKE_THREAD_LIBS_INIT})
 199 endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 200
 201 if(BUILD_UNIT_TESTS)
 202     add_executable(bench_dwt bench_dwt.c)
 203     if(UNIX)
 204         target_link_libraries(bench_dwt m ${OPENJPEG_LIBRARY_NAME})
 205     endif()
 206     if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 207         target_link_libraries(bench_dwt ${CMAKE_THREAD_LIBS_INIT})
 208     endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 209
 210     add_executable(test_sparse_array test_sparse_array.c)
 211     if(UNIX)
 212         target_link_libraries(test_sparse_array m ${OPENJPEG_LIBRARY_NAME})
 213     endif()
 214     if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 215         target_link_libraries(test_sparse_array ${CMAKE_THREAD_LIBS_INIT})
 216     endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 217 endif(BUILD_UNIT_TESTS)