tests/CMakeLists.txt

   1 # Tests
   2 include_directories(
   3   ${OPENJPEG_BINARY_DIR}/src/lib/openjp2 # opj_config.h
   4   ${OPENJPEG_BINARY_DIR}/src/bin/common # opj_apps_config.h
   5   ${OPENJPEG_SOURCE_DIR}/src/lib/openjp2
   6   ${OPENJPEG_SOURCE_DIR}/src/bin/jp2
   7   ${OPENJPEG_SOURCE_DIR}/src/bin/common
   8   ${Z_INCLUDE_DIRNAME}
   9   ${PNG_INCLUDE_DIRNAME}
  10   ${TIFF_INCLUDE_DIRNAME}
  11   )
  12
  13 # First thing define the common source:
  14 set(compare_images_SRCS compare_images.c
  15   ${OPENJPEG_SOURCE_DIR}/src/bin/jp2/convert.c
  16   ${OPENJPEG_SOURCE_DIR}/src/bin/jp2/converttif.c
  17   ${OPENJPEG_SOURCE_DIR}/src/bin/common/opj_getopt.c
  18   )
  19
  20 set(compare_dump_files_SRCS compare_dump_files.c
  21   ${OPENJPEG_SOURCE_DIR}/src/bin/common/opj_getopt.c)
  22
  23 set(compare_raw_files_SRCS compare_raw_files.c
  24   ${OPENJPEG_SOURCE_DIR}/src/bin/common/opj_getopt.c)
  25
  26 add_executable(compare_images ${compare_images_SRCS})
  27 target_link_libraries(compare_images
  28   ${OPENJPEG_LIBRARY_NAME}
  29   ${PNG_LIBNAME} ${TIFF_LIBNAME}
  30   )
  31 # To support universal exe:
  32 if(ZLIB_FOUND AND APPLE)
  33   target_link_libraries(compare_images z)
  34 else(ZLIB_FOUND AND APPLE)
  35   target_link_libraries(compare_images ${Z_LIBNAME})
  36 endif()
  37
  38 add_executable(compare_dump_files ${compare_dump_files_SRCS})
  39
  40 add_executable(j2k_random_tile_access j2k_random_tile_access.c)
  41 target_link_libraries(j2k_random_tile_access ${OPENJPEG_LIBRARY_NAME})
  42
  43 add_executable(compare_raw_files ${compare_raw_files_SRCS})
  44
  45 add_executable(test_tile_encoder test_tile_encoder.c)
  46 target_link_libraries(test_tile_encoder ${OPENJPEG_LIBRARY_NAME})
  47
  48 add_executable(test_decode_area test_decode_area.c)
  49 target_link_libraries(test_decode_area ${OPENJPEG_LIBRARY_NAME})
  50
  51 # Let's try a couple of possibilities:
  52 add_test(NAME tte0 COMMAND test_tile_encoder)
  53 add_test(NAME tte1 COMMAND test_tile_encoder 3 2048 2048 1024 1024 8 1 tte1.j2k)
  54 add_test(NAME tte2 COMMAND test_tile_encoder 3 2048 2048 1024 1024 8 1 tte2.jp2)
  55 add_test(NAME tte3 COMMAND test_tile_encoder 1 2048 2048 1024 1024 8 1 tte3.j2k)
  56 add_test(NAME tte4 COMMAND test_tile_encoder 1  256  256  128  128 8 0 tte4.j2k)
  57 add_test(NAME tte5 COMMAND test_tile_encoder 1  512  512  256  256 8 0 tte5.j2k)
  58 #add_test(NAME tte6 COMMAND test_tile_encoder 1 8192 8192  512  512 8 0 tte6.j2k)
  59 #add_test(NAME tte7 COMMAND test_tile_encoder 1 32768 32768 512  512 8 0 tte7.jp2)
  60
  61 add_executable(test_tile_decoder test_tile_decoder.c)
  62 target_link_libraries(test_tile_decoder ${OPENJPEG_LIBRARY_NAME})
  63
  64 add_test(NAME ttd0 COMMAND test_tile_decoder)
  65 set_property(TEST ttd0 APPEND PROPERTY DEPENDS tte0)
  66 add_test(NAME ttd1 COMMAND test_tile_decoder 0 0 1024 1024 tte1.j2k)
  67 set_property(TEST ttd1 APPEND PROPERTY DEPENDS tte1)
  68 add_test(NAME ttd2 COMMAND test_tile_decoder 0 0 1024 1024 tte2.jp2)
  69 set_property(TEST ttd2 APPEND PROPERTY DEPENDS tte2)
  70 #add_test(NAME ttd6 COMMAND test_tile_decoder 0 0  512  512 tte6.j2k)
  71 #set_property(TEST ttd6 APPEND PROPERTY DEPENDS tte6)
  72 #add_test(NAME ttd7 COMMAND test_tile_decoder 0 0  512  512 tte7.jp2)
  73 #set_property(TEST ttd7 APPEND PROPERTY DEPENDS tte7)
  74
  75 add_test(NAME rta1 COMMAND j2k_random_tile_access tte1.j2k)
  76 set_property(TEST rta1 APPEND PROPERTY DEPENDS tte1)
  77 add_test(NAME rta2 COMMAND j2k_random_tile_access tte2.jp2)
  78 set_property(TEST rta2 APPEND PROPERTY DEPENDS tte2)
  79 add_test(NAME rta3 COMMAND j2k_random_tile_access tte3.j2k)
  80 set_property(TEST rta3 APPEND PROPERTY DEPENDS tte3)
  81 add_test(NAME rta4 COMMAND j2k_random_tile_access tte4.j2k)
  82 set_property(TEST rta4 APPEND PROPERTY DEPENDS tte4)
  83 add_test(NAME rta5 COMMAND j2k_random_tile_access tte5.j2k)
  84 set_property(TEST rta5 APPEND PROPERTY DEPENDS tte5)
  85
  86 add_test(NAME tda_prep_reversible_no_precinct COMMAND test_tile_encoder 1 256 256 32 32 8 0 reversible_no_precinct.j2k 4 4 3 0 0 1)
  87 add_test(NAME tda_reversible_no_precinct COMMAND test_decode_area -q reversible_no_precinct.j2k)
  88 set_property(TEST tda_reversible_no_precinct APPEND PROPERTY DEPENDS tda_prep_reversible_no_precinct)
  89
  90 add_test(NAME tda_prep_reversible_with_precinct COMMAND test_tile_encoder 1 256 256 32 32 8 0 reversible_with_precinct.j2k 4 4 3 0 0 1 16 16)
  91 add_test(NAME tda_reversible_with_precinct COMMAND test_decode_area -q reversible_with_precinct.j2k)
  92 set_property(TEST tda_reversible_with_precinct APPEND PROPERTY DEPENDS tda_prep_reversible_with_precinct)
  93
  94 add_test(NAME tda_prep_irreversible_no_precinct COMMAND test_tile_encoder 1 256 256 32 32 8 1 irreversible_no_precinct.j2k 4 4 3 0 0 1)
  95 add_test(NAME tda_irreversible_no_precinct COMMAND test_decode_area -q irreversible_no_precinct.j2k)
  96 set_property(TEST tda_irreversible_no_precinct APPEND PROPERTY DEPENDS tda_prep_irreversible_no_precinct)
  97
  98 add_executable(include_openjpeg include_openjpeg.c)
  99
 100 # No image send to the dashboard if lib PNG is not available.
 101 if(NOT OPJ_HAVE_LIBPNG)
 102   message(WARNING "Lib PNG seems to be not available: if you want run the non-regression tests with images reported to the dashboard, you need it (try BUILD_THIRDPARTY)")
 103 endif()
 104
 105 add_subdirectory(conformance)
 106 add_subdirectory(nonregression)
 107 add_subdirectory(unit)
 108
 109 if(BUILD_JPIP)
 110   if(JPIP_SERVER)
 111     #set(s "http://jpip.example.com/myFCGI?target=16.jp2&fsiz=170,170&cnew=http&type=jpp-stream")
 112     set(s "${JPIP_SERVER}?target=16.jp2&fsiz=170,170&cnew=http&type=jpp-stream")
 113     set(p "${CMAKE_CURRENT_BINARY_DIR}/jpip.dat")
 114     set(md5 "d41d8cd98f00b204e9800998ecf8427e")
 115     add_test(NAME TestJPIP1 COMMAND ${CMAKE_COMMAND} -DD_URL:STRING=${s} -DD_FILE:PATH=${p}
 116       -DEXPECTED_MD5=${md5} -P ${PROJECT_SOURCE_DIR}/cmake/JPIPTestDriver.cmake)
 117   endif()
 118 endif()
 119
 120 add_executable(ppm2rgb3 ppm2rgb3.c)
 121 #add_executable(pdf2jp2 pdf2jp2.c)