tests/nonregression/CMakeLists.txt

   1 # NON-REGRESSION TESTS ON THIS DATASET LOCATED ${OPJ_DATA_ROOT}/input/nonregression
   2
   3 FILE(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   4
   5 SET(TEMP ${CMAKE_CURRENT_BINARY_DIR}/Temporary)
   6 SET(BASELINE_NR ${OPJ_DATA_ROOT}/baseline/nonregression)
   7 SET(INPUT_NR ${OPJ_DATA_ROOT}/input/nonregression)
   8
   9
  10 SET(INPUT_NR_PATH ${INPUT_NR})
  11 SET(TEMP_PATH ${TEMP})
  12 SET(INPUT_CONF_PATH ${OPJ_DATA_ROOT}/input/conformance)
  13
  14 # FIXME: should be corectly manage with a find kakadu
  15 IF (NOT WIN32)
  16 CONFIGURE_FILE("opj_ref_decode_cmd.sh.in"
  17                "${CMAKE_CURRENT_BINARY_DIR}/opj_ref_decode_cmd.sh"
  18                @ONLY)
  19 ENDIF (NOT WIN32)
  20
  21 IF (NOT REF_DECODER_BIN_PATH)
  22   MESSAGE(STATUS "REF_DECODER_BIN_PATH not set, if you want all the encoding tests suite provide the path to kdu_expand")
  23 ENDIF (NOT REF_DECODER_BIN_PATH)
  24
  25
  26
  27
  28 #########################################################################
  29 # GENERATION OF THE TEST SUITE (DUMP)
  30 # Dump all files with the selected extension inside the input directory
  31
  32 # Define a list of file which should be gracefully rejected:
  33 SET(BLACKLIST_JPEG2000
  34     empty
  35    )
  36
  37 FILE(GLOB_RECURSE OPJ_DATA_NR_LIST
  38      "${INPUT_NR}/*.j2k"
  39      "${INPUT_NR}/*.j2c"
  40      "${INPUT_NR}/*.jp2"
  41      #"${INPUT_NR}/*.jpx"
  42      )
  43
  44 FOREACH(INPUT_FILENAME ${OPJ_DATA_NR_LIST})
  45   GET_FILENAME_COMPONENT(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
  46   GET_FILENAME_COMPONENT(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
  47   STRING(REGEX MATCH ${INPUT_FILENAME_NAME} bad_jpeg2000 ${BLACKLIST_JPEG2000})
  48
  49   # Dump the input image
  50   ADD_TEST(NR-${INPUT_FILENAME_NAME}-dump
  51            ${EXECUTABLE_OUTPUT_PATH}/j2k_dump
  52                -i ${INPUT_FILENAME}
  53                -o ${TEMP}/${INPUT_FILENAME_NAME}.txt
  54                -v
  55                )
  56
  57   IF(bad_jpeg2000)
  58     SET_TESTS_PROPERTIES(NR-${INPUT_FILENAME_NAME}-dump
  59                          PROPERTIES WILL_FAIL TRUE)
  60
  61   ELSE(bad_jpeg2000)
  62
  63     # Compare the dump output with the baseline
  64     ADD_TEST(NR-${INPUT_FILENAME_NAME}-compare_dump2base
  65                 ${EXECUTABLE_OUTPUT_PATH}/compare_dump_files
  66             -b ${BASELINE_NR}/opj_v2_${INPUT_FILENAME_NAME_WE}.txt
  67             -t ${TEMP}/${INPUT_FILENAME_NAME}.txt
  68             )
  69
  70     SET_TESTS_PROPERTIES(NR-${INPUT_FILENAME_NAME}-compare_dump2base
  71                          PROPERTIES DEPENDS
  72                          NR-${INPUT_FILENAME_NAME}-dump)
  73   ENDIF(bad_jpeg2000)
  74
  75 ENDFOREACH(INPUT_FILENAME)
  76
  77
  78 #########################################################################
  79 # GENERATION OF THE TEST SUITE (DECODE AND ENCODE)
  80 # Read one and more input file(s) (located in ${OPJ_DATA_ROOT}/input/nonregression)
  81 # to know which files processed and with which options.
  82
  83 # Configure the test suite file:
  84 CONFIGURE_FILE("test_suite.ctest.in"
  85                "${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest"
  86                @ONLY)
  87
  88 # Read the file into a list
  89 FILE(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/test_suite.ctest OPJ_TEST_CMD_LINE_LIST)
  90
  91 # Try to find and configure and read another test suite file
  92 FILE(GLOB TEST_SUITE_FILES *.ctest.in)
  93 IF (TEST_SUITE_FILES)
  94   FOREACH(TEST_SUITE_FILE ${TEST_SUITE_FILES})
  95
  96     # Avoid to process the official test suite
  97     SET(FILE_ALREADY_READ 0)
  98     GET_FILENAME_COMPONENT(TEST_SUITE_FILENAME ${TEST_SUITE_FILE} NAME)
  99     STRING(REGEX MATCH "^test_suite.ctest.in$" FILE_ALREADY_READ ${TEST_SUITE_FILENAME})
 100
 101     IF(NOT FILE_ALREADY_READ)
 102       # Configure the additional test suite file:
 103       GET_FILENAME_COMPONENT(TEST_SUITE_FILE_SUB ${TEST_SUITE_FILE} NAME_WE)
 104       CONFIGURE_FILE("${TEST_SUITE_FILE}"
 105                      "${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest"
 106                      @ONLY)
 107       # Read the additional file into a list
 108       FILE(STRINGS ${CMAKE_CURRENT_BINARY_DIR}/${TEST_SUITE_FILE_SUB}.ctest OPJ_TEST_CMD_LINE_LIST_TEMP)
 109       # Append the list of command
 110       SET(OPJ_TEST_CMD_LINE_LIST ${OPJ_TEST_CMD_LINE_LIST} ${OPJ_TEST_CMD_LINE_LIST_TEMP})
 111
 112     ENDIF(NOT FILE_ALREADY_READ)
 113
 114   ENDFOREACH(TEST_SUITE_FILE)
 115
 116 ELSE(TEST_SUITE_FILES)
 117
 118   MESSAGE(FATAL_ERROR "One test suite should be available (test_suite.ctest.in) !!!")
 119
 120 ENDIF(TEST_SUITE_FILES)
 121
 122
 123 # Parse the command line found in the file(s)
 124 SET(IT_TEST_ENC 0)
 125 SET(IT_TEST_DEC 0)
 126 FOREACH(OPJ_TEST_CMD_LINE ${OPJ_TEST_CMD_LINE_LIST})
 127
 128   SET(IGNORE_LINE_FOUND 0)
 129
 130   # Replace space by ; to generate a list
 131   STRING(REPLACE " " ";" CMD_ARG_LIST ${OPJ_TEST_CMD_LINE})
 132
 133   # Check if the first argument begin by the comment sign
 134   LIST(GET CMD_ARG_LIST 0 EXE_NAME)
 135
 136   IF(EXE_NAME)
 137     STRING(REGEX MATCH "^#" IGNORE_LINE_FOUND ${EXE_NAME})
 138   ENDIF(EXE_NAME)
 139
 140   IF(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 141
 142     #MESSAGE( STATUS "Current line is ignored: ${OPJ_TEST_CMD_LINE}")
 143
 144   ELSE(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 145
 146     # Check if the first argument begin by the failed sign
 147     SET(FAILED_TEST_FOUND 0)
 148     STRING(REGEX MATCH "^!" FAILED_TEST_FOUND ${EXE_NAME})
 149
 150     IF (FAILED_TEST_FOUND)
 151       # Manage the different cases with the failed sign to remove the first argument which must be image_to_j2k
 152       SET(FAILED_TEST_FOUND_1 0)
 153       STRING(REGEX MATCH "^!image_to_j2k$|^!j2k_to_image$" FAILED_TEST_FOUND_1 ${EXE_NAME})
 154
 155       IF (FAILED_TEST_FOUND_1)
 156
 157         LIST(REMOVE_AT CMD_ARG_LIST 0)
 158
 159       ELSE (FAILED_TEST_FOUND_1)
 160
 161         SET(FAILED_TEST_FOUND_2 0)
 162         LIST(GET CMD_ARG_LIST 1 EXE_NAME)
 163         STRING(REGEX MATCH "^image_to_j2k$|^j2k_to_image$" FAILED_TEST_FOUND_2 ${EXE_NAME})
 164
 165         IF (FAILED_TEST_FOUND_2)
 166
 167           LIST(REMOVE_AT CMD_ARG_LIST 0)
 168           LIST(REMOVE_AT CMD_ARG_LIST 0)
 169
 170         ELSE (FAILED_TEST_FOUND_2)
 171
 172           MESSAGE( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use image_to_j2k or j2k_to_image)")
 173
 174         ENDIF (FAILED_TEST_FOUND_2)
 175       ENDIF (FAILED_TEST_FOUND_1)
 176
 177     ELSE (FAILED_TEST_FOUND)
 178       # Check if the first argument is equal to image_to_j2k
 179       STRING(REGEX MATCH "^image_to_j2k$|^j2k_to_image$" EXE_NAME_FOUND ${EXE_NAME})
 180
 181       IF(EXE_NAME_FOUND)
 182
 183         STRING(REGEX MATCH "image_to_j2k" ENC_TEST_FOUND ${EXE_NAME})
 184
 185       ELSE(EXE_NAME_FOUND)
 186
 187         MESSAGE( FATAL_ERROR "${EXE_NAME} is not the right executable name to encode file (try to use image_to_j2k)")
 188
 189       ENDIF(EXE_NAME_FOUND)
 190
 191       LIST(REMOVE_AT CMD_ARG_LIST 0)
 192
 193     ENDIF (FAILED_TEST_FOUND)
 194
 195     # Parse the argument list to find the input filename and output filename
 196     SET(CMD_ARG_LIST_2 "")
 197     SET(ARG_POS 0)
 198     SET(INPUT_ARG_POS 0)
 199     SET(OUTPUT_ARG_POS 0)
 200
 201     FOREACH(CMD_ARG_ELT ${CMD_ARG_LIST})
 202
 203       math(EXPR ARG_POS "${ARG_POS}+1" )
 204
 205       STRING(COMPARE EQUAL ${CMD_ARG_ELT} "-i" INPUT_ARG_FOUND)
 206       IF(INPUT_ARG_FOUND)
 207         SET(INPUT_ARG_POS ${ARG_POS})
 208         SET(INPUT_ARG_FOUND 0)
 209       ENDIF(INPUT_ARG_FOUND)
 210
 211       STRING(COMPARE EQUAL ${CMD_ARG_ELT} "-o" OUTPUT_ARG_FOUND)
 212       IF(OUTPUT_ARG_FOUND)
 213         SET(OUTPUT_ARG_POS ${ARG_POS})
 214         SET(OUTPUT_ARG_FOUND 0)
 215       ENDIF(OUTPUT_ARG_FOUND)
 216
 217       LIST (APPEND CMD_ARG_LIST_2 ${CMD_ARG_ELT})
 218
 219     ENDFOREACH(CMD_ARG_ELT)
 220
 221     LIST(GET CMD_ARG_LIST_2 ${INPUT_ARG_POS} INPUT_FILENAME)
 222     GET_FILENAME_COMPONENT(INPUT_FILENAME_NAME ${INPUT_FILENAME} NAME)
 223     GET_FILENAME_COMPONENT(INPUT_FILENAME_NAME_WE ${INPUT_FILENAME_NAME} NAME_WE)
 224     LIST(GET CMD_ARG_LIST_2 ${OUTPUT_ARG_POS} OUTPUT_FILENAME)
 225     GET_FILENAME_COMPONENT(OUTPUT_FILENAME_NAME_WE ${OUTPUT_FILENAME} NAME_WE)
 226
 227     #-----
 228     # Now we can add the test suite corresponding to a line command in the file
 229     #-----
 230
 231     # ENCODER TEST SUITE
 232     IF(ENC_TEST_FOUND)
 233         math(EXPR IT_TEST_ENC "${IT_TEST_ENC}+1" )
 234
 235         # Encode an image into the jpeg2000 format
 236         ADD_TEST(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode
 237           ${EXECUTABLE_OUTPUT_PATH}/image_to_j2k
 238           ${CMD_ARG_LIST_2}
 239         )
 240
 241         IF(FAILED_TEST_FOUND)
 242             SET_TESTS_PROPERTIES(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode PROPERTIES WILL_FAIL TRUE)
 243         ELSE(FAILED_TEST_FOUND)
 244
 245           # Dump the encoding file
 246           ADD_TEST(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 247             ${EXECUTABLE_OUTPUT_PATH}/j2k_dump
 248             -i ${OUTPUT_FILENAME}
 249             -o ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 250           )
 251           SET_TESTS_PROPERTIES(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump
 252                                PROPERTIES DEPENDS
 253                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 254
 255           # Compare the dump file with the baseline
 256           ADD_TEST(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 257             ${EXECUTABLE_OUTPUT_PATH}/compare_dump_files
 258             -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.txt
 259             -t ${OUTPUT_FILENAME}-ENC-${IT_TEST_ENC}.txt
 260           )
 261
 262           SET_TESTS_PROPERTIES(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dump2base
 263                                PROPERTIES DEPENDS
 264                                NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-dump)
 265
 266           # Decode the encoding file with kakadu expand command
 267           IF (REF_DECODER_BIN_PATH)
 268             IF (NOT WIN32)
 269               # Need a bash script to export the path of the kakadu library into PATH
 270               ADD_TEST( NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 271                 bash ${CMAKE_CURRENT_BINARY_DIR}/opj_ref_decode_cmd.sh
 272                 -i ${OUTPUT_FILENAME}
 273                 -o ${OUTPUT_FILENAME}.raw
 274               )
 275             ELSE (NOT WIN32)
 276               ADD_TEST(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 277                 ${REF_DECODER_BIN_PATH}/kdu_expand
 278                 -i ${OUTPUT_FILENAME}
 279                 -o ${OUTPUT_FILENAME}.raw
 280               )
 281             ENDIF (NOT WIN32)
 282
 283             SET_TESTS_PROPERTIES(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref
 284                                  PROPERTIES DEPENDS
 285                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-encode)
 286
 287             # Compare the decoding file with baseline generated from the kdu_expand and baseline.j2k
 288             ADD_TEST(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 289               ${EXECUTABLE_OUTPUT_PATH}/compareRAWimages
 290               -b ${BASELINE_NR}/opj_${OUTPUT_FILENAME_NAME_WE}-ENC-${IT_TEST_ENC}.raw
 291               -t ${OUTPUT_FILENAME}.raw
 292             )
 293
 294             SET_TESTS_PROPERTIES(NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-compare_dec-ref-out2base
 295                                  PROPERTIES DEPENDS
 296                                  NR-ENC-${INPUT_FILENAME_NAME}-${IT_TEST_ENC}-decode-ref)
 297
 298           ENDIF(REF_DECODER_BIN_PATH)
 299       ENDIF(FAILED_TEST_FOUND)
 300
 301     # DECODER TEST SUITE
 302     ELSE(ENC_TEST_FOUND)
 303       math(EXPR IT_TEST_DEC "${IT_TEST_DEC}+1" )
 304
 305       # Decode the input image
 306       ADD_TEST(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode
 307         ${EXECUTABLE_OUTPUT_PATH}/j2k_to_image
 308         ${CMD_ARG_LIST_2}
 309       )
 310
 311       IF(FAILED_TEST_FOUND)
 312
 313         SET_TESTS_PROPERTIES(NR-DEC-${INPUT_FILENAME_NAME}-${IT_TEST_DEC}-decode PROPERTIES WILL_FAIL TRUE)
 314
 315       ELSE(FAILED_TEST_FOUND)
 316
 317 # FIXME: add a compare2base function base on raw which
 318 # can output png diff files if necesary
 319 #  ADD_TEST(NR-${filename}-compare2base
 320 #      ${EXECUTABLE_OUTPUT_PATH}/comparePGXimages
 321 #     -b ${BASELINE_NR}/opj_${filenameRef}
 322 #     -t ${TEMP}/${filename}.pgx
 323 #     -n ${nbComponents}
 324 #     -d
 325 #     -s b_t_
 326 #     )
 327 #
 328 #  SET_TESTS_PROPERTIES(NR-${filename}-compare2base
 329 #                       PROPERTIES DEPENDS
 330 #                       NR-${filename}-decode)
 331
 332       ENDIF(FAILED_TEST_FOUND)
 333
 334     ENDIF(ENC_TEST_FOUND)
 335
 336   ENDIF(IGNORE_LINE_FOUND OR NOT EXE_NAME)
 337
 338 ENDFOREACH(OPJ_TEST_CMD_LINE)
 339