tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 cmake_minimum_required(VERSION 2.8.7)
   4
   5 file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6
   7 set(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   8 set(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   9 set(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
  10
  11
  12 set(INPUT_NR_PATH ${INPUT_NR})
  13 set(TEMP_PATH ${TEMP})
  14 set(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  15
  16 # need kdu_expand if possible
  17 find_package(KAKADU)
  18 # need jpylyzer if possible
  19 find_package(JPYLYZER)
  20
  21 #########################################################################
  22 # GENERATION OF THE TEST SUITE (DUMP)
  23 # Dump all files with the selected extension inside the input directory
  24
  25 # technically opj_dump should simply parse these one, since syntax is ok.
  26 set(BLACKLIST_JPEG2000_TMP
  27     2539.pdf.SIGFPE.706.1712.jp2
  28     0290cb77c5df21828fa74cf2ab2c84d8.SIGFPE.d25.31.jp2
  29     26ccf3651020967f7778238ef5af08af.SIGFPE.d25.527.jp2
  30     4035.pdf.SIGSEGV.d8b.3375.jp2
  31     3635.pdf.asan.77.2930.jp2
  32     issue165.jp2
  33     #edf_c2_1103421.jp2
  34     edf_c2_1178956.jp2
  35     edf_c2_1000290.jp2
  36     #edf_c2_1000691.jp2 # ok
  37     #edf_c2_20.jp2 #looks ok as per kdu_jp2info
  38     edf_c2_1377017.jp2
  39     edf_c2_1002767.jp2
  40     #edf_c2_10025.jp2
  41     edf_c2_1000234.jp2
  42     edf_c2_225881.jp2
  43     edf_c2_1000671.jp2
  44     #edf_c2_1013627.jp2 # weird box, but kdu_jp2info ok
  45     edf_c2_1015644.jp2
  46     edf_c2_101463.jp2
  47     edf_c2_1674177.jp2
  48     edf_c2_1673169.jp2
  49     issue429.jp2
  50     issue427-null-image-size.jp2
  51     issue427-illegal-tile-offset.jp2
  52    )
  53
  54 # Define a list of file which should be gracefully rejected:
  55 set(BLACKLIST_JPEG2000
  56     ${BLACKLIST_JPEG2000_TMP}
  57     broken1.jp2
  58     broken2.jp2
  59     broken3.jp2
  60     broken4.jp2
  61     gdal_fuzzer_assert_in_opj_j2k_read_SQcd_SQcc.patch.jp2
  62     gdal_fuzzer_check_comp_dx_dy.jp2
  63     gdal_fuzzer_check_number_of_tiles.jp2
  64     gdal_fuzzer_unchecked_numresolutions.jp2
  65     mem-b2ace68c-1381.jp2
  66     1851.pdf.SIGSEGV.ce9.948.jp2
  67     1888.pdf.asan.35.988.jp2
  68     issue362-2863.jp2 #kdu_jp2info ok
  69     issue362-2866.jp2
  70     issue362-2894.jp2
  71     issue400.jp2 #kdu_jp2info ok
  72     issue364-38.jp2
  73     issue364-903.jp2 #kdu_jp2info ok
  74     issue393.jp2 #kdu_jp2info ok
  75     issue408.jp2 #kdu_jp2info ok
  76     issue420.jp2 #kdu_jp2info ok
  77     27ac957758a35d00d6765a0c86350d9c.SIGFPE.d25.537.jpc #kdu_jp2info crash
  78     3672da2f1f67bbecad27d7181b4e9d7c.SIGFPE.d25.805.jpc #kdu_jp2info crash
  79     issue476.jp2 #kdu_jp2info ok
  80     issue475.jp2 #kdu_jp2info ok
  81     issue413.jp2 #kdu_jp2info ok
  82    )
  83
  84 file(GLOB_RECURSE OPJ_DATA_NR_LIST
  85      "${INPUT_NR}/*.j2k"
  86      "${INPUT_NR}/*.j2c"
  87      "${INPUT_NR}/*.jp2"
  88      "${INPUT_NR}/*.jpc"
  89      #"${INPUT_NR}/*.jpx"
  90      )
  91
  92 foreach(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  93   get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  94   #get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  95   # cannot use longest extension function, since some name contains multiples
  96   # dots. Instead write out own shortest extension function:
  97   string(FIND ${INPUT_FILENAME_NAME} "." SHORTEST_EXT_POS REVERSE)
  98   string(SUBSTRING ${INPUT_FILENAME_NAME} 0 ${SHORTEST_EXT_POS} INPUT_FILENAME_NAME_WE)
  99   string(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
 100
 101   # Dump the input image
 102   add_test(NAME NR-${INPUT_FILENAME_NAME}-dump
 103            COMMAND opj_dump
 104                -i ${INPUT_FILENAME}
 105                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
 106                -v
 107                )
 108
 109   if(bad_jpeg2000)
 110     set_tests_properties(NR-${INPUT_FILENAME_NAME}-dump
 111                          PROPERTIES WILL_FAIL TRUE)
 112
 113   else()
 114
 115     # Compare the dump output with the baseline
 116     add_test(NAME NR-${INPUT_FILENAME_NAME}-compare_dump2base
 117                 COMMAND compare_dump_files
 118             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
 119             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
 120             )
 121
 122     set_tests_properties(NR-${INPUT_FILENAME_NAME}-compare_dump2base
 123                          PROPERTIES DEPENDS
 124                          NR-${INPUT_FILENAME_NAME}-dump)
 125   endif()
 126
 127 endforeach()
 128
 129
 130 #########################################################################
 131 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
 132 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
 133 # to know which files processed and with which options.
 134
 135 # Configure the test suite file:
 136 configure_file("test_suite.ctest.in"
 137                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
 138                @ONLY)
 139
 140 # Read the file into a list
 141 file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
 142
 143 # Try to find and configure and read another test suite file
 144 file(GLOB TEST_SUITE_FILES *.ctest.in)
 145 if (TEST_SUITE_FILES)
 146   foreach(TEST_SUITE_FILE ${TEST_SUITE_FILES})
 147
 148     # Avoid to process the official test suite
 149     set(FILE_ALREADY_READ 0)
 150     get_filename_component(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
 151     string(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 152
 153     if(NOT FILE_ALREADY_READ)
 154       # Configure the additional test suite file:
 155       get_filename_component(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 156       configure_file("${TEST_SUITE_FILE}"
 157                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 158                      @ONLY)
 159       # Read the additional file into a list
 160       file(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 161       # Append the list of command
 162       set(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 163
 164     endif()
 165
 166   endforeach()
 167
 168 else()
 169
 170   message(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 171
 172 endif()
 173
 174
 175 set(nonregression_filenames_used)
 176 # Parse the command line found in the file(s)
 177 set(IT_TEST_ENC 0)
 178 set(IT_TEST_DEC 0)
 179 foreach(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 180
 181   set(IGNORE_LINE_FOUND 0)
 182
 183   # Replace space by ; to generate a list
 184   string(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 185
 186   # Check if the first argument begin by the comment sign
 187   list(GET CMD_ARG_LIST 0 EXE_NAME)
 188
 189   if(EXE_NAME)
 190     string(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 191   endif()
 192
 193   if(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 194
 195     #message( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 196
 197   else()
 198
 199     # Check if the first argument begin by the failed sign
 200     set(FAILED_TEST_FOUND 0)
 201     string(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 202
 203     if (FAILED_TEST_FOUND)
 204       # Manage the different cases with the failed sign to remove the first argument which must be opj_compress
 205       set(FAILED_TEST_FOUND_1 0)
 206       string(REGEX MATCH "^!opj_compress$|^!opj_decompress$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 207
 208       if (FAILED_TEST_FOUND_1)
 209
 210         list(REMOVE_AT CMD_ARG_LIST 0)
 211
 212       else ()
 213
 214         set(FAILED_TEST_FOUND_2 0)
 215         list(GET CMD_ARG_LIST 1 EXE_NAME)
 216         string(REGEX MATCH "^opj_compress$|^opj_decompress$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 217
 218         if (FAILED_TEST_FOUND_2)
 219
 220           list(REMOVE_AT CMD_ARG_LIST 0)
 221           list(REMOVE_AT CMD_ARG_LIST 0)
 222
 223         else ()
 224
 225           message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress or opj_decompress)")
 226
 227         endif ()
 228       endif ()
 229
 230     else ()
 231       # Check if the first argument is equal to opj_compress
 232       string(REGEX MATCH "^opj_compress$|^opj_decompress$" EXE_NAME_FOUND ${EXE_NAME})
 233
 234       if(EXE_NAME_FOUND)
 235
 236         string(REGEX MATCH "opj_compress" ENC_TEST_FOUND ${EXE_NAME})
 237
 238       else()
 239
 240         message( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use opj_compress)")
 241
 242       endif()
 243
 244       list(REMOVE_AT CMD_ARG_LIST 0)
 245
 246     endif ()
 247
 248     # Parse the argument list to find the input filename and output filename
 249     set(CMD_ARG_LIST_2 "")
 250     set(ARG_POS 0)
 251     set(INPUT_ARG_POS 0)
 252     set(OUTPUT_ARG_POS 0)
 253
 254     foreach(CMD_ARG_ELT ${CMD_ARG_LIST})
 255
 256       math(EXPR ARG_POS "${ARG_POS}+1" )
 257
 258       string(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 259       if(INPUT_ARG_FOUND)
 260         set(INPUT_ARG_POS ${ARG_POS})
 261         set(INPUT_ARG_FOUND 0)
 262       endif()
 263
 264       string(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 265       if(OUTPUT_ARG_FOUND)
 266         set(OUTPUT_ARG_POS ${ARG_POS})
 267         set(OUTPUT_ARG_FOUND 0)
 268       endif()
 269
 270       list (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 271
 272     endforeach()
 273
 274     list(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 275     get_filename_component(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 276     get_filename_component(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 277     list(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 278     get_filename_component(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 279
 280     #-----
 281     # Now we can add the test suite corresponding to a line command in the file
 282     #-----
 283     # ENCODER TEST SUITE
 284     if(ENC_TEST_FOUND)
 285         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 286
 287         # Encode an image into the jpeg2000 format
 288         add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 289           COMMAND opj_compress
 290           ${CMD_ARG_LIST_2}
 291         )
 292
 293         if(FAILED_TEST_FOUND)
 294             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 295         else()
 296
 297           # Dump the encoding file
 298           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 299             COMMAND opj_dump
 300             -i ${OUTPUT_FILENAME}
 301             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 302           )
 303           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 304                                PROPERTIES DEPENDS
 305                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 306
 307           # Compare the dump file with the baseline
 308           add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 309             COMMAND compare_dump_files
 310             -b ${BASELINE_NR}/opj_v2_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 311             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 312           )
 313
 314           set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 315                                PROPERTIES DEPENDS
 316                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 317
 318           # Decode the encoding file with kakadu expand command
 319           if (KDU_EXPAND_EXECUTABLE)
 320             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 321               COMMAND ${KDU_EXPAND_EXECUTABLE}
 322               -i ${OUTPUT_FILENAME}
 323               -o ${OUTPUT_FILENAME}.raw
 324               )
 325
 326             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 327                                  PROPERTIES DEPENDS
 328                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 329
 330             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 331             add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 332               COMMAND compare_raw_files
 333               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 334               -t ${OUTPUT_FILENAME}.raw
 335             )
 336
 337             set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 338                                  PROPERTIES DEPENDS
 339                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 340
 341           endif()
 342
 343           # Test the encoded file is a valid JP2 file
 344           if (JPYLYZER_EXECUTABLE)
 345             if (${OUTPUT_FILENAME} MATCHES "\\.jp2$")
 346               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser
 347                 COMMAND ${JPYLYZER_EXECUTABLE}
 348                 ${OUTPUT_FILENAME}
 349                 )
 350               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-jpylyser PROPERTIES
 351                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 352                 PASS_REGULAR_EXPRESSION "<isValidJP2>True</isValidJP2>"
 353                 )
 354             endif()
 355           endif(JPYLYZER_EXECUTABLE)
 356
 357           # If lossless compression (simple test is 4 arguments), decompress & compare
 358           list(LENGTH CMD_ARG_LIST_2 ARG_COUNT)
 359           if (ARG_COUNT EQUAL 4)
 360             # can we compare with the input image ?
 361             if (${INPUT_FILENAME_NAME} MATCHES "\\.tif$")
 362               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 363                 COMMAND opj_decompress -i ${OUTPUT_FILENAME} -o ${OUTPUT_FILENAME}.lossless.tif
 364                 )
 365               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode PROPERTIES
 366                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 367                 )
 368               add_test(NAME NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare
 369                 COMMAND compare_images -b ${INPUT_FILENAME} -t ${OUTPUT_FILENAME}.lossless.tif -n 1 -d
 370                 )
 371               set_tests_properties(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-compare PROPERTIES
 372                 DEPENDS NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-lossless-decode
 373                 )
 374             endif()
 375           endif()
 376       endif()
 377
 378     # DECODER TEST SUITE
 379     else()
 380       string(FIND ${INPUT_FILENAME} "nonregression" nr_pos)
 381       if(${nr_pos} GREATER 0)
 382         list(APPEND nonregression_filenames_used ${INPUT_FILENAME_NAME})
 383       endif()
 384       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 385
 386       # Decode the input image
 387       add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 388         COMMAND opj_decompress
 389         ${CMD_ARG_LIST_2}
 390       )
 391
 392       if(FAILED_TEST_FOUND)
 393
 394         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 395
 396       else()
 397         # if not failed, check against registered md5:
 398         add_test(NAME NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5 COMMAND ${CMAKE_COMMAND}
 399           -DREFFILE:STRING=${CMAKE_CURRENT_SOURCE_DIR}/md5refs.txt
 400           -DOUTFILENAME:STRING=${OUTPUT_FILENAME}
 401           -P ${CMAKE_CURRENT_SOURCE_DIR}/checkmd5refs.cmake)
 402
 403         set_tests_properties(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode-md5
 404           PROPERTIES DEPENDS NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 405         )
 406
 407 # FIXME: add a compare2base function base on raw which
 408 # can output png diff files if necessary
 409 #  add_test(NR-${filename}-compare2base
 410 #      ${EXECUTABLE_OUTPUT_PATH}/compare_images
 411 #     -b ${BASELINE_NR}/opj_${filenameRef}
 412 #     -t ${TEMP}/${filename}.pgx
 413 #     -n ${nbComponents}
 414 #     -d
 415 #     -s b_t_
 416 #     )
 417 #
 418 #  set_tests_properties(NR-${filename}-compare2base
 419 #                       PROPERTIES DEPENDS
 420 #                       NR-${filename}-decode)
 421
 422       endif()
 423
 424     endif()
 425
 426   endif()
 427
 428 endforeach()
 429
 430 set(existing_filenames)
 431 foreach(f ${OPJ_DATA_NR_LIST})
 432   get_filename_component(ff ${f} NAME)
 433   list(APPEND existing_filenames ${ff})
 434 endforeach()
 435 if(existing_filenames)
 436 list(REMOVE_ITEM existing_filenames ${nonregression_filenames_used})
 437 endif()
 438
 439 # keep track of new addition:
 440 # if we reach here, then a J2K files was added but no test is present in
 441 # test_suite.ctest.in:
 442 foreach(found_but_no_test ${existing_filenames})
 443   add_test(NAME Found-But-No-Test-${found_but_no_test} COMMAND ${CMAKE_COMMAND} -E echo "${found_but_no_test}")
 444   set_tests_properties(Found-But-No-Test-${found_but_no_test} PROPERTIES WILL_FAIL TRUE)
 445 endforeach()