tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 FILE(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   4
   5 SET(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6 SET(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   7 SET(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
   8
   9
  10 SET(INPUT_NR_PATH ${INPUT_NR})
  11 SET(TEMP_PATH ${TEMP})
  12 SET(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  13
  14 # FIXME: should be corectly manage with a find kakadu
  15 IF (NOT WIN32)
  16 CONFIGURE_FILE("opj_ref_decode_cmd.sh.in"
  17                "${CMAKE_CURRENT_BINARY_DIR}/opj_ref_decode_cmd.sh"
  18                @ONLY)
  19 ENDIF (NOT WIN32)
  20
  21 IF (NOT REF_DECODER_BIN_PATH)
  22   MESSAGE(STATUS "REF_DECODER_BIN_PATH not set, if you want all the encoding tests suite provide the path to kdu_expand")
  23 ENDIF (NOT REF_DECODER_BIN_PATH)
  24
  25
  26
  27
  28 #########################################################################
  29 # GENERATION OF THE TEST SUITE (DUMP)
  30 # Dump all files with the selected extension inside the input directory
  31
  32 # Define a list of file which should be gracefully rejected:
  33 SET(BLACKLIST_JPEG2000
  34     empty
  35    )
  36
  37 FILE(GLOB_RECURSE OPJ_DATA_NR_LIST
  38      "${INPUT_NR}/*.j2k"
  39      "${INPUT_NR}/*.j2c"
  40      "${INPUT_NR}/*.jp2"
  41      #"${INPUT_NR}/*.jpx"
  42      )
  43
  44 FOREACH(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  45   GET_FILENAME_COMPONENT(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  46   GET_FILENAME_COMPONENT(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  47   STRING(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
  48
  49   # Dump the input image
  50   ADD_TEST(NR-${INPUT_FILENAME_NAME}-dump
  51            ${EXECUTABLE_OUTPUT_PATH}/j2k_dump
  52                -i ${INPUT_FILENAME}
  53                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
  54                -v
  55                )
  56
  57   IF(bad_jpeg2000)
  58     SET_TESTS_PROPERTIES(NR-${INPUT_FILENAME_NAME}-dump
  59                          PROPERTIES WILL_FAIL TRUE)
  60
  61   ELSE(bad_jpeg2000)
  62
  63     # Compare the dump output with the baseline
  64     ADD_TEST(NR-${INPUT_FILENAME_NAME}-compare_dump2base
  65                 ${EXECUTABLE_OUTPUT_PATH}/compare_dump_files
  66             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
  67             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
  68             )
  69
  70     SET_TESTS_PROPERTIES(NR-${INPUT_FILENAME_NAME}-compare_dump2base
  71                          PROPERTIES DEPENDS
  72                          NR-${INPUT_FILENAME_NAME}-dump)
  73   ENDIF(bad_jpeg2000)
  74
  75 ENDFOREACH(INPUT_FILENAME)
  76
  77
  78 #########################################################################
  79 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
  80 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
  81 # to know which files processed and with which options.
  82
  83 # Configure the test suite file:
  84 CONFIGURE_FILE("test_suite.ctest.in"
  85                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
  86                @ONLY)
  87
  88 # Read the file into a list
  89 FILE(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
  90
  91 # Try to find and configure and read another test suite file
  92 FILE(GLOB TEST_SUITE_FILES *.ctest.in)
  93 IF (TEST_SUITE_FILES)
  94   FOREACH(TEST_SUITE_FILE ${TEST_SUITE_FILES})
  95
  96     # Avoid to process the official test suite
  97     SET(FILE_ALREADY_READ 0)
  98     STRING(REGEX MATCH "test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILE})
  99
 100     IF(NOT FILE_ALREADY_READ)
 101       # Configure the additional test suite file:
 102       GET_FILENAME_COMPONENT(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 103       CONFIGURE_FILE("${TEST_SUITE_FILE}"
 104                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 105                      @ONLY)
 106       # Read the additional file into a list
 107       FILE(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 108       # Append the list of command
 109       SET(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 110
 111     ENDIF(NOT FILE_ALREADY_READ)
 112
 113   ENDFOREACH(TEST_SUITE_FILE)
 114
 115 ELSE(TEST_SUITE_FILES)
 116
 117   MESSAGE(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 118
 119 ENDIF(TEST_SUITE_FILES)
 120
 121
 122 # Parse the command line found in the file(s)
 123 SET(IT_TEST_ENC 0)
 124 SET(IT_TEST_DEC 0)
 125 FOREACH(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 126
 127   SET(IGNORE_LINE_FOUND 0)
 128
 129   # Replace space by ; to generate a list
 130   STRING(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 131
 132   # Check if the first argument begin by the comment sign
 133   LIST(GET CMD_ARG_LIST 0 EXE_NAME)
 134
 135   IF(EXE_NAME)
 136     STRING(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 137   ENDIF(EXE_NAME)
 138
 139   IF(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 140
 141     #MESSAGE( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 142
 143   ELSE(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 144
 145     # Check if the first argument begin by the failed sign
 146     SET(FAILED_TEST_FOUND 0)
 147     STRING(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 148
 149     IF (FAILED_TEST_FOUND)
 150       # Manage the different cases with the failed sign to remove the first argument which must be image_to_j2k
 151       SET(FAILED_TEST_FOUND_1 0)
 152       STRING(REGEX MATCH "^!image_to_j2k$|^!j2k_to_image$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 153
 154       IF (FAILED_TEST_FOUND_1)
 155
 156         LIST(REMOVE_AT CMD_ARG_LIST 0)
 157
 158       ELSE (FAILED_TEST_FOUND_1)
 159
 160         SET(FAILED_TEST_FOUND_2 0)
 161         LIST(GET CMD_ARG_LIST 1 EXE_NAME)
 162         STRING(REGEX MATCH "^image_to_j2k$|^j2k_to_image$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 163
 164         IF (FAILED_TEST_FOUND_2)
 165
 166           LIST(REMOVE_AT CMD_ARG_LIST 0)
 167           LIST(REMOVE_AT CMD_ARG_LIST 0)
 168
 169         ELSE (FAILED_TEST_FOUND_2)
 170
 171           MESSAGE( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use image_to_j2k or j2k_to_image)")
 172
 173         ENDIF (FAILED_TEST_FOUND_2)
 174       ENDIF (FAILED_TEST_FOUND_1)
 175
 176     ELSE (FAILED_TEST_FOUND)
 177       # Check if the first argument is equal to image_to_j2k
 178       STRING(REGEX MATCH "^image_to_j2k$|^j2k_to_image$" EXE_NAME_FOUND ${EXE_NAME})
 179
 180       IF(EXE_NAME_FOUND)
 181
 182         STRING(REGEX MATCH "image_to_j2k" ENC_TEST_FOUND ${EXE_NAME})
 183
 184       ELSE(EXE_NAME_FOUND)
 185
 186         MESSAGE( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use image_to_j2k)")
 187
 188       ENDIF(EXE_NAME_FOUND)
 189
 190       LIST(REMOVE_AT CMD_ARG_LIST 0)
 191
 192     ENDIF (FAILED_TEST_FOUND)
 193
 194     # Parse the argument list to find the input filename and output filename
 195     SET(CMD_ARG_LIST_2 "")
 196     SET(ARG_POS 0)
 197     SET(INPUT_ARG_POS 0)
 198     SET(OUTPUT_ARG_POS 0)
 199
 200     FOREACH(CMD_ARG_ELT ${CMD_ARG_LIST})
 201
 202       math(EXPR ARG_POS "${ARG_POS}+1" )
 203
 204       STRING(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 205       IF(INPUT_ARG_FOUND)
 206         SET(INPUT_ARG_POS ${ARG_POS})
 207         SET(INPUT_ARG_FOUND 0)
 208       ENDIF(INPUT_ARG_FOUND)
 209
 210       STRING(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 211       IF(OUTPUT_ARG_FOUND)
 212         SET(OUTPUT_ARG_POS ${ARG_POS})
 213         SET(OUTPUT_ARG_FOUND 0)
 214       ENDIF(OUTPUT_ARG_FOUND)
 215
 216       LIST (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 217
 218     ENDFOREACH(CMD_ARG_ELT)
 219
 220     LIST(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 221     GET_FILENAME_COMPONENT(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 222     GET_FILENAME_COMPONENT(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 223     LIST(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 224     GET_FILENAME_COMPONENT(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 225
 226     #-----
 227     # Now we can add the test suite corresponding to a line command in the file
 228     #-----
 229
 230     # ENCODER TEST SUITE
 231     IF(ENC_TEST_FOUND)
 232         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 233
 234         # Encode an image into the jpeg2000 format
 235         ADD_TEST(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 236           ${EXECUTABLE_OUTPUT_PATH}/image_to_j2k
 237           ${CMD_ARG_LIST_2}
 238         )
 239
 240         IF(FAILED_TEST_FOUND)
 241             SET_TESTS_PROPERTIES(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 242         ELSE(FAILED_TEST_FOUND)
 243
 244           # Dump the encoding file
 245           ADD_TEST(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 246             ${EXECUTABLE_OUTPUT_PATH}/j2k_dump
 247             -i ${OUTPUT_FILENAME}
 248             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 249           )
 250           SET_TESTS_PROPERTIES(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 251                                PROPERTIES DEPENDS
 252                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 253
 254           # Compare the dump file with the baseline
 255           ADD_TEST(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 256             ${EXECUTABLE_OUTPUT_PATH}/compare_dump_files
 257             -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 258             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 259           )
 260
 261           SET_TESTS_PROPERTIES(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 262                                PROPERTIES DEPENDS
 263                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 264
 265           # Decode the encoding file with kakadu expand command
 266           IF (NOT REF_DECODER_NOTFOUND)
 267             IF (NOT WIN32)
 268               # Need a bash script to export the path of the kakadu library into PATH
 269               ADD_TEST( NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 270                 bash ${CMAKE_CURRENT_BINARY_DIR}/opj_ref_decode_cmd.sh
 271                 -i ${OUTPUT_FILENAME}
 272                 -o ${OUTPUT_FILENAME}.raw
 273               )
 274             ELSE (NOT WIN32)
 275               ADD_TEST(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 276                 ${REF_DECODER_BIN_PATH}/kdu_expand
 277                 -i ${OUTPUT_FILENAME}
 278                 -o ${OUTPUT_FILENAME}.raw
 279               )
 280             ENDIF (NOT WIN32)
 281
 282             SET_TESTS_PROPERTIES(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 283                                  PROPERTIES DEPENDS
 284                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 285
 286             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 287             ADD_TEST(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 288               ${EXECUTABLE_OUTPUT_PATH}/compareRAWimages
 289               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 290               -t ${OUTPUT_FILENAME}.raw
 291             )
 292
 293             SET_TESTS_PROPERTIES(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 294                                  PROPERTIES DEPENDS
 295                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 296
 297           ENDIF(NOT REF_DECODER_NOTFOUND)
 298       ENDIF(FAILED_TEST_FOUND)
 299
 300     # DECODER TEST SUITE
 301     ELSE(ENC_TEST_FOUND)
 302       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 303
 304       # Decode the input image
 305       ADD_TEST(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 306         ${EXECUTABLE_OUTPUT_PATH}/j2k_to_image
 307         ${CMD_ARG_LIST_2}
 308       )
 309
 310       IF(FAILED_TEST_FOUND)
 311
 312         SET_TESTS_PROPERTIES(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 313
 314       ELSE(FAILED_TEST_FOUND)
 315
 316 # FIXME: add a compare2base function base on raw which
 317 # can output png diff files if necesary
 318 #  ADD_TEST(NR-${filename}-compare2base
 319 #      ${EXECUTABLE_OUTPUT_PATH}/comparePGXimages
 320 #     -b ${BASELINE_NR}/opj_${filenameRef}
 321 #     -t ${TEMP}/${filename}.pgx
 322 #     -n ${nbComponents}
 323 #     -d
 324 #     -s b_t_
 325 #     )
 326 #
 327 #  SET_TESTS_PROPERTIES(NR-${filename}-compare2base
 328 #                       PROPERTIES DEPENDS
 329 #                       NR-${filename}-decode)
 330
 331       ENDIF(FAILED_TEST_FOUND)
 332
 333     ENDIF(ENC_TEST_FOUND)
 334
 335   ENDIF(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 336
 337 ENDFOREACH(OPJ_TEST_CMD_LINE)
 338