src/lib/openjp2/CMakeLists.txt

   1 include_regular_expression("^.*$")
   2
   3 #
   4 install( FILES  ${CMAKE_CURRENT_BINARY_DIR}/opj_config.h
   5  DESTINATION ${OPENJPEG_INSTALL_INCLUDE_DIR} COMPONENT Headers)
   6
   7 include_directories(
   8   ${${OPENJPEG_NAMESPACE}_BINARY_DIR}/src/lib/openjp2 # opj_config.h and opj_config_private.h
   9 )
  10 # Defines the source code for the library
  11 set(OPENJPEG_SRCS
  12   ${CMAKE_CURRENT_SOURCE_DIR}/thread.c
  13   ${CMAKE_CURRENT_SOURCE_DIR}/thread.h
  14   ${CMAKE_CURRENT_SOURCE_DIR}/bio.c
  15   ${CMAKE_CURRENT_SOURCE_DIR}/bio.h
  16   ${CMAKE_CURRENT_SOURCE_DIR}/cio.c
  17   ${CMAKE_CURRENT_SOURCE_DIR}/cio.h
  18   ${CMAKE_CURRENT_SOURCE_DIR}/dwt.c
  19   ${CMAKE_CURRENT_SOURCE_DIR}/dwt.h
  20   ${CMAKE_CURRENT_SOURCE_DIR}/event.c
  21   ${CMAKE_CURRENT_SOURCE_DIR}/event.h
  22   ${CMAKE_CURRENT_SOURCE_DIR}/image.c
  23   ${CMAKE_CURRENT_SOURCE_DIR}/image.h
  24   ${CMAKE_CURRENT_SOURCE_DIR}/invert.c
  25   ${CMAKE_CURRENT_SOURCE_DIR}/invert.h
  26   ${CMAKE_CURRENT_SOURCE_DIR}/j2k.c
  27   ${CMAKE_CURRENT_SOURCE_DIR}/j2k.h
  28   ${CMAKE_CURRENT_SOURCE_DIR}/jp2.c
  29   ${CMAKE_CURRENT_SOURCE_DIR}/jp2.h
  30   ${CMAKE_CURRENT_SOURCE_DIR}/mct.c
  31   ${CMAKE_CURRENT_SOURCE_DIR}/mct.h
  32   ${CMAKE_CURRENT_SOURCE_DIR}/mqc.c
  33   ${CMAKE_CURRENT_SOURCE_DIR}/mqc.h
  34   ${CMAKE_CURRENT_SOURCE_DIR}/mqc_inl.h
  35   ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg.c
  36   ${CMAKE_CURRENT_SOURCE_DIR}/openjpeg.h
  37   ${CMAKE_CURRENT_SOURCE_DIR}/opj_clock.c
  38   ${CMAKE_CURRENT_SOURCE_DIR}/opj_clock.h
  39   ${CMAKE_CURRENT_SOURCE_DIR}/pi.c
  40   ${CMAKE_CURRENT_SOURCE_DIR}/pi.h
  41   ${CMAKE_CURRENT_SOURCE_DIR}/t1.c
  42   ${CMAKE_CURRENT_SOURCE_DIR}/t1.h
  43   ${CMAKE_CURRENT_SOURCE_DIR}/t2.c
  44   ${CMAKE_CURRENT_SOURCE_DIR}/t2.h
  45   ${CMAKE_CURRENT_SOURCE_DIR}/tcd.c
  46   ${CMAKE_CURRENT_SOURCE_DIR}/tcd.h
  47   ${CMAKE_CURRENT_SOURCE_DIR}/tgt.c
  48   ${CMAKE_CURRENT_SOURCE_DIR}/tgt.h
  49   ${CMAKE_CURRENT_SOURCE_DIR}/function_list.c
  50   ${CMAKE_CURRENT_SOURCE_DIR}/function_list.h
  51   ${CMAKE_CURRENT_SOURCE_DIR}/opj_codec.h
  52   ${CMAKE_CURRENT_SOURCE_DIR}/opj_includes.h
  53   ${CMAKE_CURRENT_SOURCE_DIR}/opj_intmath.h
  54   ${CMAKE_CURRENT_SOURCE_DIR}/opj_malloc.c
  55   ${CMAKE_CURRENT_SOURCE_DIR}/opj_malloc.h
  56   ${CMAKE_CURRENT_SOURCE_DIR}/opj_stdint.h
  57   ${CMAKE_CURRENT_SOURCE_DIR}/sparse_array.c
  58   ${CMAKE_CURRENT_SOURCE_DIR}/sparse_array.h
  59 )
  60 if(BUILD_JPIP)
  61   add_definitions(-DUSE_JPIP)
  62   set(OPENJPEG_SRCS
  63     ${OPENJPEG_SRCS}
  64     ${CMAKE_CURRENT_SOURCE_DIR}/cidx_manager.c
  65     ${CMAKE_CURRENT_SOURCE_DIR}/cidx_manager.h
  66     ${CMAKE_CURRENT_SOURCE_DIR}/phix_manager.c
  67     ${CMAKE_CURRENT_SOURCE_DIR}/ppix_manager.c
  68     ${CMAKE_CURRENT_SOURCE_DIR}/thix_manager.c
  69     ${CMAKE_CURRENT_SOURCE_DIR}/tpix_manager.c
  70     ${CMAKE_CURRENT_SOURCE_DIR}/indexbox_manager.h
  71   )
  72 endif()
  73
  74 option(OPJ_DISABLE_TPSOT_FIX "Disable TPsot==TNsot fix. See https://github.com/uclouvain/openjpeg/issues/254." OFF)
  75 if(OPJ_DISABLE_TPSOT_FIX)
  76   add_definitions(-DOPJ_DISABLE_TPSOT_FIX)
  77 endif()
  78
  79 # Special case for old i586-mingw32msvc-gcc cross compiler
  80 if(NOT WIN32 AND CMAKE_COMPILER_IS_GNUCC AND CMAKE_C_COMPILER MATCHES ".*mingw32msvc.*" )
  81   set(WIN32 YES)
  82 endif()
  83
  84 # Build the library
  85 if(WIN32)
  86   if(BUILD_SHARED_LIBS)
  87     add_definitions(-DOPJ_EXPORTS)
  88   else()
  89     add_definitions(-DOPJ_STATIC)
  90   endif()
  91   add_library(${OPENJPEG_LIBRARY_NAME} ${OPENJPEG_SRCS})
  92   set(INSTALL_LIBS ${OPENJPEG_LIBRARY_NAME})
  93 else()
  94   # Builds both static and dynamic libs
  95   add_library(${OPENJPEG_LIBRARY_NAME} SHARED ${OPENJPEG_SRCS})
  96   add_library(openjp2_static STATIC ${OPENJPEG_SRCS})
  97   set_target_properties(openjp2_static PROPERTIES OUTPUT_NAME ${OPENJPEG_LIBRARY_NAME})
  98   set(INSTALL_LIBS ${OPENJPEG_LIBRARY_NAME} openjp2_static)
  99 endif()
 100
 101 if(UNIX)
 102   target_link_libraries(${OPENJPEG_LIBRARY_NAME} m)
 103 endif()
 104 set_target_properties(${OPENJPEG_LIBRARY_NAME} PROPERTIES ${OPENJPEG_LIBRARY_PROPERTIES})
 105 if(${CMAKE_VERSION} VERSION_GREATER "2.8.11")
 106   target_compile_options(${OPENJPEG_LIBRARY_NAME} PRIVATE ${OPENJP2_COMPILE_OPTIONS})
 107 endif()
 108
 109 # Install library
 110 install(TARGETS ${INSTALL_LIBS}
 111   EXPORT OpenJPEGTargets
 112   RUNTIME DESTINATION ${OPENJPEG_INSTALL_BIN_DIR} COMPONENT Applications
 113   LIBRARY DESTINATION ${OPENJPEG_INSTALL_LIB_DIR} COMPONENT Libraries
 114   ARCHIVE DESTINATION ${OPENJPEG_INSTALL_LIB_DIR} COMPONENT Libraries
 115 )
 116
 117 # Install includes files
 118 install(FILES openjpeg.h opj_stdint.h
 119   DESTINATION ${OPENJPEG_INSTALL_INCLUDE_DIR} COMPONENT Headers
 120 )
 121
 122 if(BUILD_DOC)
 123 # install man page of the library
 124 install(
 125   FILES       ${OPENJPEG_SOURCE_DIR}/doc/man/man3/libopenjp2.3
 126   DESTINATION ${OPENJPEG_INSTALL_MAN_DIR}/man3)
 127 endif()
 128
 129 if(BUILD_LUTS_GENERATOR)
 130 # internal utility to generate t1_luts.h (part of the jp2 lib)
 131 # no need to install:
 132   add_executable(t1_generate_luts t1_generate_luts.c)
 133   if(UNIX)
 134     target_link_libraries(t1_generate_luts m)
 135   endif()
 136 endif()
 137
 138 # Experimental option; let's how cppcheck performs
 139 # Implementation details:
 140 # I could not figure out how to easily upload a file to CDash. Instead simply
 141 # pretend cppcheck is part of the Build step. Technically cppcheck can even
 142 # output gcc formatted error/warning report
 143 # Another implementation detail: I could not redirect error to the error
 144 # catching mechanism something is busted in cmake 2.8.5, I had to use the
 145 # warning regex to catch them.
 146 if(OPENJPEG_CPPCHECK)
 147   find_package(CPPCHECK REQUIRED)
 148   foreach(f ${OPENJPEG_SRCS})
 149     # cppcheck complains about too many configuration, pretend to be WIN32:
 150     add_custom_command(TARGET ${OPENJPEG_LIBRARY_NAME}
 151       COMMAND ${CPPCHECK_EXECUTABLE} -DWIN32 ${f})
 152   endforeach()
 153 endif()
 154
 155 if(OPJ_USE_DSYMUTIL)
 156   if(BUILD_SHARED_LIBS)
 157     add_custom_command(TARGET ${OPENJPEG_LIBRARY_NAME} POST_BUILD
 158     COMMAND "dsymutil" "$<TARGET_SONAME_FILE:${OPENJPEG_LIBRARY_NAME}>"
 159     COMMENT "dsymutil $<TARGET_SONAME_FILE:${OPENJPEG_LIBRARY_NAME}>"
 160     DEPENDS ${OPENJPEG_LIBRARY_NAME})
 161   endif()
 162 endif()
 163
 164 #################################################################################
 165 # threading configuration
 166 #################################################################################
 167 set(CMAKE_THREAD_PREFER_PTHREAD TRUE)
 168
 169 option(OPJ_USE_THREAD "Build with thread/mutex support " ON)
 170 if(NOT OPJ_USE_THREAD)
 171    add_definitions( -DMUTEX_stub)
 172 endif(NOT OPJ_USE_THREAD)
 173
 174 find_package(Threads QUIET)
 175
 176 if(OPJ_USE_THREAD AND WIN32 AND NOT Threads_FOUND )
 177     add_definitions( -DMUTEX_win32)
 178     set(Threads_FOUND YES)
 179 endif()
 180
 181 if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_WIN32_THREADS_INIT )
 182    add_definitions( -DMUTEX_win32)
 183 endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_WIN32_THREADS_INIT )
 184
 185 if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT )
 186    add_definitions( -DMUTEX_pthread)
 187 endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT )
 188
 189 if(OPJ_USE_THREAD AND NOT Threads_FOUND)
 190   message(FATAL_ERROR "No thread library found and thread/mutex support is required by OPJ_USE_THREAD option")
 191 endif(OPJ_USE_THREAD AND NOT Threads_FOUND)
 192
 193 if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 194    TARGET_LINK_LIBRARIES(${OPENJPEG_LIBRARY_NAME} ${CMAKE_THREAD_LIBS_INIT})
 195 endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 196
 197 if(BUILD_UNIT_TESTS)
 198     add_executable(bench_dwt bench_dwt.c)
 199     if(UNIX)
 200         target_link_libraries(bench_dwt m ${OPENJPEG_LIBRARY_NAME})
 201     endif()
 202     if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 203         target_link_libraries(bench_dwt ${CMAKE_THREAD_LIBS_INIT})
 204     endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 205
 206     add_executable(test_sparse_array test_sparse_array.c)
 207     if(UNIX)
 208         target_link_libraries(test_sparse_array m ${OPENJPEG_LIBRARY_NAME})
 209     endif()
 210     if(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 211         target_link_libraries(test_sparse_array ${CMAKE_THREAD_LIBS_INIT})
 212     endif(OPJ_USE_THREAD AND Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 213 endif(BUILD_UNIT_TESTS)