src/lib/openjpip/CMakeLists.txt

   1 include_regular_expression("^.*$")
   2
   3 add_definitions(-DUSE_JPIP)
   4
   5 include_directories(
   6   ${CMAKE_CURRENT_SOURCE_DIR}
   7   ${OPENJPEG_BINARY_DIR}/src/lib/openjp2 # opj_config.h
   8   ${OPENJPEG_SOURCE_DIR}/src/lib/openjp2
   9   ${FCGI_INCLUDE_DIRS}
  10   ${CURL_INCLUDE_DIRS}
  11 )
  12
  13 # Defines the source code for the library
  14 set(OPENJPIP_SRCS
  15   ${CMAKE_CURRENT_SOURCE_DIR}/boxheader_manager.c
  16   ${CMAKE_CURRENT_SOURCE_DIR}/codestream_manager.c
  17   ${CMAKE_CURRENT_SOURCE_DIR}/imgreg_manager.c
  18   ${CMAKE_CURRENT_SOURCE_DIR}/marker_manager.c
  19   ${CMAKE_CURRENT_SOURCE_DIR}/msgqueue_manager.c
  20   ${CMAKE_CURRENT_SOURCE_DIR}/box_manager.c
  21   ${CMAKE_CURRENT_SOURCE_DIR}/faixbox_manager.c
  22   ${CMAKE_CURRENT_SOURCE_DIR}/index_manager.c
  23   ${CMAKE_CURRENT_SOURCE_DIR}/metadata_manager.c
  24   ${CMAKE_CURRENT_SOURCE_DIR}/placeholder_manager.c
  25   ${CMAKE_CURRENT_SOURCE_DIR}/byte_manager.c
  26   ${CMAKE_CURRENT_SOURCE_DIR}/ihdrbox_manager.c
  27   ${CMAKE_CURRENT_SOURCE_DIR}/manfbox_manager.c
  28   ${CMAKE_CURRENT_SOURCE_DIR}/mhixbox_manager.c
  29   ${CMAKE_CURRENT_SOURCE_DIR}/target_manager.c
  30   ${CMAKE_CURRENT_SOURCE_DIR}/cachemodel_manager.c
  31   ${CMAKE_CURRENT_SOURCE_DIR}/j2kheader_manager.c
  32   ${CMAKE_CURRENT_SOURCE_DIR}/jp2k_encoder.c
  33   ${CMAKE_CURRENT_SOURCE_DIR}/openjpip.c
  34   ${CMAKE_CURRENT_SOURCE_DIR}/query_parser.c
  35   ${CMAKE_CURRENT_SOURCE_DIR}/channel_manager.c
  36   ${CMAKE_CURRENT_SOURCE_DIR}/session_manager.c
  37   ${CMAKE_CURRENT_SOURCE_DIR}/jpip_parser.c
  38   ${CMAKE_CURRENT_SOURCE_DIR}/sock_manager.c
  39   ${OPENJPEG_SOURCE_DIR}/src/lib/openjp2/opj_malloc.c
  40   )
  41
  42 set(SERVER_SRCS
  43   ${CMAKE_CURRENT_SOURCE_DIR}/auxtrans_manager.c
  44   )
  45
  46 set(LOCAL_SRCS
  47   ${CMAKE_CURRENT_SOURCE_DIR}/jp2k_decoder.c
  48   ${CMAKE_CURRENT_SOURCE_DIR}/imgsock_manager.c
  49   ${CMAKE_CURRENT_SOURCE_DIR}/jpipstream_manager.c
  50   ${CMAKE_CURRENT_SOURCE_DIR}/cache_manager.c
  51   ${CMAKE_CURRENT_SOURCE_DIR}/dec_clientmsg_handler.c
  52   )
  53
  54 # Build the library
  55 if(WIN32)
  56   if(BUILD_SHARED_LIBS)
  57     add_definitions(-DOPJ_EXPORTS)
  58   else()
  59     add_definitions(-DOPJ_STATIC)
  60   endif()
  61 endif()
  62 add_library(openjpip ${OPENJPIP_SRCS} ${LOCAL_SRCS})
  63 set_target_properties(openjpip
  64   PROPERTIES ${OPENJPEG_LIBRARY_PROPERTIES})
  65 if(NOT ${CMAKE_VERSION} VERSION_LESS "2.8.12")
  66   target_compile_options(openjpip PRIVATE ${OPENJPEG_LIBRARY_COMPILE_OPTIONS})
  67 endif()
  68 target_link_libraries(openjpip ${OPENJPEG_LIBRARY_NAME})
  69 if(WIN32)
  70   # add Winsock on windows+mingw
  71   target_link_libraries(openjpip ws2_32)
  72 endif()
  73
  74 # Install library
  75 install(TARGETS openjpip
  76   EXPORT OpenJPEGTargets
  77   RUNTIME DESTINATION ${OPENJPEG_INSTALL_BIN_DIR} COMPONENT Applications
  78   LIBRARY DESTINATION ${OPENJPEG_INSTALL_LIB_DIR} COMPONENT Libraries
  79   ARCHIVE DESTINATION ${OPENJPEG_INSTALL_LIB_DIR} COMPONENT Libraries
  80   )
  81
  82 if(BUILD_JPIP_SERVER)
  83   add_library(openjpip_server STATIC ${OPENJPIP_SRCS} ${SERVER_SRCS})
  84   target_link_libraries(openjpip_server ${FCGI_LIBRARIES} ${CURL_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})
  85   set_target_properties(openjpip_server
  86     PROPERTIES COMPILE_FLAGS "-DSERVER")
  87   install(TARGETS openjpip_server
  88     EXPORT OpenJPEGTargets
  89     DESTINATION ${OPENJPEG_INSTALL_LIB_DIR} COMPONENT Libraries
  90     )
  91 endif()