CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.10)
   2 project(RtAudio)
   3
   4 include(CTest)
   5 include(CheckFunctionExists)
   6
   7 option(BUILD_PYTHON "Build PyRtAudio python bindings" OFF)
   8 option(AUDIO_WINDOWS_DS "Build Windows DirectSound API" OFF)
   9 option(AUDIO_WINDOWS_ASIO "Build Windows ASIO API" OFF)
  10 option(AUDIO_WINDOWS_WASAPI "Build Windows WASAPI API" OFF)
  11 option(AUDIO_LINUX_OSS "Build Linux OSS API" OFF)
  12 option(AUDIO_LINUX_ALSA "Build Linux ALSA API" OFF)
  13 option(AUDIO_LINUX_PULSE "Build Linux PulseAudio API" OFF)
  14 option(AUDIO_UNIX_JACK "Build Unix JACK audio server API" OFF)
  15 option(AUDIO_OSX_CORE "Build Mac OSX CoreAudio API" OFF)
  16
  17 if (CMAKE_BUILD_TYPE STREQUAL "Debug")
  18     add_definitions(-D__RTAUDIO_DEBUG__)
  19 endif ()
  20
  21 check_function_exists(gettimeofday HAVE_GETTIMEOFDAY)
  22
  23 if (HAVE_GETTIMEOFDAY)
  24     add_definitions(-DHAVE_GETTIMEOFDAY)
  25 endif ()
  26
  27 if (CMAKE_COMPILER_IS_GNUCXX)
  28     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall")
  29 endif (CMAKE_COMPILER_IS_GNUCXX)
  30
  31 set(rtaudio_SOURCES RtAudio.cpp)
  32
  33 set(LINKLIBS)
  34 if (CMAKE_SYSTEM_NAME MATCHES "kNetBSD.*|NetBSD.*")
  35     message(STATUS "NetBSD detected, using OSS")
  36     find_package(Threads REQUIRED CMAKE_THREAD_PREFER_PTHREAD)
  37     list(APPEND LINKLIBS ossaudio ${CMAKE_THREAD_LIBS_INIT})
  38     set(AUDIO_LINUX_OSS ON)
  39 elseif (UNIX AND NOT APPLE)
  40     if (NOT AUDIO_LINUX_PULSE AND NOT AUDIO_LINUX_ALSA AND NOT AUDIO_LINUX_OSS AND NOT AUDIO_UNIX_JACK)
  41         set(AUDIO_LINUX_ALSA ON)
  42     endif()
  43
  44     if (AUDIO_LINUX_PULSE)
  45         find_library(PULSE_LIB pulse)
  46         find_library(PULSESIMPLE_LIB pulse-simple)
  47         list(APPEND LINKLIBS ${PULSE_LIB} ${PULSESIMPLE_LIB})
  48         add_definitions(-D__LINUX_PULSE__)
  49         message(STATUS "Using Linux PulseAudio")
  50     endif (AUDIO_LINUX_PULSE)
  51     if (AUDIO_LINUX_ALSA)
  52         find_package(ALSA)
  53         find_package(Threads REQUIRED CMAKE_THREAD_PREFER_PTHREAD)
  54         if (NOT ALSA_FOUND)
  55             message(FATAL_ERROR "ALSA API requested but no ALSA dev libraries found")
  56         endif()
  57         list(APPEND LINKLIBS ${ALSA_LIBRARY} ${CMAKE_THREAD_LIBS_INIT})
  58         add_definitions(-D__LINUX_ALSA__)
  59         message(STATUS "Using Linux ALSA")
  60     endif (AUDIO_LINUX_ALSA)
  61 endif ()
  62
  63 if (APPLE)
  64     if (NOT AUDIO_OSX_CORE AND NOT AUDIO_UNIX_JACK)
  65         set(AUDIO_OSX_CORE ON)
  66     endif()
  67
  68     if (AUDIO_OSX_CORE)
  69         find_library(COREAUDIO_LIB CoreAudio)
  70         find_library(COREFOUNDATION_LIB CoreFoundation)
  71         list(APPEND LINKLIBS ${COREAUDIO_LIB} ${COREFOUNDATION_LIB})
  72         add_definitions(-D__MACOSX_CORE__)
  73         message(STATUS "Using OSX CoreAudio")
  74     endif (AUDIO_OSX_CORE)
  75 endif (APPLE)
  76
  77 # JACK supported on many Unices
  78 if (UNIX)
  79     if (AUDIO_UNIX_JACK)
  80         find_library(JACK_LIB jack)
  81         list(APPEND LINKLIBS ${JACK_LIB})
  82         add_definitions(-D__UNIX_JACK__)
  83         message(STATUS "Using JACK")
  84     endif (AUDIO_UNIX_JACK)
  85 endif (UNIX)
  86
  87 if (WIN32)
  88     if (NOT AUDIO_WINDOWS_DS AND NOT AUDIO_WINDOWS_ASIO AND NOT AUDIO_WINDOWS_WASAPI)
  89         set(AUDIO_WINDOWS_WASAPI ON)
  90     endif()
  91
  92     include_directories(include)
  93     list(APPEND LINKLIBS winmm ole32)
  94
  95     if (AUDIO_WINDOWS_DS)
  96         add_definitions(-D__WINDOWS_DS__)
  97         message(STATUS "Using Windows DirectSound")
  98         list(APPEND LINKLIBS dsound)
  99     endif (AUDIO_WINDOWS_DS)
 100     if (AUDIO_WINDOWS_WASAPI)
 101         add_definitions(-D__WINDOWS_WASAPI__)
 102         message(STATUS "Using Windows WASAPI")
 103         list(APPEND LINKLIBS uuid ksuser)
 104     endif (AUDIO_WINDOWS_WASAPI)
 105     if (AUDIO_WINDOWS_ASIO)
 106         list(APPEND rtaudio_SOURCES
 107             include/asio.cpp
 108             include/asiodrivers.cpp
 109             include/asiolist.cpp
 110             include/iasiothiscallresolver.cpp)
 111         add_definitions(-D__WINDOWS_ASIO__)
 112         message(STATUS "Using Windows ASIO")
 113     endif (AUDIO_WINDOWS_ASIO)
 114 endif (WIN32)
 115
 116 add_library(rtaudio SHARED ${rtaudio_SOURCES})
 117 add_library(rtaudio_static STATIC ${rtaudio_SOURCES})
 118
 119 target_link_libraries(rtaudio ${LINKLIBS})
 120
 121 if (BUILD_TESTING)
 122     add_subdirectory(tests)
 123 endif (BUILD_TESTING)
 124