tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 cmake_minimum_required(VERSION 2.8.7)
   4
   5 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6
   7 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   8 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   9 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
  10
  11
  12 set(INPUT_NR_PATH ${INPUT_NR})
  13 set(TEMP_PATH ${TEMP})
  14 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  15
  16 # need kdu_expand if possible
  17 find_package(KAKADU)
  18 # need jpylyzer if possible
  19 find_package(JPYLYZER)
  20
  21 #########################################################################
  22 # GENERATION OF THE TEST SUITE (DUMP)
  23 # Dump all files with the selected extension inside the input directory
  24
  25 # technically opj_dump should simply parse these one, since syntax is ok.
  26 set(BLACKLIST_JPEG2000_TMP
  27     2539.pdf.SIGFPE.706.1712.jp2
  28     0290cb77c5df21828fa74cf2ab2c84d8.SIGFPE.d25.31.jp2
  29     26ccf3651020967f7778238ef5af08af.SIGFPE.d25.527.jp2
  30     4035.pdf.SIGSEGV.d8b.3375.jp2
  31     3635.pdf.asan.77.2930.jp2
  32     issue165.jp2
  33     #edf_c2_1103421.jp2
  34     edf_c2_1178956.jp2
  35     edf_c2_1000290.jp2
  36     #edf_c2_1000691.jp2 # ok
  37     edf_c2_1377017.jp2
  38     edf_c2_1002767.jp2
  39     edf_c2_10025.jp2
  40     edf_c2_1000234.jp2
  41     edf_c2_225881.jp2
  42     edf_c2_1000671.jp2
  43     #edf_c2_1013627.jp2 # weird box, but kdu_jp2info ok
  44     edf_c2_1015644.jp2
  45     edf_c2_101463.jp2
  46     edf_c2_1674177.jp2
  47     edf_c2_1673169.jp2
  48     issue418.jp2
  49     issue429.jp2
  50     issue427-null-image-size.jp2
  51     issue427-illegal-tile-offset.jp2
  52     issue495.jp2
  53     issue820.jp2
  54    )
  55
  56 # Define a list of file which should be gracefully rejected:
  57 set(BLACKLIST_JPEG2000
  58     ${BLACKLIST_JPEG2000_TMP}
  59     broken1.jp2
  60     broken2.jp2
  61     broken3.jp2
  62     broken4.jp2
  63     edf_c2_20.jp2 #may look ok as per kdu_jp2info, but inspection it reveals that the transformation value is out of range
  64     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  65     gdal_fuzzer_check_comp_dx_dy.jp2
  66     gdal_fuzzer_check_number_of_tiles.jp2
  67     gdal_fuzzer_unchecked_numresolutions.jp2
  68     mem-b2ace68c-1381.jp2
  69     1851.pdf.SIGSEGV.ce9.948.jp2
  70     1888.pdf.asan.35.988.jp2
  71     issue362-2863.jp2 #kdu_jp2info ok
  72     issue362-2866.jp2
  73     issue362-2894.jp2
  74     issue400.jp2 #kdu_jp2info ok
  75     issue364-38.jp2
  76     issue364-903.jp2 #kdu_jp2info ok
  77     issue393.jp2 #kdu_jp2info ok
  78     issue408.jp2 #kdu_jp2info ok
  79     issue420.jp2 #kdu_jp2info ok
  80     27ac957758a35d00d6765a0c86350d9c.SIGFPE.d25.537.jpc #kdu_jp2info crash
  81     3672da2f1f67bbecad27d7181b4e9d7c.SIGFPE.d25.805.jpc #kdu_jp2info crash
  82     issue475.jp2 #kdu_jp2info ok
  83     issue413.jp2 #kdu_jp2info ok
  84     issue823.jp2 #kdu_jp2info ok
  85     issue826.jp2 #inspection reveales that the transformation value is out of range
  86     oss-fuzz2785.jp2 #inspection reveales that the transformation value is out of range
  87    )
  88
  89 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  90      "${INPUT_NR}/*.j2k"
  91      "${INPUT_NR}/*.j2c"
  92      "${INPUT_NR}/*.jp2"
  93      "${INPUT_NR}/*.jpc"
  94      "${INPUT_NR}/*.jph"
  95      "${INPUT_NR}/*.jhc"
  96      #"${INPUT_NR}/*.jpx"
  97      )
  98
  99 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
 100   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 101   #get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 102   # cannot use longest extension function, since some name contains multiples
 103   # dots. Instead write out own shortest extension function:
 104   string(FIND ${INPUT_FILENAME_NAME} "." SHORTEST_EXT_POS REVERSE)
 105   string(SUBSTRING ${INPUT_FILENAME_NAME} 0 ${SHORTEST_EXT_POS} INPUT_FILENAME_NAME_WE)
 106   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
 107
 108   # Dump the input image
 109   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
 110            COMMAND opj_dump
 111                -i ${INPUT_FILENAME}
 112                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
 113                -v
 114                )
 115
 116   if(bad_jpeg2000)
 117     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
 118                          PROPERTIES WILL_FAIL TRUE)
 119
 120   else()
 121
 122     # Compare the dump output with the baseline
 123     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
 124                 COMMAND compare_dump_files
 125             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
 126             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
 127             )
 128
 129     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
 130                          PROPERTIES DEPENDS
 131                          NR-${INPUT_FILENAME_NAME}-dump)
 132   endif()
 133
 134 endforeach()
 135
 136
 137 #########################################################################
 138 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
 139 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
 140 # to know which files processed and with which options.
 141
 142 # Configure the test suite file:
 143 configure_file("test_suite.ctest.in"
 144                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
 145                @ONLY)
 146
 147 # Read the file into a list
 148 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
 149
 150 # Try to find and configure and read another test suite file
 151 file(GLOB TEST_SUITE_FILES *.ctest.in)
 152 if (TEST_SUITE_FILES)
 153   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
 154
 155     # Avoid to process the official test suite
 156     set(FILE_ALREADY_READ 0)
 157     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
 158     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 159
 160     if(NOT FILE_ALREADY_READ)
 161       # Configure the additional test suite file:
 162       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 163       configure_file("${TEST_SUITE_FILE}"
 164                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 165                      @ONLY)
 166       # Read the additional file into a list
 167       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 168       # Append the list of command
 169       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 170
 171     endif()
 172
 173   endforeach()
 174
 175 else()
 176
 177   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 178
 179 endif()
 180
 181
 182 set(nonregression_filenames_used)
 183 # Parse the command line found in the file(s)
 184 set(IT_TEST_ENC 0)
 185 set(IT_TEST_DEC 0)
 186 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 187
 188   set(IGNORE_LINE_FOUND 0)
 189
 190   # Replace space by ; to generate a list
 191   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 192
 193   # Check if the first argument begin by the comment sign
 194   list(GET CMD_ARG_LIST 0 EXE_NAME)
 195
 196   if(EXE_NAME)
 197     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 198   endif()
 199
 200   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 201
 202     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 203
 204   else()
 205
 206     # Check if the first argument begin by the failed sign
 207     set(FAILED_TEST_FOUND 0)
 208     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 209
 210     if (FAILED_TEST_FOUND)
 211       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 212       set(FAILED_TEST_FOUND_1 0)
 213       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 214
 215       if (FAILED_TEST_FOUND_1)
 216
 217         list(REMOVE_AT CMD_ARG_LIST 0)
 218
 219       else ()
 220
 221         set(FAILED_TEST_FOUND_2 0)
 222         list(GET CMD_ARG_LIST 1 EXE_NAME)
 223         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 224
 225         if (FAILED_TEST_FOUND_2)
 226
 227           list(REMOVE_AT CMD_ARG_LIST 0)
 228           list(REMOVE_AT CMD_ARG_LIST 0)
 229
 230         else ()
 231
 232           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 233
 234         endif ()
 235       endif ()
 236
 237     else ()
 238       # Check if the first argument is equal to opj_compress
 239       string(REGEX MATCH "^opj_compress$|^opj_compress_no_raw$|^opj_compress_no_raw_lossless$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 240
 241       if(EXE_NAME_FOUND)
 242
 243         string(REGEX MATCH "^opj_compress$|^opj_compress_no_raw$|^opj_compress_no_raw_lossless$" ENC_TEST_FOUND ${EXE_NAME})
 244         string(REGEX MATCH "^opj_compress_no_raw$|^opj_compress_no_raw_lossless$" NO_RAW ${EXE_NAME})
 245         string(REGEX MATCH "opj_compress_no_raw_lossless" LOSSLESS ${EXE_NAME})
 246
 247       else()
 248
 249         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 250
 251       endif()
 252
 253       list(REMOVE_AT CMD_ARG_LIST 0)
 254
 255       if(ENC_TEST_FOUND)
 256
 257         # Parse lines like opj_compress lossy-check { -n 3 -m 0:0:0 -p 0:0:0 } ...
 258         set(LOSSY_CHECK_ARG_LIST "")
 259         list(GET CMD_ARG_LIST 0 NEXT_ARG)
 260         string(REGEX MATCH "^lossy-check$" LOSSY_CHECK ${NEXT_ARG})
 261         if(LOSSY_CHECK)
 262             list(REMOVE_AT CMD_ARG_LIST 0)
 263             list(GET CMD_ARG_LIST 0 NEXT_ARG)
 264             string(REGEX MATCH "^{$" FOUND_OPEN_CURL ${NEXT_ARG})
 265             if(NOT FOUND_OPEN_CURL)
 266                 message( FATAL_ERROR "'{' expected after lossy-check")
 267             endif()
 268             list(REMOVE_AT CMD_ARG_LIST 0)
 269             while(TRUE)
 270                 list(GET CMD_ARG_LIST 0 NEXT_ARG)
 271                 list(REMOVE_AT CMD_ARG_LIST 0)
 272                 string(REGEX MATCH "^}$" FOUND_CLOSE_CURL ${NEXT_ARG})
 273                 if(FOUND_CLOSE_CURL)
 274                     break()
 275                 endif()
 276                 list (APPEND LOSSY_CHECK_ARG_LIST ${NEXT_ARG})
 277             endwhile()
 278         endif()
 279       endif()
 280
 281     endif ()
 282
 283     # Parse the argument list to find the input filename and output filename
 284     set(CMD_ARG_LIST_2 "")
 285     set(ARG_POS 0)
 286     set(INPUT_ARG_POS 0)
 287     set(OUTPUT_ARG_POS 0)
 288
 289     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 290
 291       math(EXPR ARG_POS "${ARG_POS}+1" )
 292
 293       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 294       if(INPUT_ARG_FOUND)
 295         set(INPUT_ARG_POS ${ARG_POS})
 296         set(INPUT_ARG_FOUND 0)
 297       endif()
 298
 299       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 300       if(OUTPUT_ARG_FOUND)
 301         set(OUTPUT_ARG_POS ${ARG_POS})
 302         set(OUTPUT_ARG_FOUND 0)
 303       endif()
 304
 305       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 306
 307     endforeach()
 308
 309     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 310     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 311     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 312     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 313     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 314
 315     #-----
 316     # Now we can add the test suite corresponding to a line command in the file
 317     #-----
 318     # ENCODER TEST SUITE
 319     if(ENC_TEST_FOUND)
 320         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 321
 322         # Encode an image into the jpeg2000 format
 323         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 324           COMMAND opj_compress
 325           ${CMD_ARG_LIST_2}
 326         )
 327
 328         if(FAILED_TEST_FOUND)
 329             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 330         else()
 331
 332           # Dump the encoding file
 333           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 334             COMMAND opj_dump
 335             -i ${OUTPUT_FILENAME}
 336             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 337           )
 338           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 339                                PROPERTIES DEPENDS
 340                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 341
 342           # Compare the dump file with the baseline
 343           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 344             COMMAND compare_dump_files
 345             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 346             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 347           )
 348
 349           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 350                                PROPERTIES DEPENDS
 351                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 352
 353           if(LOSSY_CHECK)
 354             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 355             COMMAND opj_decompress
 356             -i ${OUTPUT_FILENAME}
 357             -o ${OUTPUT_FILENAME}.tif
 358             )
 359
 360             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 361                                 PROPERTIES DEPENDS
 362                                 NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 363
 364             # Compare the decoding file with original one, using tolerance
 365             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 366             COMMAND compare_images
 367             -b ${INPUT_FILENAME}
 368             -t ${OUTPUT_FILENAME}.tif
 369             -s bXtY
 370             ${LOSSY_CHECK_ARG_LIST}
 371             )
 372
 373             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 374                                 PROPERTIES DEPENDS
 375                                 NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 376
 377           # Decode the encoding file with kakadu expand command
 378           elseif (KDU_EXPAND_EXECUTABLE)
 379             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 380               COMMAND ${KDU_EXPAND_EXECUTABLE}
 381               -i ${OUTPUT_FILENAME}
 382               -o ${OUTPUT_FILENAME}.raw
 383               )
 384
 385             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 386                                  PROPERTIES DEPENDS
 387                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 388
 389             if(NOT NO_RAW)
 390                 # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 391                 add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 392                 COMMAND compare_raw_files
 393                 -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 394                 -t ${OUTPUT_FILENAME}.raw
 395                 )
 396
 397                 set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 398                                     PROPERTIES DEPENDS
 399                                     NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 400             endif()
 401           endif()
 402
 403           # Test the encoded file is a valid JP2 file
 404           if (JPYLYZER_EXECUTABLE)
 405             if (${OUTPUT_FILENAME} MATCHES "\\.jp2$")
 406               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser
 407                 COMMAND ${JPYLYZER_EXECUTABLE}
 408                 ${OUTPUT_FILENAME}
 409                 )
 410               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser PROPERTIES
 411                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 412                 PASS_REGULAR_EXPRESSION "<isValidJP2>True</isValidJP2>"
 413                 )
 414             endif()
 415           endif(JPYLYZER_EXECUTABLE)
 416
 417           # If lossless compression (simple test is 4 arguments), decompress & compare
 418           list(LENGTH CMD_ARG_LIST_2 ARG_COUNT)
 419           if ((ARG_COUNT EQUAL 4) OR LOSSLESS)
 420             # can we compare with the input image ?
 421             if (${INPUT_FILENAME_NAME} MATCHES "\\.tif$")
 422               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 423                 COMMAND opj_decompress -i ${OUTPUT_FILENAME} -o ${OUTPUT_FILENAME}.lossless.tif
 424                 )
 425               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode PROPERTIES
 426                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 427                 )
 428               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare
 429                 COMMAND compare_images -b ${INPUT_FILENAME} -t ${OUTPUT_FILENAME}.lossless.tif -n 1 -d
 430                 )
 431               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare PROPERTIES
 432                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 433                 )
 434             endif()
 435           endif()
 436       endif()
 437
 438     # DECODER TEST SUITE
 439     else()
 440       string(FIND ${INPUT_FILENAME} "nonregression" nr_pos)
 441       if(${nr_pos} GREATER 0)
 442         list(APPEND nonregression_filenames_used ${INPUT_FILENAME_NAME})
 443       endif()
 444       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 445
 446       # Decode the input image
 447       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 448         COMMAND opj_decompress
 449         ${CMD_ARG_LIST_2}
 450       )
 451
 452       if(FAILED_TEST_FOUND)
 453
 454         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 455
 456       else()
 457         # if not failed, check against registered md5:
 458         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 459           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 460           -DOUTFILENAME:STRING=${OUTPUT_FILENAME}
 461           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 462
 463         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5
 464           PROPERTIES DEPENDS NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 465         )
 466
 467 # FIXME: add a compare2base function base on raw which
 468 # can output png diff files if necessary
 469 #  add_test(NR-${filename}-compare2base
 470 #      ${EXECUTABLE_OUTPUT_PATH}/compare_images
 471 #     -b ${BASELINE_NR}/opj_${filenameRef}
 472 #     -t ${TEMP}/${filename}.pgx
 473 #     -n ${nbComponents}
 474 #     -d
 475 #     -s b_t_
 476 #     )
 477 #
 478 #  set_tests_properties(NR-${filename}-compare2base
 479 #                       PROPERTIES DEPENDS
 480 #                       NR-${filename}-decode)
 481
 482       endif()
 483
 484     endif()
 485
 486   endif()
 487
 488 endforeach()
 489
 490 set(existing_filenames)
 491 foreach(f ${OPJ_DATA_NR_LIST})
 492   get_filename_component(ff ${f} NAME)
 493   list(APPEND existing_filenames ${ff})
 494 endforeach()
 495 if(existing_filenames)
 496 list(REMOVE_ITEM existing_filenames ${nonregression_filenames_used})
 497 endif()
 498
 499 # keep track of new addition:
 500 # if we reach here, then a J2K files was added but no test is present in
 501 # test_suite.ctest.in:
 502 foreach(found_but_no_test ${existing_filenames})
 503   add_test(NAME Found-But-No-Test-${found_but_no_test} COMMAND ${CMAKE_COMMAND} -E echo "${found_but_no_test}")
 504   set_tests_properties(Found-But-No-Test-${found_but_no_test} PROPERTIES WILL_FAIL TRUE)
 505 endforeach()