tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 cmake_minimum_required(VERSION 2.8.7)
   4
   5 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6
   7 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   8 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   9 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
  10
  11
  12 set(INPUT_NR_PATH ${INPUT_NR})
  13 set(TEMP_PATH ${TEMP})
  14 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  15
  16 # need kdu_expand if possible
  17 find_package(KAKADU)
  18 # need jpylyzer if possible
  19 find_package(JPYLYZER)
  20
  21 #########################################################################
  22 # GENERATION OF THE TEST SUITE (DUMP)
  23 # Dump all files with the selected extension inside the input directory
  24
  25 # technically opj_dump should simply parse these one, since syntax is ok.
  26 set(BLACKLIST_JPEG2000_TMP
  27     2539.pdf.SIGFPE.706.1712.jp2
  28     0290cb77c5df21828fa74cf2ab2c84d8.SIGFPE.d25.31.jp2
  29     26ccf3651020967f7778238ef5af08af.SIGFPE.d25.527.jp2
  30     4035.pdf.SIGSEGV.d8b.3375.jp2
  31     3635.pdf.asan.77.2930.jp2
  32     issue165.jp2
  33     #edf_c2_1103421.jp2
  34     edf_c2_1178956.jp2
  35     edf_c2_1000290.jp2
  36     #edf_c2_1000691.jp2 # ok
  37     edf_c2_1377017.jp2
  38     edf_c2_1002767.jp2
  39     edf_c2_10025.jp2
  40     edf_c2_1000234.jp2
  41     edf_c2_225881.jp2
  42     edf_c2_1000671.jp2
  43     #edf_c2_1013627.jp2 # weird box, but kdu_jp2info ok
  44     edf_c2_1015644.jp2
  45     edf_c2_101463.jp2
  46     edf_c2_1674177.jp2
  47     edf_c2_1673169.jp2
  48     issue418.jp2
  49     issue429.jp2
  50     issue427-null-image-size.jp2
  51     issue427-illegal-tile-offset.jp2
  52     issue495.jp2
  53     issue820.jp2
  54    )
  55
  56 # Define a list of file which should be gracefully rejected:
  57 set(BLACKLIST_JPEG2000
  58     ${BLACKLIST_JPEG2000_TMP}
  59     broken1.jp2
  60     broken2.jp2
  61     broken3.jp2
  62     broken4.jp2
  63     edf_c2_20.jp2 #may look ok as per kdu_jp2info, but inspection it reveals that the transformation value is out of range
  64     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  65     gdal_fuzzer_check_comp_dx_dy.jp2
  66     gdal_fuzzer_check_number_of_tiles.jp2
  67     gdal_fuzzer_unchecked_numresolutions.jp2
  68     mem-b2ace68c-1381.jp2
  69     1851.pdf.SIGSEGV.ce9.948.jp2
  70     1888.pdf.asan.35.988.jp2
  71     issue362-2863.jp2 #kdu_jp2info ok
  72     issue362-2866.jp2
  73     issue362-2894.jp2
  74     issue400.jp2 #kdu_jp2info ok
  75     issue364-38.jp2
  76     issue364-903.jp2 #kdu_jp2info ok
  77     issue393.jp2 #kdu_jp2info ok
  78     issue408.jp2 #kdu_jp2info ok
  79     issue420.jp2 #kdu_jp2info ok
  80     27ac957758a35d00d6765a0c86350d9c.SIGFPE.d25.537.jpc #kdu_jp2info crash
  81     3672da2f1f67bbecad27d7181b4e9d7c.SIGFPE.d25.805.jpc #kdu_jp2info crash
  82     issue475.jp2 #kdu_jp2info ok
  83     issue413.jp2 #kdu_jp2info ok
  84     issue823.jp2 #kdu_jp2info ok
  85     issue826.jp2 #inspection reveales that the transformation value is out of range
  86     oss-fuzz2785.jp2 #inspection reveales that the transformation value is out of range
  87    )
  88
  89 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  90      "${INPUT_NR}/*.j2k"
  91      "${INPUT_NR}/*.j2c"
  92      "${INPUT_NR}/*.jp2"
  93      "${INPUT_NR}/*.jpc"
  94      #"${INPUT_NR}/*.jpx"
  95      )
  96
  97 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  98   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  99   #get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 100   # cannot use longest extension function, since some name contains multiples
 101   # dots. Instead write out own shortest extension function:
 102   string(FIND ${INPUT_FILENAME_NAME} "." SHORTEST_EXT_POS REVERSE)
 103   string(SUBSTRING ${INPUT_FILENAME_NAME} 0 ${SHORTEST_EXT_POS} INPUT_FILENAME_NAME_WE)
 104   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
 105
 106   # Dump the input image
 107   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
 108            COMMAND opj_dump
 109                -i ${INPUT_FILENAME}
 110                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
 111                -v
 112                )
 113
 114   if(bad_jpeg2000)
 115     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
 116                          PROPERTIES WILL_FAIL TRUE)
 117
 118   else()
 119
 120     # Compare the dump output with the baseline
 121     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
 122                 COMMAND compare_dump_files
 123             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
 124             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
 125             )
 126
 127     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
 128                          PROPERTIES DEPENDS
 129                          NR-${INPUT_FILENAME_NAME}-dump)
 130   endif()
 131
 132 endforeach()
 133
 134
 135 #########################################################################
 136 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
 137 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
 138 # to know which files processed and with which options.
 139
 140 # Configure the test suite file:
 141 configure_file("test_suite.ctest.in"
 142                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
 143                @ONLY)
 144
 145 # Read the file into a list
 146 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
 147
 148 # Try to find and configure and read another test suite file
 149 file(GLOB TEST_SUITE_FILES *.ctest.in)
 150 if (TEST_SUITE_FILES)
 151   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
 152
 153     # Avoid to process the official test suite
 154     set(FILE_ALREADY_READ 0)
 155     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
 156     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 157
 158     if(NOT FILE_ALREADY_READ)
 159       # Configure the additional test suite file:
 160       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 161       configure_file("${TEST_SUITE_FILE}"
 162                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 163                      @ONLY)
 164       # Read the additional file into a list
 165       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 166       # Append the list of command
 167       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 168
 169     endif()
 170
 171   endforeach()
 172
 173 else()
 174
 175   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 176
 177 endif()
 178
 179
 180 set(nonregression_filenames_used)
 181 # Parse the command line found in the file(s)
 182 set(IT_TEST_ENC 0)
 183 set(IT_TEST_DEC 0)
 184 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 185
 186   set(IGNORE_LINE_FOUND 0)
 187
 188   # Replace space by ; to generate a list
 189   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 190
 191   # Check if the first argument begin by the comment sign
 192   list(GET CMD_ARG_LIST 0 EXE_NAME)
 193
 194   if(EXE_NAME)
 195     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 196   endif()
 197
 198   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 199
 200     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 201
 202   else()
 203
 204     # Check if the first argument begin by the failed sign
 205     set(FAILED_TEST_FOUND 0)
 206     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 207
 208     if (FAILED_TEST_FOUND)
 209       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 210       set(FAILED_TEST_FOUND_1 0)
 211       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 212
 213       if (FAILED_TEST_FOUND_1)
 214
 215         list(REMOVE_AT CMD_ARG_LIST 0)
 216
 217       else ()
 218
 219         set(FAILED_TEST_FOUND_2 0)
 220         list(GET CMD_ARG_LIST 1 EXE_NAME)
 221         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 222
 223         if (FAILED_TEST_FOUND_2)
 224
 225           list(REMOVE_AT CMD_ARG_LIST 0)
 226           list(REMOVE_AT CMD_ARG_LIST 0)
 227
 228         else ()
 229
 230           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 231
 232         endif ()
 233       endif ()
 234
 235     else ()
 236       # Check if the first argument is equal to opj_compress
 237       string(REGEX MATCH "^opj_compress$|^opj_compress_no_raw$|^opj_compress_no_raw_lossless$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 238
 239       if(EXE_NAME_FOUND)
 240
 241         string(REGEX MATCH "^opj_compress$|^opj_compress_no_raw$|^opj_compress_no_raw_lossless$" ENC_TEST_FOUND ${EXE_NAME})
 242         string(REGEX MATCH "^opj_compress_no_raw$|^opj_compress_no_raw_lossless$" NO_RAW ${EXE_NAME})
 243         string(REGEX MATCH "opj_compress_no_raw_lossless" LOSSLESS ${EXE_NAME})
 244
 245       else()
 246
 247         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 248
 249       endif()
 250
 251       list(REMOVE_AT CMD_ARG_LIST 0)
 252
 253     endif ()
 254
 255     # Parse the argument list to find the input filename and output filename
 256     set(CMD_ARG_LIST_2 "")
 257     set(ARG_POS 0)
 258     set(INPUT_ARG_POS 0)
 259     set(OUTPUT_ARG_POS 0)
 260
 261     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 262
 263       math(EXPR ARG_POS "${ARG_POS}+1" )
 264
 265       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 266       if(INPUT_ARG_FOUND)
 267         set(INPUT_ARG_POS ${ARG_POS})
 268         set(INPUT_ARG_FOUND 0)
 269       endif()
 270
 271       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 272       if(OUTPUT_ARG_FOUND)
 273         set(OUTPUT_ARG_POS ${ARG_POS})
 274         set(OUTPUT_ARG_FOUND 0)
 275       endif()
 276
 277       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 278
 279     endforeach()
 280
 281     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 282     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 283     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 284     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 285     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 286
 287     #-----
 288     # Now we can add the test suite corresponding to a line command in the file
 289     #-----
 290     # ENCODER TEST SUITE
 291     if(ENC_TEST_FOUND)
 292         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 293
 294         # Encode an image into the jpeg2000 format
 295         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 296           COMMAND opj_compress
 297           ${CMD_ARG_LIST_2}
 298         )
 299
 300         if(FAILED_TEST_FOUND)
 301             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 302         else()
 303
 304           # Dump the encoding file
 305           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 306             COMMAND opj_dump
 307             -i ${OUTPUT_FILENAME}
 308             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 309           )
 310           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 311                                PROPERTIES DEPENDS
 312                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 313
 314           # Compare the dump file with the baseline
 315           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 316             COMMAND compare_dump_files
 317             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 318             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 319           )
 320
 321           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 322                                PROPERTIES DEPENDS
 323                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 324
 325           # Decode the encoding file with kakadu expand command
 326           if (KDU_EXPAND_EXECUTABLE)
 327             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 328               COMMAND ${KDU_EXPAND_EXECUTABLE}
 329               -i ${OUTPUT_FILENAME}
 330               -o ${OUTPUT_FILENAME}.raw
 331               )
 332
 333             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 334                                  PROPERTIES DEPENDS
 335                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 336
 337             if(NOT NO_RAW)
 338                 # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 339                 add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 340                 COMMAND compare_raw_files
 341                 -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 342                 -t ${OUTPUT_FILENAME}.raw
 343                 )
 344
 345                 set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 346                                     PROPERTIES DEPENDS
 347                                     NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 348             endif()
 349
 350           endif()
 351
 352           # Test the encoded file is a valid JP2 file
 353           if (JPYLYZER_EXECUTABLE)
 354             if (${OUTPUT_FILENAME} MATCHES "\\.jp2$")
 355               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser
 356                 COMMAND ${JPYLYZER_EXECUTABLE}
 357                 ${OUTPUT_FILENAME}
 358                 )
 359               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser PROPERTIES
 360                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 361                 PASS_REGULAR_EXPRESSION "<isValidJP2>True</isValidJP2>"
 362                 )
 363             endif()
 364           endif(JPYLYZER_EXECUTABLE)
 365
 366           # If lossless compression (simple test is 4 arguments), decompress & compare
 367           list(LENGTH CMD_ARG_LIST_2 ARG_COUNT)
 368           if ((ARG_COUNT EQUAL 4) OR LOSSLESS)
 369             # can we compare with the input image ?
 370             if (${INPUT_FILENAME_NAME} MATCHES "\\.tif$")
 371               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 372                 COMMAND opj_decompress -i ${OUTPUT_FILENAME} -o ${OUTPUT_FILENAME}.lossless.tif
 373                 )
 374               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode PROPERTIES
 375                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 376                 )
 377               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare
 378                 COMMAND compare_images -b ${INPUT_FILENAME} -t ${OUTPUT_FILENAME}.lossless.tif -n 1 -d
 379                 )
 380               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare PROPERTIES
 381                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 382                 )
 383             endif()
 384           endif()
 385       endif()
 386
 387     # DECODER TEST SUITE
 388     else()
 389       string(FIND ${INPUT_FILENAME} "nonregression" nr_pos)
 390       if(${nr_pos} GREATER 0)
 391         list(APPEND nonregression_filenames_used ${INPUT_FILENAME_NAME})
 392       endif()
 393       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 394
 395       # Decode the input image
 396       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 397         COMMAND opj_decompress
 398         ${CMD_ARG_LIST_2}
 399       )
 400
 401       if(FAILED_TEST_FOUND)
 402
 403         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 404
 405       else()
 406         # if not failed, check against registered md5:
 407         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 408           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 409           -DOUTFILENAME:STRING=${OUTPUT_FILENAME}
 410           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 411
 412         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5
 413           PROPERTIES DEPENDS NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 414         )
 415
 416 # FIXME: add a compare2base function base on raw which
 417 # can output png diff files if necessary
 418 #  add_test(NR-${filename}-compare2base
 419 #      ${EXECUTABLE_OUTPUT_PATH}/compare_images
 420 #     -b ${BASELINE_NR}/opj_${filenameRef}
 421 #     -t ${TEMP}/${filename}.pgx
 422 #     -n ${nbComponents}
 423 #     -d
 424 #     -s b_t_
 425 #     )
 426 #
 427 #  set_tests_properties(NR-${filename}-compare2base
 428 #                       PROPERTIES DEPENDS
 429 #                       NR-${filename}-decode)
 430
 431       endif()
 432
 433     endif()
 434
 435   endif()
 436
 437 endforeach()
 438
 439 set(existing_filenames)
 440 foreach(f ${OPJ_DATA_NR_LIST})
 441   get_filename_component(ff ${f} NAME)
 442   list(APPEND existing_filenames ${ff})
 443 endforeach()
 444 if(existing_filenames)
 445 list(REMOVE_ITEM existing_filenames ${nonregression_filenames_used})
 446 endif()
 447
 448 # keep track of new addition:
 449 # if we reach here, then a J2K files was added but no test is present in
 450 # test_suite.ctest.in:
 451 foreach(found_but_no_test ${existing_filenames})
 452   add_test(NAME Found-But-No-Test-${found_but_no_test} COMMAND ${CMAKE_COMMAND} -E echo "${found_but_no_test}")
 453   set_tests_properties(Found-But-No-Test-${found_but_no_test} PROPERTIES WILL_FAIL TRUE)
 454 endforeach()