configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(RtAudio, 5.0.0, gary@music.mcgill.ca, rtaudio)
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_SRCDIR(RtAudio.cpp)
   5 AC_CONFIG_FILES([rtaudio.pc Makefile tests/Makefile doc/Makefile doc/doxygen/Doxyfile])
   6 AM_INIT_AUTOMAKE([1.14 -Wall -Werror foreign subdir-objects])
   7
   8 # libtool version: current:revision:age
   9 #
  10 # If the library source code has changed at all since the last update, then
  11 # increment revision (`c:r:a' becomes `c:r+1:a').
  12 #
  13 # If any interfaces have been added, removed, or changed since the last update,
  14 # increment current, and set revision to 0.
  15 #
  16 # If any interfaces have been added since the last public release, then
  17 # increment age.
  18 #
  19 # If any interfaces have been removed since the last public release, then set
  20 # age to 0.
  21 m4_define([lt_current], 6)
  22 m4_define([lt_revision], 0)
  23 m4_define([lt_age], 0)
  24
  25 m4_define([lt_version_info], [lt_current:lt_revision:lt_age])
  26 m4_define([lt_current_minus_age], [m4_eval(lt_current - lt_age)])
  27
  28 SO_VERSION=lt_version_info
  29 AC_SUBST(SO_VERSION)
  30 AC_SUBST(api)
  31 AC_SUBST(req)
  32 AC_SUBST(visibility)
  33
  34 api=""
  35 req=""
  36 use_asio=""
  37
  38
  39 # configure flags
  40 AC_ARG_ENABLE(debug, [AS_HELP_STRING([--enable-debug],[enable various debug output])])
  41 AC_ARG_WITH(jack, [AS_HELP_STRING([--with-jack], [choose JACK server support])])
  42 AC_ARG_WITH(alsa, [AS_HELP_STRING([--with-alsa], [choose native ALSA API support (linux only)])])
  43 AC_ARG_WITH(pulse, [AS_HELP_STRING([--with-pulse], [choose PulseAudio API support (unixes)])])
  44 AC_ARG_WITH(oss, [AS_HELP_STRING([--with-oss], [choose OSS API support (unixes)])])
  45 AC_ARG_WITH(core, [AS_HELP_STRING([--with-core], [choose CoreAudio API support (mac only)])])
  46 AC_ARG_WITH(asio, [AS_HELP_STRING([--with-asio], [choose ASIO API support (win32 only)])])
  47 AC_ARG_WITH(ds, [AS_HELP_STRING([--with-ds], [choose DirectSound API support (win32 only)])])
  48 AC_ARG_WITH(wasapi, [AS_HELP_STRING([--with-wasapi], [choose Windows Audio Session API support (win32 only)])])
  49
  50 # Check version number coherency between RtAudio.h and configure.ac
  51 AC_MSG_CHECKING([that version numbers are coherent])
  52 RTAUDIO_VERSION=`sed -n 's/#define RTAUDIO_VERSION "\(.*\)"/\1/p' $srcdir/RtAudio.h`
  53 AS_IF([test "x$RTAUDIO_VERSION" != "x$PACKAGE_VERSION"],[
  54    AC_MSG_RESULT([no])
  55    AC_MSG_FAILURE([testing RTAUDIO_VERSION==PACKAGE_VERSION failed, check that RtAudio.h defines RTAUDIO_VERSION as "$PACKAGE_VERSION" or that the first line of configure.ac has been updated.])
  56    ],[
  57    AC_MSG_RESULT([yes])
  58 ])
  59 # Enable some nice automake features if they are available
  60 m4_ifdef([AM_MAINTAINER_MODE], [AM_MAINTAINER_MODE])
  61 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  62
  63 # Fill GXX with something before test.
  64 GXX="no"
  65 # if the user did not provide any CXXFLAGS, we can override them
  66 AS_IF([test "x$CXXFLAGS" = "x" ], [override_cxx=yes], [override_cxx=no])
  67 AS_IF([test "x$CFLAGS" = "x" ], [override_c=yes], [override_c=no])
  68
  69 # Checks for programs.
  70 AC_PROG_CXX(g++ CC c++ cxx)
  71 AM_PROG_AR
  72 AC_PATH_PROG(AR, ar, no)
  73 AS_IF([test "x${AR}" = "xno" ], [
  74     AC_MSG_ERROR([Could not find ar - needed to create a library])
  75 ])
  76
  77 # Initialize libtool
  78 LT_INIT([win32-dll])
  79 AC_CONFIG_MACRO_DIR([m4])
  80
  81 # Checks for header files.
  82 AC_HEADER_STDC
  83 AC_CHECK_HEADERS(sys/ioctl.h unistd.h)
  84
  85 # Check compiler and use -Wall if gnu
  86 AS_IF([test "x${GXX}" = "xyes" ], [
  87   CXXFLAGS="-Wall -Wextra ${CXXFLAGS}"
  88   AS_IF([ test "x${enable_debug}" = "xyes" ], [
  89     # Add -Werror in debug mode (except unused-function)
  90     CXXFLAGS="-Werror -Wno-error=unused-function ${CXXFLAGS}"
  91   ], [
  92     # hide private symbols in non-debug mode
  93     visibility="-fvisibility=hidden"
  94   ])
  95 ])
  96
  97 # Check for debug
  98 AC_MSG_CHECKING([whether to compile debug version])
  99 debugflags=""
 100 AS_CASE([${enable_debug}],
 101   [ yes ], [
 102     AC_MSG_RESULT([yes])
 103     AC_DEFINE([__RTAUDIO_DEBUG__])
 104     debugflags="${debugflags} -g -O0"
 105     object_path=Debug
 106   ],
 107   [ no ], [
 108     AC_MSG_RESULT([no!])
 109     debugflags="${debugflags} -O3"
 110   ], [
 111     AC_MSG_RESULT([no])
 112   ])
 113
 114 # For debugging and optimization ... overwrite default because it has both -g and -O2
 115 AS_IF([test "x$debugflags" != x],
 116   AS_IF([test "x$override_cxx" = "xyes" ], CXXFLAGS="$CXXFLAGS $debugflags", CXXFLAGS="$debugflags $CXXFLAGS")
 117   AS_IF([test "x$override_c" = "xyes" ], CFLAGS="$CFLAGS $debugflags", CFLAGS="$debugflags $CFLAGS")
 118   )
 119
 120
 121 # Checks for functions
 122 AC_CHECK_FUNC(gettimeofday, [cppflag="$cppflag -DHAVE_GETTIMEOFDAY"], )
 123
 124 # Checks for doxygen
 125 AC_CHECK_PROG( DOXYGEN, [doxygen], [doxygen] )
 126 AM_CONDITIONAL( MAKE_DOC, [test "x${DOXYGEN}" != x ] )
 127
 128 # Copy doc files to build dir if necessary
 129 AC_CONFIG_LINKS( [doc/release.txt:doc/release.txt] )
 130 AC_CONFIG_LINKS( [doc/doxygen/footer.html:doc/doxygen/footer.html] )
 131 AC_CONFIG_LINKS( [doc/doxygen/error.txt:doc/doxygen/error.txt] )
 132 AC_CONFIG_LINKS( [doc/doxygen/tutorial.txt:doc/doxygen/tutorial.txt] )
 133 AC_CONFIG_LINKS( [doc/doxygen/compiling.txt:doc/doxygen/compiling.txt] )
 134 AC_CONFIG_LINKS( [doc/doxygen/acknowledge.txt:doc/doxygen/acknowledge.txt] )
 135 AC_CONFIG_LINKS( [doc/doxygen/license.txt:doc/doxygen/license.txt] )
 136 AC_CONFIG_LINKS( [doc/doxygen/header.html:doc/doxygen/header.html] )
 137 AC_CONFIG_LINKS( [doc/doxygen/duplex.txt:doc/doxygen/duplex.txt] )
 138 AC_CONFIG_LINKS( [doc/doxygen/settings.txt:doc/doxygen/settings.txt] )
 139 AC_CONFIG_LINKS( [doc/doxygen/probe.txt:doc/doxygen/probe.txt] )
 140 AC_CONFIG_LINKS( [doc/doxygen/playback.txt:doc/doxygen/playback.txt] )
 141 AC_CONFIG_LINKS( [doc/doxygen/multi.txt:doc/doxygen/multi.txt] )
 142 AC_CONFIG_LINKS( [doc/doxygen/recording.txt:doc/doxygen/recording.txt] )
 143 AC_CONFIG_LINKS( [doc/doxygen/apinotes.txt:doc/doxygen/apinotes.txt] )
 144 AC_CONFIG_LINKS( [doc/images/mcgill.gif:doc/images/mcgill.gif] )
 145 AC_CONFIG_LINKS( [doc/images/ccrma.gif:doc/images/ccrma.gif] )
 146
 147 # Checks for package options and external software
 148 AC_CANONICAL_HOST
 149
 150 # Aggregate options into a single string.
 151 AS_IF([test "x$with_jack"   = "xyes"], [systems="$systems jack"])
 152 AS_IF([test "x$with_alsa"   = "xyes"], [systems="$systems alsa"])
 153 AS_IF([test "x$with_pulse"  = "xyes"], [systems="$systems pulse"])
 154 AS_IF([test "x$with_oss"    = "xyes"], [systems="$systems oss"])
 155 AS_IF([test "x$with_core"   = "xyes"], [systems="$systems core"])
 156 AS_IF([test "x$with_asio"   = "xyes"], [systems="$systems asio"])
 157 AS_IF([test "x$with_dsound" = "xyes"], [systems="$systems ds"])
 158 AS_IF([test "x$with_wasapi" = "xyes"], [systems="$systems wasapi"])
 159 required=" $systems "
 160
 161 # If none, assign defaults if any are known for this OS.
 162 # User must specified with-* options for any unknown OS.
 163 AS_IF([test "x$systems" = "x"],
 164   AS_CASE([$host],
 165     [*-*-netbsd*],   [systems="oss"],
 166     [*-*-freebsd*],  [systems="oss"],
 167     [*-*-linux*],    [systems="alsa pulse jack oss"],
 168     [*-apple*],      [systems="core jack"],
 169     [*-mingw32*],    [systems="asio ds wasapi jack"]
 170   ))
 171
 172 # If any were specifically requested disabled, do it.
 173 AS_IF([test "x$with_jack"   = "xno"], [systems=`echo $systems|tr ' ' \\\\n|grep -v jack`])
 174 AS_IF([test "x$with_alsa"   = "xno"], [systems=`echo $systems|tr ' ' \\\\n|grep -v alsa`])
 175 AS_IF([test "x$with_pulse"  = "xno"], [systems=`echo $systems|tr ' ' \\\\n|grep -v pulse`])
 176 AS_IF([test "x$with_oss"    = "xno"], [systems=`echo $systems|tr ' ' \\\\n|grep -v oss`])
 177 AS_IF([test "x$with_core"   = "xno"], [systems=`echo $systems|tr ' ' \\\\n|grep -v core`])
 178 AS_IF([test "x$with_asio"   = "xno"], [systems=`echo $systems|tr ' ' \\\\n|grep -v asio`])
 179 AS_IF([test "x$with_dsound" = "xno"], [systems=`echo $systems|tr ' ' \\\\n|grep -v dsound`])
 180 AS_IF([test "x$with_wasapi" = "xno"], [systems=`echo $systems|tr ' ' \\\\n|grep -v wasapi`])
 181 systems=" `echo $systems|tr \\\\n ' '` "
 182
 183 # For each audio system, check if it is selected and found.
 184 # Note: Order specified above is not necessarily respected. However,
 185 # *actual* priority is set at run-time, see RtAudio::openRtApi.
 186 # One AS_CASE per system, since they are not mutually-exclusive.
 187
 188 AS_CASE(["$systems"], [*" alsa "*], [
 189   AC_CHECK_LIB(asound, snd_pcm_open,
 190     [api="$api -D__LINUX_ALSA__"
 191      req="$req alsa"
 192      need_pthread=yes
 193      found="$found ALSA"
 194      LIBS="-lasound $LIBS"],
 195     AS_CASE(["$required"], [*" alsa "*],
 196       AC_MSG_ERROR([ALSA support requires the asound library!])))
 197 ])
 198
 199 AS_CASE(["$systems"], [*" pulse "*], [
 200   AC_CHECK_LIB(pulse-simple, pa_simple_flush,
 201     [api="$api -D__LINUX_PULSE__"
 202      req="$req libpulse-simple"
 203      need_pthread=yes
 204      found="$found PulseAudio"
 205      LIBS="-lpulse-simple $LIBS"],
 206     AS_CASE(["$required"], [*" pulse "*],
 207       AC_MSG_ERROR([PulseAudio support requires the pulse-simple library!])))
 208 ])
 209
 210 AS_CASE(["$systems"], [*" oss "*], [
 211   # libossaudio not required on some platforms (e.g. linux) so we
 212   # don't break things if it's not found, but issue a warning when we
 213   # are not sure (i.e. not on linux)
 214   AS_CASE([$host], [*-*-linux*], [], [*], [need_ossaudio=yes])
 215   AC_CHECK_LIB(ossaudio, main, [have_ossaudio=true],
 216     AS_CASE(["$required"], [*" oss "*],
 217       AS_IF([test "x$need_ossaudio" = xyes],
 218         AC_MSG_WARN([RtAudio may require the ossaudio library]))))
 219
 220   # linux systems may have soundcard.h but *not* have OSS4 installed,
 221   # we have to actually check if it exports OSS4 symbols
 222   AC_CHECK_DECL(SNDCTL_SYSINFO,
 223     [api="$api -D__LINUX_OSS__"
 224      need_pthread=yes
 225      found="$found OSS"],
 226      AS_CASE(["$required"], [*" oss "*],
 227        AC_MSG_ERROR([sys/soundcard.h not found]))
 228     [],
 229     [#include <sys/soundcard.h>])
 230 ])
 231
 232 AS_CASE(["$systems"], [*" jack "*], [
 233   AC_CHECK_LIB(jack, jack_client_open,
 234     [api="$api -D__UNIX_JACK__"
 235      req="$req jack"
 236      need_pthread=yes
 237      found="$found JACK"
 238      LIBS="-ljack $LIBS"],
 239     AS_CASE(["$required"], [*" jack "*],
 240       AC_MSG_ERROR([JACK support requires the jack library!])))
 241 ])
 242
 243 AS_CASE(["$systems"], [*" core "*], [
 244   AC_CHECK_HEADER(CoreAudio/CoreAudio.h,
 245     [api="$api -D__MACOSX_CORE__"
 246      need_pthread=yes
 247      found="$found CoreAudio",
 248      LIBS="$LIBS -framework CoreAudio -framework CoreFoundation"],
 249     AS_CASE(["$required"], [*" core "*],
 250       AC_MSG_ERROR([CoreAudio header files not found!])))
 251 ])
 252
 253 AS_CASE(["$systems"], [*" asio "*], [
 254   api="$api -D__WINDOWS_ASIO__"
 255   use_asio=yes
 256   CPPFLAGS="-I$srcdir/include $CPPFLAGS"
 257   need_ole32=yes
 258   found="$found ASIO"
 259 ])
 260
 261 AS_CASE(["$systems"], [*" ds "*], [
 262   AC_CHECK_HEADERS(mmsystem.h mmreg.h dsound.h,
 263     [api="$api -D__WINDOWS_DS__"
 264      need_ole32=yes
 265      found="$found DirectSound"
 266      LIBS="-ldsound -lwinmm $LIBS"])
 267 ])
 268
 269 AS_CASE(["$systems"], [*" wasapi "*], [
 270   AC_CHECK_HEADERS(windows.h audioclient.h avrt.h mmdeviceapi.h,
 271     [api="$api -D__WINDOWS_WASAPI__"
 272      CPPFLAGS="-I$srcdir/include $CPPFLAGS"
 273      need_ole32=yes
 274      found="$found WASAPI"
 275      LIBS="-lwinmm -lksuser -lmfplat -lmfuuid -lwmcodecdspuuid $LIBS"])
 276 ])
 277
 278 AS_IF([test -n "$need_ole32"], [LIBS="-lole32 $LIBS"])
 279
 280 AS_IF([test -n "$need_pthread"],[
 281   AC_MSG_CHECKING([for pthread])
 282   AC_CHECK_LIB(pthread, pthread_create, ,
 283     AC_MSG_ERROR([RtAudio requires the pthread library!]))])
 284
 285 AC_MSG_CHECKING([for audio API])
 286
 287 # Error case: no known realtime systems found.
 288 AS_IF([test x"$api" = "x"], [
 289   AC_MSG_RESULT([none])
 290   AC_MSG_ERROR([No known system type found for realtime support!])
 291 ], [
 292   AC_MSG_RESULT([$found])
 293 ])
 294
 295 AM_CONDITIONAL( ASIO, [test "x${use_asio}" = "xyes" ])
 296
 297 CPPFLAGS="$CPPFLAGS $api"
 298
 299 AC_OUTPUT