src/lib/openjp2/CMakeLists.txt

   1 include_regular_expression("^.*$")
   2
   3 #
   4 install( FILES  ${CMAKE_CURRENT_BINARY_DIR}/opj_config.h
   5  DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${OPENJPEG_INSTALL_SUBDIR} COMPONENT Headers)
   6
   7 include_directories(
   8   ${${OPENJPEG_NAMESPACE}_BINARY_DIR}/src/lib/openjp2 # opj_config.h and opj_config_private.h
   9 )
  10 # Defines the source code for the library
  11 set(OPENJPEG_SRCS
  12   ${CMAKE_CURRENT_SOURCE_DIR}/thread.c
  13   ${CMAKE_CURRENT_SOURCE_DIR}/thread.h
  14   ${CMAKE_CURRENT_SOURCE_DIR}/bio.c
  15   ${CMAKE_CURRENT_SOURCE_DIR}/bio.h
  16   ${CMAKE_CURRENT_SOURCE_DIR}/cio.c
  17   ${CMAKE_CURRENT_SOURCE_DIR}/cio.h
  18   ${CMAKE_CURRENT_SOURCE_DIR}/dwt.c
  19   ${CMAKE_CURRENT_SOURCE_DIR}/dwt.h
  20   ${CMAKE_CURRENT_SOURCE_DIR}/event.c
  21   ${CMAKE_CURRENT_SOURCE_DIR}/event.h
  22   ${CMAKE_CURRENT_SOURCE_DIR}/ht_dec.c
  23   ${CMAKE_CURRENT_SOURCE_DIR}/image.c
  24   ${CMAKE_CURRENT_SOURCE_DIR}/image.h
  25   ${CMAKE_CURRENT_SOURCE_DIR}/invert.c
  26   ${CMAKE_CURRENT_SOURCE_DIR}/invert.h
  27   ${CMAKE_CURRENT_SOURCE_DIR}/j2k.c
  28   ${CMAKE_CURRENT_SOURCE_DIR}/j2k.h
  29   ${CMAKE_CURRENT_SOURCE_DIR}/jp2.c
  30   ${CMAKE_CURRENT_SOURCE_DIR}/jp2.h
  31   ${CMAKE_CURRENT_SOURCE_DIR}/mct.c
  32   ${CMAKE_CURRENT_SOURCE_DIR}/mct.h
  33   ${CMAKE_CURRENT_SOURCE_DIR}/mqc.c
  34   ${CMAKE_CURRENT_SOURCE_DIR}/mqc.h
  35   ${CMAKE_CURRENT_SOURCE_DIR}/mqc_inl.h
  36   ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg.c
  37   ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg.h
  38   ${CMAKE_CURRENT_SOURCE_DIR}/opj_clock.c
  39   ${CMAKE_CURRENT_SOURCE_DIR}/opj_clock.h
  40   ${CMAKE_CURRENT_SOURCE_DIR}/pi.c
  41   ${CMAKE_CURRENT_SOURCE_DIR}/pi.h
  42   ${CMAKE_CURRENT_SOURCE_DIR}/t1.c
  43   ${CMAKE_CURRENT_SOURCE_DIR}/t1.h
  44   ${CMAKE_CURRENT_SOURCE_DIR}/t2.c
  45   ${CMAKE_CURRENT_SOURCE_DIR}/t2.h
  46   ${CMAKE_CURRENT_SOURCE_DIR}/tcd.c
  47   ${CMAKE_CURRENT_SOURCE_DIR}/tcd.h
  48   ${CMAKE_CURRENT_SOURCE_DIR}/tgt.c
  49   ${CMAKE_CURRENT_SOURCE_DIR}/tgt.h
  50   ${CMAKE_CURRENT_SOURCE_DIR}/function_list.c
  51   ${CMAKE_CURRENT_SOURCE_DIR}/function_list.h
  52   ${CMAKE_CURRENT_SOURCE_DIR}/opj_codec.h
  53   ${CMAKE_CURRENT_SOURCE_DIR}/opj_includes.h
  54   ${CMAKE_CURRENT_SOURCE_DIR}/opj_intmath.h
  55   ${CMAKE_CURRENT_SOURCE_DIR}/opj_malloc.c
  56   ${CMAKE_CURRENT_SOURCE_DIR}/opj_malloc.h
  57   ${CMAKE_CURRENT_SOURCE_DIR}/opj_stdint.h
  58   ${CMAKE_CURRENT_SOURCE_DIR}/sparse_array.c
  59   ${CMAKE_CURRENT_SOURCE_DIR}/sparse_array.h
  60 )
  61 if(BUILD_JPIP)
  62   add_definitions(-DUSE_JPIP)
  63   set(OPENJPEG_SRCS
  64     ${OPENJPEG_SRCS}
  65     ${CMAKE_CURRENT_SOURCE_DIR}/cidx_manager.c
  66     ${CMAKE_CURRENT_SOURCE_DIR}/cidx_manager.h
  67     ${CMAKE_CURRENT_SOURCE_DIR}/phix_manager.c
  68     ${CMAKE_CURRENT_SOURCE_DIR}/ppix_manager.c
  69     ${CMAKE_CURRENT_SOURCE_DIR}/thix_manager.c
  70     ${CMAKE_CURRENT_SOURCE_DIR}/tpix_manager.c
  71     ${CMAKE_CURRENT_SOURCE_DIR}/indexbox_manager.h
  72   )
  73 endif()
  74
  75 option(OPJ_DISABLE_TPSOT_FIX "Disable TPsot==TNsot fix. See https://github.com/uclouvain/openjpeg/issues/254." OFF)
  76 if(OPJ_DISABLE_TPSOT_FIX)
  77   add_definitions(-DOPJ_DISABLE_TPSOT_FIX)
  78 endif()
  79
  80 # Special case for old i586-mingw32msvc-gcc cross compiler
  81 if(NOT WIN32 AND CMAKE_COMPILER_IS_GNUCC AND CMAKE_C_COMPILER MATCHES ".*mingw32msvc.*" )
  82   set(WIN32 YES)
  83 endif()
  84
  85 # Build the library
  86 if(WIN32)
  87   if(BUILD_SHARED_LIBS)
  88     add_definitions(-DOPJ_EXPORTS)
  89   else()
  90     add_definitions(-DOPJ_STATIC)
  91   endif()
  92   add_library(${OPENJPEG_LIBRARY_NAME} ${OPENJPEG_SRCS})
  93   set(INSTALL_LIBS ${OPENJPEG_LIBRARY_NAME})
  94 else()
  95   if(BUILD_SHARED_LIBS AND BUILD_STATIC_LIBS)
  96     # Builds both static and dynamic libs
  97     add_library(${OPENJPEG_LIBRARY_NAME} SHARED ${OPENJPEG_SRCS})
  98     add_library(openjp2_static STATIC ${OPENJPEG_SRCS})
  99     set_target_properties(openjp2_static PROPERTIES OUTPUT_NAME ${OPENJPEG_LIBRARY_NAME})
 100     set(INSTALL_LIBS ${OPENJPEG_LIBRARY_NAME} openjp2_static)
 101     target_include_directories(openjp2_static PUBLIC $<INSTALL_INTERFACE:${OPENJPEG_INSTALL_INCLUDE_DIR}>)
 102   else()
 103     add_library(${OPENJPEG_LIBRARY_NAME} ${OPENJPEG_SRCS})
 104     set(INSTALL_LIBS ${OPENJPEG_LIBRARY_NAME})
 105   endif()
 106 endif()
 107
 108 target_include_directories(${OPENJPEG_LIBRARY_NAME} PUBLIC $<INSTALL_INTERFACE:${OPENJPEG_INSTALL_INCLUDE_DIR}>)
 109 if(UNIX)
 110   target_link_libraries(${OPENJPEG_LIBRARY_NAME} m)
 111 endif()
 112 set_target_properties(${OPENJPEG_LIBRARY_NAME} PROPERTIES ${OPENJPEG_LIBRARY_PROPERTIES})
 113 if(NOT ${CMAKE_VERSION} VERSION_LESS "2.8.12")
 114   target_compile_options(${OPENJPEG_LIBRARY_NAME} PRIVATE ${OPENJP2_COMPILE_OPTIONS})
 115 endif()
 116
 117 # Install library
 118 install(TARGETS ${INSTALL_LIBS}
 119   EXPORT OpenJPEGTargets
 120   RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT Applications
 121   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT Libraries
 122   ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT Libraries
 123 )
 124
 125 # Install includes files
 126 install(FILES openjpeg.h opj_stdint.h
 127   DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/${OPENJPEG_INSTALL_SUBDIR} COMPONENT Headers
 128 )
 129
 130 if(BUILD_DOC)
 131 # install man page of the library
 132 install(
 133   FILES       ${OPENJPEG_SOURCE_DIR}/doc/man/man3/libopenjp2.3
 134   DESTINATION ${CMAKE_INSTALL_MANDIR}/man3)
 135 endif()
 136
 137 if(BUILD_LUTS_GENERATOR)
 138 # internal utility to generate t1_luts.h and t1_ht_luts.h (part of the jp2 lib)
 139 # no need to install:
 140   add_executable(t1_generate_luts t1_generate_luts.c t1_ht_generate_luts.c)
 141   if(UNIX)
 142     target_link_libraries(t1_generate_luts m)
 143   endif()
 144 endif()
 145
 146 # Experimental option; let's how cppcheck performs
 147 # Implementation details:
 148 # I could not figure out how to easily upload a file to CDash. Instead simply
 149 # pretend cppcheck is part of the Build step. Technically cppcheck can even
 150 # output gcc formatted error/warning report
 151 # Another implementation detail: I could not redirect error to the error
 152 # catching mechanism something is busted in cmake 2.8.5, I had to use the
 153 # warning regex to catch them.
 154 if(OPENJPEG_CPPCHECK)
 155   find_package(CPPCHECK REQUIRED)
 156   foreach(f ${OPENJPEG_SRCS})
 157     # cppcheck complains about too many configuration, pretend to be WIN32:
 158     add_custom_command(TARGET ${OPENJPEG_LIBRARY_NAME}
 159       COMMAND ${CPPCHECK_EXECUTABLE} -DWIN32 ${f})
 160   endforeach()
 161 endif()
 162
 163 if(OPJ_USE_DSYMUTIL)
 164   if(BUILD_SHARED_LIBS)
 165     add_custom_command(TARGET ${OPENJPEG_LIBRARY_NAME} POST_BUILD
 166     COMMAND "dsymutil" "$<TARGET_SONAME_FILE:${OPENJPEG_LIBRARY_NAME}>"
 167     COMMENT "dsymutil $<TARGET_SONAME_FILE:${OPENJPEG_LIBRARY_NAME}>"
 168     DEPENDS ${OPENJPEG_LIBRARY_NAME})
 169   endif()
 170 endif()
 171
 172 #################################################################################
 173 # threading configuration
 174 #################################################################################
 175 set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
 176
 177 option(OPJ_USE_THREAD "Build with thread/mutex support " ON)
 178 if(NOT OPJ_USE_THREAD)
 179    add_definitions( -DMUTEX_stub)
 180 endif(NOT OPJ_USE_THREAD)
 181
 182 find_package(Threads QUIET)
 183
 184 if(OPJ_USE_THREAD AND WIN32 AND NOT Threads_FOUND )
 185     add_definitions( -DMUTEX_win32)
 186     set(Threads_FOUND YES)
 187 endif()
 188
 189 if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_WIN32_THREADS_INIT )
 190    add_definitions( -DMUTEX_win32)
 191 endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_WIN32_THREADS_INIT )
 192
 193 if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT )
 194    add_definitions( -DMUTEX_pthread)
 195 endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT )
 196
 197 if(OPJ_USE_THREAD AND NOT Threads_FOUND)
 198   message(FATAL_ERROR "No thread library found and thread/mutex support is required by OPJ_USE_THREAD option")
 199 endif(OPJ_USE_THREAD AND NOT Threads_FOUND)
 200
 201 if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 202    TARGET_LINK_LIBRARIES(${OPENJPEG_LIBRARY_NAME} ${CMAKE_THREAD_LIBS_INIT})
 203 endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 204
 205 if(BUILD_UNIT_TESTS AND UNIX)
 206     add_executable(bench_dwt bench_dwt.c)
 207     if(UNIX)
 208         target_link_libraries(bench_dwt m ${OPENJPEG_LIBRARY_NAME})
 209     endif()
 210     if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 211         target_link_libraries(bench_dwt ${CMAKE_THREAD_LIBS_INIT})
 212     endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 213
 214     add_executable(test_sparse_array test_sparse_array.c)
 215     if(UNIX)
 216         target_link_libraries(test_sparse_array m ${OPENJPEG_LIBRARY_NAME})
 217     endif()
 218     if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 219         target_link_libraries(test_sparse_array ${CMAKE_THREAD_LIBS_INIT})
 220     endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 221 endif(BUILD_UNIT_TESTS AND UNIX)